

### Hermione Masturbate ###

### Tier 4 (Intro) ###

label hg_pf_strip_T4_fingering:
    if not hg_masturbated.trigger:
        $ hg_masturbated.triggered()

        gen "[hermione_name]..." ("base", xpos="far_left", ypos="head")
        her "Yes, [genie_name]?" ("base", "base", "base", "mid")
        gen "Do you ever touch yourself?" ("base", xpos="far_left", ypos="head")
        her "What? why?" ("upset", "wink", "base", "mid")
        gen "It's a simple question [hermione_name]..." ("base", xpos="far_left", ypos="head")
        her "[genie_name]!" ("scream", "happyCl", "worried", "mid")
        gen "And I want you to speak truthfully..." ("base", xpos="far_left", ypos="head")
        her "......" ("normal", "happyCl", "worried", "mid")
        gen "Well, [hermione_name]?" ("base", xpos="far_left", ypos="head")
        her "{size=-5}I suppose I do...{/size}" ("angry", "happyCl", "worried", "mid", emote="sweat")
        gen "*huh*? What was that?" ("base", xpos="far_left", ypos="head")
        her "I said that I do alright!!!" ("scream", "happyCl", "worried", "mid")
        gen "*Hmm*... I'm not sure I believe you." ("base", xpos="far_left", ypos="head")
        her "What? why would I lie?" ("annoyed", "base", "worried", "R")
        gen "I'm not sure... maybe it's because you think it's what I want you to say..." ("base", xpos="far_left", ypos="head")
        her "That doesn't make any--" ("annoyed", "base", "worried", "mid")
        gen "But don't worry, I'm sure a quick little demonstration will erase any doubts..." ("base", xpos="far_left", ypos="head")
        her "So that's what you're after......" ("annoyed", "narrow", "angry", "R")
        her "*Sigh*...{w=0.4} I suppose I could..." ("open", "narrow", "worried", "down")
        her "But you better keep your hands to yourself..." ("angry", "narrow", "worried", "mid")
        gen "Witcher's promise." ("base", xpos="far_left", ypos="head")
        her "..." ("annoyed", "squint", "base", "mid")
    else: # Repeat
        gen "[hermione_name]." ("base", xpos="far_left", ypos="head")
        gen "Why don't you give that lovely pussy of yours a little rub." ("grin", xpos="far_left", ypos="head")
        her "Again?" ("annoyed", "narrow", "base", "mid")
        her "..." ("disgust", "narrow", "base", "down")
        her "F-Fine... Just keep your hands to yourself..." ("open", "squint", "base", "R")

    call play_music("playful_tension") # SEX THEME.
    her "..........." ("upset", "base", "base", "mid")
    her "Do you want me to... start?" ("soft", "wink", "base", "mid")
    gen "When you're ready..." ("base", xpos="far_left", ypos="head")

    if hermione.is_worn("panties"):
        gen "But why don't we get rid of those panties first." ("base", xpos="far_left", ypos="head")

    her "..........." ("disgust", "narrow", "base", "down")

    if hermione.is_worn("panties"): # Rest of the clothes is taken off during stripping.
        pause 1.0
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        $ hermione.strip("panties")
        pause 1.0

    if hermione.is_any_worn("clothes"):
        gen "Now take off the rest." ("base", xpos="far_left", ypos="head")
        $ hermione.strip("all")
        pause .5

    her "(I never would've imagined... To do this in front of my headmaster of all people...)" ("normal", "happyCl", "worried", "mid")

    $ hermione.set_pose("masturbate")
    $ hermione.set_body(armleft="on_pussy")
    her "" ("soft", "closed", "worried", "mid", trans=d3)

    $ renpy.play("sounds/slick_02.ogg")
    with hpunch
    pause 1.0
    play bg_sounds "sounds/slickloop.ogg" fadein 2
    call ctc

    gen "Nice..." ("grin", xpos="far_left", ypos="head")
    her "........" ("upset", "wink", "base", "mid")
    gen "............." ("base", xpos="far_left", ypos="head")
    her "............." ("normal", "happyCl", "worried", "mid")
    stop bg_sounds
    her "*Umm*... [genie_name]?"
    gen "Yes, what is it?" ("base", xpos="far_left", ypos="head")
    her "For how long did you want me to do this?" ("open", "base", "worried", "mid")
    gen "Until you finish [hermione_name]..." ("base", xpos="far_left", ypos="head")

    if game.daytime:
        her "But my classes are about to start, [genie_name]..." ("annoyed", "base", "worried", "mid")
    else:
        her "But it's getting late, [genie_name]..." ("annoyed", "base", "worried", "mid")

    her "I'm not sure if I'll be able to... finish... in time." ("disgust", "narrow", "base", "down")
    gen "Do you need the points or not?" ("base", xpos="far_left", ypos="head")
    her "I do, [genie_name]! I'm sorry..." ("open", "narrow", "worried", "down")
    her "I'll keep going then..." ("disgust", "narrow", "base", "down")
    play bg_sounds "sounds/slickloop.ogg" fadein 2
    gen "(*Hmm*... Maybe I should encourage her a little.)" ("base", xpos="far_left", ypos="head")

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "\"Yes... keep going, slut.\"":
            her "[genie_name]!!!" ("angry", "base", "angry", "mid")
            her "How...{w=0.4} How dare you!" ("upset", "base", "angry", "mid")
            gen "what?" ("base", xpos="far_left", ypos="head")
            her "I hardly think that kind of... *Ah*...{w=0.5} language is appropriate." ("open", "happyCl", "base", "mid")
            gen "And masturbating in front of your headmaster is?" ("base", xpos="far_left", ypos="head")
            her "Well...{w=0.4} this...{w=0.4} this is different." ("open", "narrow", "worried", "down")
            her "I'm doing this for the honour of Gryffindor..."
            her "To help my--... *Ah*" ("open", "closed", "worried", "down")
            play bg_sounds "sounds/slickloopfast.ogg"
            call nar(">You notice Hermione beginning to move her fingers a little faster.")
            #
            # TODO: Add wet layer for panties/pussy
            #
            her "*Ah*...{heart}{heart}{heart}" ("soft", "narrow", "annoyed", "up")
            her "My classmates win the house cup..." ("angry", "wink", "base", "mid")
            gen "As if that's the only reason..." ("grin", xpos="far_left", ypos="head")
            her "I..{w=0.4}*Ah*... of course it...--" ("normal", "happyCl", "worried", "mid")

            $ hermione.set_body_zorder(armright=3)
            $ hermione.set_body(armleft="on_pussy", armright="on_tits")

            her "*Ah-a*{heart}..." ("open", "happyCl", "worried", "mid")
            her "What..{w=0.4}*Ah*... other reason would there be for me to..." ("angry", "narrow", "base", "down")
            gen "It seems to me that you might be enjoying this a little too much..." ("base", xpos="far_left", ypos="head")
            her "I am not, [genie_name]!" ("open", "happyCl", "worried", "mid")
            gen "Really?" ("base", xpos="far_left", ypos="head")
            her "......................" ("normal", "happyCl", "worried", "mid")
            gen "Then why are your fingers moving so fast, slut?" ("base", xpos="far_left", ypos="head")
            call ctc

            her "*Ah*...{heart}" ("open", "happyCl", "worried", "mid")
            gen "ha! just Admit it, you do enjoy being called a slut!" ("base", xpos="far_left", ypos="head")
            her "I do not!" ("normal", "happyCl", "worried", "mid")
            her "I'm just thinking about...{w=0.4}*Ah*...{w=0.4} how happy everyone will be when we win!" ("shock", "happyCl", "worried", "mid")
            gen "And what if they find out how you earned the points?" ("base", xpos="far_left", ypos="head")
            stop bg_sounds
            her "what?!" ("shock", "wide", "base", "stare")
            gen "Then it wouldn't just be me degrading you..." ("base", xpos="far_left", ypos="head")
            play bg_sounds "sounds/slickloop.ogg"
            her "..." ("soft", "closed", "base", "R")
            gen "It would be the entire school." ("base", xpos="far_left", ypos="head")
            play bg_sounds "sounds/slickloopfast.ogg"
            her "The entire-- *Ah*...{heart}" ("silly", "narrow", "base", "dead", cheeks="blush")
            gen "Every...{w=0.4} single...{w=0.4} student." ("base", xpos="far_left", ypos="head")
            play bg_sounds "sounds/slickloopveryfast.ogg"
            her "*Ah*...{heart}{heart}{heart}" ("grin", "narrow", "annoyed", "up", cheeks="blush")
            her "[genie_name], please... {w=0.4}*mmmh*...{w=0.4} don't tell anyone..." ("soft", "narrow", "base", "mid_soft", cheeks="blush")
            call nar(">Hermione continues to rub herself with even more effort...")
            her "They can't...{w=0.4}*Ah*...{w=0.4} They can't find out..." ("soft", "narrow", "base", "R_soft", cheeks="blush")
            her "If harry and ron knew..." ("open", "narrow", "base", "down", cheeks="blush")
            her "I'd... *Ah*...{heart}" ("soft", "closed", "annoyed", "up", cheeks="blush")
            gen "You'd what [hermione_name]?" ("base", xpos="far_left", ypos="head")
            her "I'd..." ("open", "closed", "worried", "mid", cheeks="blush")
            her "I'd...{heart}" ("silly", "closed", "worried", "mid", cheeks="blush")
            her "I...{heart}{heart}{heart}" ("grin", "narrow", "annoyed", "up", cheeks="blush")

        "\"Play with your breasts\"":
            her "My breasts..." ("open", "narrow", "worried", "down")
            her "I'm not sure if I should--" ("open", "narrow", "base", "down")
            gen "There's another ten points for Gryffindor in it for you..." ("base", xpos="far_left", ypos="head")
            $ current_payout += 10
            her "..." ("normal", "happy", "base", "R")
            her "......" ("soft", "happy", "base", "R")

            $ hermione.set_body_zorder(armright=3)
            $ hermione.set_body(armleft="on_pussy", armright="on_tits")

            her "*Ah*...{heart}" ("open", "closed", "base", "R")
            gen "There... Isn't that better?" ("base", xpos="far_left", ypos="head")
            her "*Ah*... W-what..." ("open", "wink", "worried", "mid")
            her "......" ("normal", "happyCl", "base", "mid")
            gen "That's it..." ("base", xpos="far_left", ypos="head")
            her "......" ("normal", "narrow", "base", "mid", cheeks="blush")
            her "[genie_name], do you mind if..." ("soft", "narrow", "base", "L", cheeks="blush")
            gen "What [hermione_name]?" ("base", xpos="far_left", ypos="head")
            her "Could you... Call me names..." ("open", "narrow", "base", "R", cheeks="blush")
            gen "Such as?" ("base", xpos="far_left", ypos="head")

            her "...{size=-5}A Slut...{/size} But only if it's not too much to ask..." ("soft", "narrow", "base", "down", cheeks="blush")
            gen "That's unbecoming of you to use such language, you little whore..." ("base", xpos="far_left", ypos="head")
            her "*Ah*...{heart}{heart}" ("open", "closed", "annoyed", "mid")
            gen "What would your parents think if they saw this?" ("base", xpos="far_left", ypos="head")
            her "I-{heart}" ("open", "narrow", "worried", "up", cheeks="blush")
            play bg_sounds "sounds/slickloopfast.ogg"
            her "*Ah*...{heart} I don't know..." ("soft", "closed", "base", "up", cheeks="blush")
            her "To be perfectly honest [genie_name]... I don't think I care...{heart}{heart}{heart}" ("silly", "narrow", "base", "up", cheeks="blush")
            gen "Really?" ("base", xpos="far_left", ypos="head")

            her "Really...{heart}" ("silly", "narrow", "base", "mid_soft", cheeks="blush")
            gen "Would you at least stop?" ("base", xpos="far_left", ypos="head")
            her "*Ah*...{heart}" ("open_tongue", "narrow", "base", "up", cheeks="blush")
            her "Maybe..." ("open_tongue", "narrow", "base", "up", cheeks="blush")
            her "I'm not sure..." ("open", "narrow", "base", "R", cheeks="blush")
            gen "So you wouldn't mind if they heard me calling you a slut?" ("base", xpos="far_left", ypos="head")
            her "I...{w=0.4}*mmmh*... Of course I--" ("normal", "happyCl", "worried", "mid", cheeks="blush")
            gen "I bet if they appeared right now you wouldn't even stop touching yourself you filthy slut." ("base", xpos="far_left", ypos="head")
            her "*Ah*...{heart}" ("open_tongue", "narrow", "base", "up", cheeks="blush")
            gen "You're nothing but a disgrace and a whore..." ("base", xpos="far_left", ypos="head")
            her "*Ah*...{w=0.4} I'm-{heart}" ("open", "happyCl", "worried", "mid", cheeks="blush")

            her "{heart}{heart}{heart}" ("grin", "narrow", "base", "up", cheeks="blush")

        "\"Spread em!\"":
            gen "Excellent... Just make sure to give me a nice view of that wet pussy!" ("base", xpos="far_left", ypos="head")
            her "[genie_name]!" ("open", "base", "angry", "mid", cheeks="blush")
            gen "What?" ("base", xpos="far_left", ypos="head")

            her "It's not {size=-5}wet...{/size}" ("annoyed", "narrow", "worried", "R", cheeks="blush")
            gen "Are you sure? Because from where I'm sitting it looks nice and wet." ("base", xpos="far_left", ypos="head")
            her "*Ah*...{heart}" ("soft", "narrow", "base", "up", cheeks="blush")
            her "It...{w=0.4} it's just sweat, [genie_name]..." ("open", "narrow", "base", "R", cheeks="blush")
            gen "if you say so..." ("base", xpos="far_left", ypos="head")
            her "..............." ("soft", "closed", "base", "up", cheeks="blush")
            gen "Slut." ("base", xpos="far_left", ypos="head")
            play bg_sounds "sounds/slickloopfast.ogg"
            her "{heart}{heart}{heart}" ("silly", "narrow", "base", "up_soft", cheeks="blush")
            her "Sir... please..." ("open", "narrow", "base", "mid_soft", cheeks="blush")

            $ hermione.set_body_zorder(armright=3)
            $ hermione.set_body(armleft="on_pussy", armright="on_tits")

            play bg_sounds "sounds/slickloopveryfast.ogg"
            call nar(">Hermione starts fingering herself even faster.")
            gen "Very good..." ("base", xpos="far_left", ypos="head")
            her "...{heart}" ("silly", "narrow", "base", "up", cheeks="blush")
            her "*Ah*...{heart}" ("open_tongue", "narrow", "base", "up", cheeks="blush")
            gen "That's it slut... Try going a little deeper..." ("base", xpos="far_left", ypos="head")
            her "..." ("open_tongue", "narrow", "base", "up", cheeks="blush")

            her "...{heart}" ("open", "happyCl", "worried", "mid", cheeks="blush")

    play bg_sounds "sounds/slickloop.ogg"
    her "*Ah*..." ("soft", "narrow", "base", "R", cheeks="blush")
    gen "almost there [hermione_name]?" ("base", xpos="far_left", ypos="head")
    her "a-almost..." ("annoyed", "base", "worried", "L", cheeks="blush")
    her "I just need a bit longer..."
    gen "well you better hurry..." ("base", xpos="far_left", ypos="head")
    her "*Ah*...{w=0.3} I know, [genie_name]." ("angry", "happyCl", "worried", "mid")
    her "..........." ("normal", "closed", "base", "R", cheeks="blush")
    gen "Is everything alright?" ("base", xpos="far_left", ypos="head")
    play bg_sounds "sounds/slickloopfast.ogg"
    her "................" ("annoyed", "narrow", "base", "down", cheeks="blush", tears="sweat")
    gen "Why are you being so quiet [hermione_name]?" ("base", xpos="far_left", ypos="head")
    play bg_sounds "sounds/slickloop.ogg"
    her "......" ("annoyed", "base", "worried", "R_soft", cheeks="blush")
    her "[genie_name]... I don't think I can..."
    gen "What?" ("base", xpos="far_left", ypos="head")
    stop bg_sounds
    her "...{w=0.3} Finish..." ("angry", "happyCl", "base", "down", cheeks="blush", tears="soft")

    menu:
        "-Chastise her-":
            gen "Well then, I guess Slytherin will have to win the house cup this year." ("base", xpos="far_left", ypos="head")
            her "B-but--" ("disgust", "narrow", "worried", "mid", cheeks="blush", tears="soft")
            gen "Now, now [hermione_name]... A deal's a deal." ("base", xpos="far_left", ypos="head")
            her "But I'm trying [genie_name]..." ("upset", "narrow", "worried", "down", tears="crying")
            gen "Try harder..." ("base", xpos="far_left", ypos="head")
            play bg_sounds "sounds/slickloopveryfast.ogg"
            her "" (eyes="happyCl", tears="tears_soft_sweat")
            call nar(">Hermione starts grinding furiously against her hand.")

            # Reset pose
            $ hermione.set_body_zorder(armright=0)
            $ hermione.set_body(armleft="down", armright="down")
            $ hermione.set_pose(None)
            $ hermione.strip("all")

            stop bg_sounds
            her "*SOB*!{w=0.3} I can't..." ("angry", "happyCl", "base", "down", cheeks="blush", tears="messy")
            gen "Well then... Zero points to Gryffindor." ("base", xpos="far_left", ypos="head")
            her "{size=-5}After everything I...{/size} Really [genie_name]?" ("open", "base", "worried", "stare", cheeks="blush", tears="messy")
            her "After I stood here and..." ("scream", "base", "angry", "mid", cheeks="blush", tears="messy")
            her ".........." ("angry", "squint", "base", "mid", cheeks="blush", tears="messy")

            call blkfade
            hide hermione_main
            call her_chibi("stand", "desk", "base")
            $ hermione.wear("all")
            stop music fadeout 2.0

            call hide_blkfade

            her "I am not going to sell you a single favour anymore, [genie_name]!" ("scream", "base", "low", "mid", cheeks="blush", tears="mascara")

            call her_walk(action="run", xpos="door", speed=2, reduce=True)
            call her_chibi("leave")

            $ her_mood += 15

            pause 1.0
            gen "..." ("base", xpos="far_left", ypos="head")
            gen "We'll see about that." ("base", xpos="far_left", ypos="head")

            jump end_hermione_event

        "-Forgive her-":
            gen "It's alright, [hermione_name]." ("base", xpos="far_left", ypos="head")
            her "Really?" ("open", "narrow", "worried", "mid", cheeks="blush", tears="crying")
            gen "I'm sure you're just a little nervous." ("base", xpos="far_left", ypos="head")

            # Reset pose
            $ hermione.set_body_zorder(armright=0)
            $ hermione.set_body(armleft="down", armright="down")
            $ hermione.set_pose(None)
            $ hermione.strip("all")

            her "Thank you [genie_name]." ("base", "base", "worried", "mid", cheeks="blush", tears="soft")
            her "I promise to try harder next time." ("base", "happyCl", "worried", "mid", cheeks="blush")

    jump end_hg_pf_strip

