init python:
    def genie_transform(trans, st, at):
        trans.xpos = states.gen.image.xpos
        trans.ypos = states.gen.image.ypos
        trans.zoom = states.gen.image.zoom
        trans.xzoom = states.gen.image.xzoom
        trans.offset = states.gen.image.offset
        return 0

layeredimage genie_stats:
    anchor (0.0, 1.0)

    always "genie_bbase"
    always "genie_outfit_robes"
    always "genie_goatee"

    # TODO: Add outfit support; Low priority

layeredimage genie:
    anchor (0.0, 1.0)

    group outfit:
        attribute nude

    attribute bbase default

    group face:
        attribute base default null
        attribute grin
        attribute angry
        attribute smile
        attribute open

    group outfit:
        attribute robes default
        attribute santa

    attribute goatee default if_any ("robes", "nude")
    group _ multiple variant "santa_beard" if_any "santa":
        attribute base
        attribute grin
        attribute angry
        attribute smile
        attribute open

    at Transform(function=genie_transform)

image side genie = LayeredImageProxy("genie")