### Tier 5 ###

label hg_pf_strip_T5_fingering:


    gen "[hermione_name]..." ("base", xpos="far_left", ypos="head")
    her "Yes, [genie_name]?" ("base", "base", "base", "mid")
    gen "I hope you're feeling horny." ("base", xpos="far_left", ypos="head")
    her "Maybe a little, [genie_name]." ("base", "narrow", "base", "mid_soft")
    gen "Good, then we better do something about that..." ("base", xpos="far_left", ypos="head")
    her "[genie_name]..." ("open", "wink", "worried", "mid")
    gen "Why don't you give that lovely pussy of yours a little rub." ("grin", xpos="far_left", ypos="head")
    her "{heart}{heart}{heart}" ("base", "narrow", "base", "mid_soft")
    her "............." ("base", "base", "base", "R_soft")
    her "Alright...{w=0.4} if that's what you want..." ("base", "narrow", "worried", "down")
    if not hg_masturbated.trigger:
        her "(I can't believe I'm agreeing to do this...)" ("soft", "narrow", "base", "down")
    else:
        her "(I can't believe I'm agreeing to do this...{w=0.4} again...)" ("soft", "narrow", "base", "down")

    $ hg_masturbated.triggered()

    if hermione.is_worn("panties"):
        call nar(">Hermione bends over and takes off her panties.")
        pause 1.0
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        $ hermione.strip("panties")
        pause 1.0

    if hermione.is_any_worn("clothes"):
        gen "Now take off the rest." ("base", xpos="far_left", ypos="head")
        $ hermione.strip("all")

    her "(Okay then, here I go...)" ("normal", "happyCl", "worried", "mid")

    show screen blkfade
    with d5
    $ hermione.set_pose("masturbate")
    $ hermione.set_body_zorder(armright=3)
    $ hermione.set_body(armleft="on_pussy")
    her "" ("soft", "closed", "worried", "mid", trans=d3)
    $ renpy.play("sounds/slick_02.ogg")
    with hpunch
    with kissiris
    her "*Ah*..." ("open", "squint", "worried", "R", cheeks="blush")
    call ctc
    hide screen blkfade
    with d5

    call play_music("playful_tension") # SEX THEME.
    gen "Nice..." ("grin", xpos="far_left", ypos="head")

    play bg_sounds "sounds/slickloop.ogg" fadein 2
    her "*Mmhh*... {heart}" ("open", "happyCl", "worried", "mid")
    her "*Ah*...{w=0.4} {heart}-aha..." ("open", "happyCl", "worried", "mid")
    gen "..." ("base", xpos="far_left", ypos="head")
    her "*Ah-ah*..." ("open", "happyCl", "worried", "mid")
    gen "......................" ("base", xpos="far_left", ypos="head")
    her "*Ah*...{w=0.4} *ah*...{heart}" ("open", "happyCl", "worried", "mid")
    her "*Ah*...{w=0.4} [genie_name]?" ("soft", "happy", "base", "R")
    gen "What is it?" ("base", xpos="far_left", ypos="head")
    her "Do you....{w=0.4}*Ah*...{w=0.4} like this?" ("open", "happyCl", "worried", "mid")
    gen "Do I like watching \"you\" finger your cute little pussy?" ("base", xpos="far_left", ypos="head")
    gen "Of course, [hermione_name]. Why?" ("base", xpos="far_left", ypos="head")
    her "{heart}{heart}{heart}" ("normal", "happyCl", "worried", "mid")
    her "*Ah*... You're just so quiet..." ("open", "happyCl", "worried", "mid")
    gen "Do you need a little more encouragement?" ("base", xpos="far_left", ypos="head")
    her "*Ah*...{w=0.4} yes... please....{heart}" ("open", "happyCl", "worried", "mid")
    gen "*Tch*... Such a dirty whore..." ("base", xpos="far_left", ypos="head")
    play bg_sounds "sounds/slickloopfast.ogg"
    her "Yes [genie_name], *Ah*...{heart}" ("grin", "narrow", "base", "up", cheeks="blush")
    her "Please... *Ah*...{w=0.4} more...{heart}" ("grin", "base", "angry", "mid", cheeks="blush")
    gen "You deserve to be punished for being such a filthy slut!" ("angry", xpos="far_left", ypos="head")
    her "Yes, [genie_name]... punish me..." ("open", "narrow", "base", "up", cheeks="blush")
    her "Make me your little slut..." ("open", "narrow", "base", "up", cheeks="blush")
    play bg_sounds "sounds/slickloopveryfast.ogg"
    her "I will... *Ah*...{w=0.4} {heart}do anything...{w=0.4} *Ah*...{heart}" ("silly", "narrow", "base", "dead")
    gen "Anything [hermione_name]?" ("base", xpos="far_left", ypos="head")
    her "*Ah-a*...{heart} Yessss..." ("silly", "narrow", "base", "up", cheeks="blush")
    gen "Cum." ("base", xpos="far_left", ypos="head")
    #
    # TODO: CUM LAYERS
    #
    her "{heart}{heart}{heart}!!!{heart}{heart}{heart}" ("silly", "narrow", "base", "dead", cheeks="blush")
    with kissiris
    with hpunch
    $ renpy.play("sounds/slick_01.ogg")

    her "*Ah*...{heart}...{heart}" ("grin", "narrow", "annoyed", "up", cheeks="blush")
    with kissiris
    with hpunch
    $ renpy.play("sounds/slick_01.ogg")

    her "*Ah*... *Ah*...{heart}" ("silly", "base", "base", "ahegao", cheeks="blush")
    play bg_sounds "sounds/slickloopfast.ogg"
    her "..." ("open_tongue", "closed", "base", "up", cheeks="blush")
    her "...{heart}{heart}{heart}" ("grin", "narrow", "annoyed", "dead", cheeks="blush")
    her "*Gah*...{w=0.4} *Ah*...{w=0.4} *Ah*..." ("open_tongue", "narrow", "annoyed", "dead", cheeks="blush")
    play bg_sounds "sounds/slickloop.ogg"
    her "[genie_name]...{heart}{heart}{heart}" ("open", "narrow", "annoyed", "mid", cheeks="blush")
    her "............." ("soft", "narrow", "annoyed", "up")
    stop bg_sounds
    call nar(">Hermione takes a minute to collect herself.")

    # Reset pose
    $ hermione.set_body_zorder(armright=0)
    $ hermione.set_body(armleft="down", armright="down")
    $ hermione.set_pose(None)

    $ hermione.wear("all")

    jump end_hg_pf_strip

### Tier 6 ###

label hg_pf_strip_T6_fingering:

    $ hg_masturbated.triggered()

    gen "[hermione_name]?" ("base", xpos="far_left", ypos="head")
    her "[genie_name]?" ("base", "base", "base", "mid")
    gen "You don't mind pleasuring yourself in front of me, do you?" ("base", xpos="far_left", ypos="head")
    if her_whoring <= 16:
        her "As long as I am being paid..." ("grin", "base", "base", "R")
        gen "That's the spirit!" ("grin", xpos="far_left", ypos="head")
    else:
        her "I mean I have done it once today already..." ("grin", "base", "base", "R")
        gen "Once more for good luck then!" ("grin", xpos="far_left", ypos="head")
        her "If you insist...{heart}" ("open", "base", "base", "R", cheeks="blush")

    her "..." ("base", "narrow", "base", "mid_soft")
    if hermione.is_worn("panties"):
        call nar(">Hermione hastily takes off her panties.")
        pause 1.0
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        $ hermione.strip("panties")
        pause 1.0

    if hermione.is_any_worn("clothes"):
        gen "Now take off the rest." ("base", xpos="far_left", ypos="head")
        $ hermione.strip("all")

    her "(...)" ("base", "happyCl", "worried", "mid")

    show screen blkfade
    with d5
    $ hermione.set_pose("masturbate")
    $ hermione.set_body_zorder(armright=3)
    $ hermione.set_body(armleft="on_pussy")
    her "" ("soft", "closed", "worried", "mid", trans=d3)
    $ renpy.play("sounds/slick_02.ogg")
    with hpunch
    with kissiris
    her "*Ah*..." ("open", "squint", "worried", "R", cheeks="blush")
    call ctc
    hide screen blkfade
    with d5


    stop music fadeout 3.0
    play bg_sounds "sounds/slickloop.ogg" fadein 2

    her "*Mmmh*...{heart}" ("base", "narrow", "base", "down", cheeks="blush")
    her "[genie_name]...{w=0.4} Do you...{w=0.4} like it when I do it like this?" ("grin", "narrow", "base", "down", cheeks="blush")
    $ renpy.music.set_volume(0.3, 0.0)
    call play_music("chipper_doodle") # HERMIONE'S THEME.

    gen "Yes, I love it..." ("base", xpos="far_left", ypos="head")
    gen "Try going a little deeper with your fingers." ("base", xpos="far_left", ypos="head")
    her "Alright [genie_name]..." ("base", "happyCl", "base", "mid", cheeks="blush")
    play bg_sounds "sounds/slickloopfast.ogg"
    her "*Ah*...{w=0.4} *Ah*...{w=0.4}{heart}" ("open", "happyCl", "worried", "mid", cheeks="blush")
    her "*Ah*...{w=0.6} [genie_name]...{heart}" ("open", "happyCl", "worried", "mid", cheeks="blush")

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "\"Tell me what you're thinking about.\"":
            her "*huh*?" ("open", "wink", "worried", "mid", cheeks="blush")
            her "Oh, *umm*... nothing..." ("soft", "happyCl", "worried", "mid", cheeks="blush")
            gen "[hermione_name]..." ("base", xpos="far_left", ypos="head")
            her "[genie_name],{w=0.4} it's a bit weird..." ("disgust", "narrow", "base", "down", cheeks="blush")
            gen "Even more reason to tell me." ("angry", xpos="far_left", ypos="head")
            her "......" ("annoyed", "narrow", "annoyed", "mid", cheeks="blush")
            her "Fine..." ("open", "base", "base", "R", cheeks="blush")
            her "If you must know... I was thinking about the time I corrected professor Snape on the ingredients of a Hiccoughing potion." ("open", "narrow", "worried", "down", cheeks="blush")
            gen "....." ("base", xpos="far_left", ypos="head")
            her "*Ah*...{heart}" ("soft", "narrow", "annoyed", "up", cheeks="blush")
            her "It was...{w=0.4} *Ah*...{w=0.4} {heart} in front of the entire class as well." (cheeks="blush")
            her "He refused to let me answer any questions for a week after that." ("base", "narrow", "worried", "down", cheeks="blush")
            her "But it was worth it..." ("soft", "happy", "base", "R", cheeks="blush")
            her "The look on his face when he realised he was wrong...{heart}" ("soft", "narrow", "annoyed", "up", cheeks="blush")
            her "*A-ah*...{heart}" (cheeks="blush")
            her "It just felt so good!{heart}" ("grin", "narrow", "base", "dead", cheeks="blush")
            gen "This is what you're thinking of when masturbating?" ("base", xpos="far_left", ypos="head")
            her "..." ("normal", "narrow", "base", "dead", cheeks="blush")
            her "Is that too weird?" ("upset", "narrow", "base", "mid", cheeks="blush")
            gen "(No wonder why she's being such a know it all... she's getting off from it.)" ("base", xpos="far_left", ypos="head")
            gen "Let's just get back to business shall we?" ("base", xpos="far_left", ypos="head")
            her "................." ("base", "narrow", "annoyed", "up", cheeks="blush")
            call nar(">Hermione goes quiet for a moment to enjoy herself, now fully focused on moving her fingers.","start")
            gen "(Having a bit too much fun I think...)" ("base", xpos="far_left", ypos="head")

        "\"You really are a shameless slut, aren't you?\"":
            her "Yes..." ("soft", "narrow", "annoyed", "up")
            her "*Ah*... {heart}" ("silly", "narrow", "base", "dead")
            her "I don't know if has to do with the time I've spent with you...{heart}" ("angry", "wink", "base", "mid")
            her "Or if I've always been this way...{heart}" ("angry", "narrow", "base", "down")
            her "But... {heart} {w=0.4}*Ah*...{w=0.4} {heart} I'm a slut [genie_name]...{heart}" ("soft", "narrow", "annoyed", "up")
            play bg_sounds "sounds/slickloopfast.ogg"
            her "A shameless slut..." ("grin", "narrow", "base", "dead")
            her "That pleasures herself...{heart} {w=0.4}*Ah*..." ("soft", "narrow", "annoyed", "up")
            her "Just to make her headmaster happy..." ("grin", "narrow", "base", "dead")
            gen "Oh, yes..." ("base", xpos="far_left", ypos="head")
            her "That's it [genie_name]..." ("base", "narrow", "worried", "up_soft")
            her "Enjoy yourself while I stand here..." ("silly", "narrow", "base", "dead")
            her "*Ah*...{heart}" ("open_wide_tongue", "narrow", "annoyed", "up")
            her "Fingering my pussy..." ("silly", "narrow", "annoyed", "up")
            her "*Ah*...{w=0.4} *Ah*...{heart}" ("grin", "narrow", "annoyed", "up")
            her "*Ah*...{w=0.4} Do you.... like this [genie_name]?" ("shock", "happyCl", "worried", "mid")
            her "Watching me {w=0.4}*Ah*...{w=0.4}{heart} degrade myself?" ("silly", "narrow", "base", "dead")
            gen "Very much, [hermione_name]. Just keep going..." ("base", xpos="far_left", ypos="head")
            her "{heart}{heart}{heart}" ("silly", "narrow", "base", "dead")

        "\"Play with your tits some more!\"":
            her "*Hmm*?" ("soft", "narrow", "annoyed", "up")
            her "Okay...{w=0.4} if you insist..." ("open", "base", "base", "R", cheeks="blush")

            $ hermione.set_body_zorder(armright=3)
            $ hermione.set_body(armright="on_tits")

            her "*Ah*...{heart}" ("angry", "wink", "base", "mid")
            gen "Now pinch your nipples." ("base", xpos="far_left", ypos="head")
            her "[genie_name]..." ("open", "happy", "base", "mid", cheeks="blush")
            gen "do it, [hermione_name]." ("base", xpos="far_left", ypos="head")
            her "..." ("open", "base", "base", "R", cheeks="blush")
            $ renpy.play("sounds/gasp2.ogg")
            her "*Ah*..." ("grin", "narrow", "base", "up", cheeks="blush")
            gen "..." ("grin", xpos="far_left", ypos="head")
            call nar(">You gaze at Hermione's breasts as she runs the tips of her fingers across her nipple...")
            her "*Ah*..." ("silly", "narrow", "base", "dead")
            gen "So you do like playing with those big tits of yours." ("grin", xpos="far_left", ypos="head")
            her "I do, [genie_name]... {w=0.4}*Ah*...{heart}" ("soft", "narrow", "annoyed", "up")
            her "I don't know why..." ("base", "base", "base", "R", cheeks="blush")
            her "But I love it...{heart}{heart}" ("open", "narrow", "worried", "down")
            gen "You nasty slut!" ("base", xpos="far_left", ypos="head")
            her "*Ah*...{w=0.4}{heart} *Ah-a*...{heart}" ("open_tongue", "narrow", "annoyed", "up")
            her "I am..."
            her "A nasty slut... {w=0.4}*Ah*...{heart}" ("silly", "narrow", "base", "dead")
            gen "You are a disgrace, [hermione_name]!" ("base", xpos="far_left", ypos="head")
            her "*Ah-ah*...{heart}{heart}{heart}" ("open_wide_tongue", "narrow", "annoyed", "up")

    gen "Why don't you come down and I'll help you finish?" ("base", xpos="far_left", ypos="head")
    her "..." ("base", "narrow", "worried", "down")

    # Hermione climbs off your desk.
    show screen blkfade
    with d5
    hide hermione_main
    call play_sound("climb_desk")
    stop bg_sounds
    ">Hermione slowly climbs down from the desk and stands in front of you."
    pause.5

    # Both hands down
    $ hermione.set_body_zorder(armright=0)
    $ hermione.set_body(armleft="down", armright="down")

    call her_chibi_scene("behind_desk_show_tits") #TODO Replace with naked chibi

    hide screen blktone
    hide screen bld1
    hide screen blkfade
    with d5
    call ctc

    her ".............." ("base", "narrow", "base", "up", cheeks="blush", trans=d3)

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "-Grab her tits-":
            call nar(">You reach forward and grab a hold of Hermione's tits.")

            call her_chibi_scene("grope_tits")

            her "[genie_name]!" ("shock", "happyCl", "worried", "mid")
            her "This wasn't part of the deal!" ("open", "happyCl", "worried", "mid")
            her "And I was almost about to--" ("annoyed", "narrow", "angry", "R", cheeks="blush")
            gen "Can't let you have all the fun by yourself can we [hermione_name]." ("base", xpos="far_left", ypos="head")
            her "*Ah*...{w=0.4}{heart} Well, as long as it's just to make this end faster..." ("open", "narrow", "base", "up", cheeks="blush")
            her "I suppose I can...{w=0.4} *Ah*...{w=0.4}{heart} allow it..." ("base", "narrow", "base", "down", cheeks="blush")
            call nar(">You give her tits a couple of firm squeezes...")
            gen "Just admit that you love it." ("base", xpos="far_left", ypos="head")
            her "*Ah*...{w=0.4} fine...{heart}" ("open", "happyCl", "worried", "mid", cheeks="blush")
            her "{size=-5}I like it...{/size}" ("soft", "narrow", "annoyed", "up")
            gen "What was that [hermione_name]?" ("base", xpos="far_left", ypos="head")
            her "......." ("normal", "narrow", "annoyed", "up")
            her "I love this..." ("grin", "narrow", "base", "dead")
            her "Standing here... all exposed..." ("base", "narrow", "worried", "down_soft", cheeks="blush")
            her "*Ah*...{w=0.4} while you play with me...{heart}" ("grin", "narrow", "base", "up", cheeks="blush")
            gen "Heh... Nice." ("base", xpos="far_left", ypos="head")
            her "*Ah*...{heart}" ("open", "narrow", "base", "up", cheeks="blush")
            her "I sometimes wish I could spend all day in here..." ("grin", "narrow", "angry", "dead", cheeks="blush")
            gen "Perhaps we could arrange that some time..." ("base", xpos="far_left", ypos="head")
            call nar(">You keep on massaging the girl's breasts...")
            her "......."
            her "[genie_name]... I...{w=0.4} Please...{w=0.4} I was so close..." ("open", "base", "worried", "L", cheeks="blush")
            her "*Ah*...{heart}" ("base", "narrow", "worried", "down")
            her "Could you touch me...{w=0.4} down there..." ("open", "happy", "base", "mid", cheeks="blush")
            gen "What was that [hermione_name]? You'll have to speak up." ("base", xpos="far_left", ypos="head")
            her "Please finger me..." ("open", "narrow", "base", "up", cheeks="blush")
            gen "One more time, a little louder this time." ("base", xpos="far_left", ypos="head")
            her "*Ah*...{heart} {size=+5}please finger my pussy!{/size}" ("scream", "narrow", "base", "up", cheeks="blush")
            gen "As you wish..." ("base", xpos="far_left", ypos="head")
            call her_chibi_scene("grope_ass_front")
            with vpunch
            $ renpy.play("sounds/slick_02.ogg")

            call nar(">You swiftly plunge two fingers into her dripping pussy.")

            her "{heart}{heart}{size=+5}!!!{/size}{heart}{heart}" ("open_wide_tongue", "narrow", "annoyed", "up")

        "-Finger her-":
            call her_chibi_scene("grope_ass_front")
            call nar(">You run your hands up and down Hermione's legs...")
            her "!!!" ("open", "happyCl", "worried", "mid")
            call nar(">And slowly move your hands towards her pussy...")
            her "................." ("silly", "narrow", "base", "dead")
            gen "That's it [hermione_name]..." ("base", xpos="far_left", ypos="head")
            her "{size=-7}[genie_name]...{/size}" ("soft", "narrow", "annoyed", "up")
            gen "Good girl." ("base", xpos="far_left", ypos="head")
            her "...................." ("open", "closed", "base", "mid", cheeks="blush")
            gen "Just be quiet for a second..." ("base", xpos="far_left", ypos="head")
            call nar(">You enjoy the sensation of stroking the inside of Hermione's thighs...")
            call nar(">Kneading her gently and moving ever closer to her wet pussy...")
            gen "I love your big... firm, ass..." ("base", xpos="far_left", ypos="head")
            call nar(">As you get closer to her pussy you suddenly move your hands around her back to squeeze her ass...")
            her "....................." ("annoyed", "base", "annoyed", "dead", cheeks="blush")
            gen "Your loins..." ("base", xpos="far_left", ypos="head")
            call nar(">You slide your fingers across the side of her body as you return to the front, and then gently begin rubbing your forefinger just above her clit.")
            her ".....................{size=-8} [genie_name]...{/size}" ("silly", "narrow", "base", "dead", cheeks="blush")
            gen "What was that, [hermione_name]?" ("base", xpos="far_left", ypos="head")
            her "....................." ("annoyed", "wink", "base", "mid", cheeks="blush")
            her "... I...{w=0.4} {size=-5}... I need you...{w=0.4} inside of me...{/size}" ("disgust", "narrow", "base", "down", cheeks="blush")
            gen "You'll have to speak up if you expect me to hear you..." ("base", xpos="far_left", ypos="head")
            her "I...{w=0.4} *Ah*...{w=0.4}{heart} need..." ("open", "narrow", "base", "up", cheeks="blush")
            call nar(">You swiftly plunge two fingers into her drenched pussy.")
            $ renpy.play("sounds/slick_02.ogg")
            her "!!!{heart}{heart}" ("grin", "narrow", "annoyed", "up")
            call nar(">You start to pump your fingers inside her before she can do more than gasp.")
            play bg_sounds "sounds/slickloop.ogg"
            her "{size=+10}{heart}{heart}!!!{heart}{heart}{/size}" ("silly", "narrow", "base", "dead")
            gen "That's it [hermione_name]. Just enjoy yourself." ("base", xpos="far_left", ypos="head")
            her ".................................................." ("base", "narrow", "base", "up", cheeks="blush")
            gen "Do you like this?" ("base", xpos="far_left", ypos="head")
            gen "You like it when I finger your pussy?" ("base", xpos="far_left", ypos="head")
            her "I love it!{heart}{w=0.4} I love your fingers in my tight...{w=0.4} wet....{w=0.4} pussy!!{heart}" ("silly", "narrow", "annoyed", "up")
            gen "Well, I certainly think we can do better..." ("base", xpos="far_left", ypos="head")
            call nar(">with your other hand, you start rubbing your thumb against her clit.")
            her "{size=+10}!!!{/size}" ("open", "narrow", "base", "up", cheeks="blush")

    play bg_sounds "sounds/slickloopfast.ogg"
    call nar(">With little need to move, Hermione pounds herself down to the base of your fingers.")
    her "*Ah*...{heart}{w=0.4} please...{w=0.4}{heart} keep...{heart}" ("silly", "narrow", "base", "dead", cheeks="blush")
    her "Fingering my pussy!{heart}{heart}" ("silly", "narrow", "annoyed", "up", cheeks="blush")
    gen "As you command!" ("grin", xpos="far_left", ypos="head")
    call nar(">You force another finger into her pussy!")
    $ renpy.play("sounds/slick_02.ogg")
    play bg_sounds "sounds/slickloopveryfast.ogg"
    her "*Ah*...{w=0.4} yes! {heart}iloveitiloveitiloveit!{heart}" ("scream", "wide", "annoyed", "dead", cheeks="blush")
    gen "what do you love, [hermione_name]?" ("base", xpos="far_left", ypos="head")
    her "Ah!!{heart} I love your fingers in my pussy [genie_name]!{heart}" ("open_wide_tongue", "happyCl", "annoyed", "dead", cheeks="blush")
    call nar(">Hermione's legs begin to shake slightly as you finger her with renewed vigour.")
    gen "are you about to--" ("base", xpos="far_left", ypos="head")
    her "*Ah*...{heart} yes!!" ("mad", "narrow", "annoyed", "dead", cheeks="blush")
    her "I'm about to cum [genie_name]!!{heart}" ("grin", "narrow", "base", "dead", cheeks="blush")
    her "From being fucked by your fingers!!{heart}{heart}" ("open_tongue", "base", "base", "ahegao", cheeks="blush")
    gen "Touch your tits [hermione_name]!" ("base", xpos="far_left", ypos="head")
    gen "I want to see you play with them as you cum." ("base", xpos="far_left", ypos="head")

    $ hermione.set_body_zorder(armright=3)
    $ hermione.set_body(armright="on_tits")

    her "*Ah*...{w=0.4} Yes...{w=0.4}*Ah*... my--" ("soft", "narrow", "base", "dead", cheeks="blush")
    her "[genie_name]{heart}... I'm...*Ah*...{w=0.4} I'm cumming!{heart}" ("silly", "narrow", "annoyed", "dead", cheeks="blush")
    her "{heart}{heart}{heart}!!!{heart}{heart}{heart}" ("silly", "narrow", "base", "dead", cheeks="blush")
    with kissiris
    with hpunch
    $ renpy.play("sounds/slick_01.ogg")
    #
    # TODO: CUM LAYERS
    #
    her "*Ah*...{w=0.4}{heart}...{heart}" ("grin", "narrow", "annoyed", "dead", cheeks="blush")
    with kissiris
    with hpunch
    $ renpy.play("sounds/slick_01.ogg")
    her "*Ah*...{w=0.4} *Ah*...{heart}" ("silly", "narrow", "annoyed", "dead", cheeks="blush")
    with kissiris
    with hpunch
    $ renpy.play("sounds/slick_01.ogg")
    her "*Mmmmmmh*!!!" ("soft", "base", "annoyed", "dead", cheeks="blush")
    her "........................" ("grin", "base", "annoyed", "dead", cheeks="blush")
    stop bg_sounds

    if hermione.is_worn("bottom"):
        call nar(">You remove your hands from underneath Hermione's skirt, fingers drenched by her love juices.")
    else:
        call nar(">You remove your hands from Hermione's love canal, fingers drenched by her love juices.")

    call her_chibi_scene("behind_desk_front")
    show screen bld1
    with d3

    # Reset pose
    $ hermione.set_body_zorder(armright=0)
    $ hermione.set_body(armleft="down", armright="down")
    $ hermione.set_pose(None)

    gen "This shall do for now [hermione_name]." ("base", xpos="far_left", ypos="head")

    her "*Ah*...{w=0.4} *Ah*...{heart}" ("open", "narrow", "annoyed", "dead", cheeks="blush")
    her "Yes...{w=0.4} yes, [genie_name]{heart}" ("silly", "narrow", "base", "mid_soft", cheeks="blush")

    $ hermione.wear("all")
    $ renpy.music.set_volume(1.0, 3.0)

    jump end_hg_pf_strip
