
label hg_ps_get_panties:
    # Public shaming: Panty thief
    hide hermione_main
    with d3
    gen "{size=-4}(I could ask her to take off her panties and give them to me before she leaves for classes today.){/size}" ("base", xpos="far_left", ypos="head")

    menu:
        "\"(Yes, let's do it!)\"":
            pass
        "\"(Not right now.)\"":
            jump hermione_favor_menu

    gen "[hermione_name]?" ("base", xpos="far_left", ypos="head")
    her "I am listening, [genie_name]." (xpos="right",ypos="base")
    gen "I will need your panties..." ("base", xpos="far_left", ypos="head")

    if not hg_strip.trigger:
        jump too_much

    elif hg_ps_get_panties.points == 0:
        stop music fadeout 10.0

        her "W-what?" ("open", "base", "worried", "mid")
        her "My... panties...?"
        her "[genie_name], this is--"
        gen "This is the favour I will be buying from you today, [hermione_name]..." ("base", xpos="far_left", ypos="head")
        gen "If you are not interested you are more than welcome to leave." ("base", xpos="far_left", ypos="head")
        her "No, I am interested. I am.... it's just..."
        her "You need my..."

        call play_music("chipper_doodle")

        her "... panties, [genie_name]?" ("angry", "base", "angry", "mid")
        gen "Yes I do..." ("base", xpos="far_left", ypos="head")
        her "May I ask what you are planning to do with them...?" ("disgust", "narrow", "base", "mid_soft")
        gen "*Ehm*... I'm conducting research..." ("base", xpos="far_left", ypos="head")
        her "But this is kind of inappropriate, don't you think?"
        gen "But don't you hate it that some of the girls from Slytherin..." ("base", xpos="far_left", ypos="head")
        gen "Are selling favours for house points, [hermione_name]?" ("base", xpos="far_left", ypos="head")
        her "Yes I do!" ("angry", "base", "angry", "mid")
        her "(Those Slytherin tramps have no dignity.)" ("annoyed", "narrow", "angry", "R")
        gen "Well, there you go then!" ("base", xpos="far_left", ypos="head")
        her "*huh*?" ("disgust", "narrow", "base", "mid_soft")
        gen "Beat them at their own game!" ("base", xpos="far_left", ypos="head")
        her "What?" ("open", "base", "base", "mid")
        gen "Yes! Don't just put the Gryffindor house back on top..." ("base", xpos="far_left", ypos="head")
        gen "But do it by beating them at their own game!" ("base", xpos="far_left", ypos="head")
        her "[genie_name]..." ("open", "base", "worried", "mid")
        gen "As headmaster, I cannot play favourites. But you know how I feel about Gryffindor..." ("base", xpos="far_left", ypos="head")
        gen "I wish I could give you the points but that would ruin the system..." ("base", xpos="far_left", ypos="head")
        hide hermione_main
        with d3

        if hermione.is_worn("panties"):
            $ hermione.strip("robe", "accessory")
            $ hermione.strip("panties")
            call nar(">Suddenly Hermione bends forward and takes off her panties.","start")
        else:
            if hermione.is_any_worn("robe", "top", "bottom"):
                call nar(">Suddenly Hermione reaches inside one of her hidden pockets.","start")
            else:
                call nar(">Suddenly Hermione reaches inside--","start")
                call nar(">Wait, she's not exactly clothed...{w=0.4} Well then...")
                call nar(">By some kind of magic, a pair of panties suddenly appears in her hand.")

        call nar(">She extends her arm to you, clutching a little piece of fabric in her fist.","end")
        gen "??!" ("base", xpos="far_left", ypos="head")
        her "Just take them, [genie_name]..." ("mad", "base", "worried", "mid", tears="soft")
        call nar(">Slightly surprised, you take the panties from her hand.")
        gen "What? When did you?" ("base", xpos="far_left", ypos="head")
        her "Your speech was so moving..."
        her "You are so right, [genie_name]! I shall beat them at their own game!"
        her "My classes are about to start, so I should probably go now..."
        her "..........." ("normal", "base", "base", "R",tears="soft")
        her "I hope nobody will notice that I have no underwear on today..." ("annoyed", "base", "worried", "R")
        her "Oh, and I will be back tonight to pick them up, [genie_name]." ("open", "base", "base", "mid")
        gen "Of course. Your panties will be right here on my desk, waiting for you..." ("base", xpos="far_left", ypos="head")
        her "............." ("angry", "happyCl", "worried", "mid",emote="sweat")

    else:
        label dev:
        if hg_ps_get_panties.points > 0:
            her "Again, [genie_name]?"
            gen "Yes, again..." ("base", xpos="far_left", ypos="head")

        her "Here..."

        if her_whoring >= 12:
            hide hermione_main
            with d3

            if hermione.is_worn("panties"):
                $ hermione.strip("robe", "accessory")
                $ hermione.strip("panties")
                call nar(">Suddenly Hermione bends forward and takes off her panties.", "start")
            else:
                if hermione.is_any_worn("top", "bottom"):
                    call nar(">Hermione pulls her panties out of her pocket.", "start")
                else:
                    call nar(">Suddenly Hermione reaches inside--","start")
                    call nar(">Wait, she's not exactly clothed...{w=0.4} Well then...")
                    call nar(">By some kind of magic, a pair of panties suddenly appears in her hand.")

            call nar(">She casually throws them on your desk.", "end")

            gen "What?" ("base", xpos="far_left", ypos="head")
            her "Yes, I had a feeling that you might ask for these today, [genie_name]." ("base", "base", "base", "mid")
            gen "A feeling?" ("base", xpos="far_left", ypos="head")
            her "Well, to be completely honest I just do not bother to wear them much anymore..." ("grin", "base", "base", "R")

            if hermione.is_equipped("panties"):
                her "Unless I'm asked to, that is..."

        else:
            hide hermione_main
            with d3

            if hermione.is_worn("panties"):
                $ hermione.strip("robe", "accessory")
                $ hermione.strip("panties")
                call nar(">Hermione takes off her panties without hesitation.", "start")
            else:
                if hermione.is_any_worn("top", "bottom"):
                    call nar(">Suddenly Hermione reaches inside one of her hidden pockets.", "start")
                else:
                    call nar(">Suddenly Hermione reaches inside--", "start")
                    call nar(">Wait, she's not exactly clothed...{w=0.4} Well...")
                    call nar(">Magically, a pair of panties suddenly appears in her hand.")

            call nar(">She casually throws the offending underwear on your desk.", "end")

        her "Classes are about to start, so I'd better go now..." ("soft", "base", "base", "mid")

    call her_walk(action="leave")

    call give_reward(">You have acquired Hermione's panties!", "interface/icons/panties.webp")
    $ hg_ps_get_panties.inProgress = True

    jump end_hermione_event


label hg_cum_on_panties_response:
    # Hermione responds the cum on her panties

    call give_reward("> You hand over the panties...", "interface/icons/panties_cum.webp")

    if her_tier == 2:
        her "*Hmm*....?" ("annoyed", "narrow", "worried", "down",xpos="right",ypos="base")
        her "[genie_name]? What is this?" ("angry", "base", "angry", "mid")
        her "What have you done to them?"
        her "They are covered in something slimy..." ("normal", "squint", "angry", "mid")

        menu:
            "\"An experiment went wrong\"":
                her "An experiment went wrong, [genie_name]?" ("open", "base", "base", "mid")
                gen "Yes... Or maybe I should rather say..." ("base", xpos="far_left", ypos="head")
                gen "\"An experiment went very right\"? *He-he*..." ("grin", xpos="far_left", ypos="head")
                her ".....................?" ("normal", "squint", "angry", "mid")
                her "What kind of experiment was it?"
                gen "What? Oh..." ("base", xpos="far_left", ypos="head")
                gen "Some top secret research I'm conducting." ("base", xpos="far_left", ypos="head")
                gen "I can't discuss it with a student." ("base", xpos="far_left", ypos="head")
                her "................................" ("angry", "base", "angry", "mid")
            "\"You gave them to me like this!\"":
                her "I most certainly did not, [genie_name]!"
                her ".........................."

        her "Well, these will require some serious cleaning before I can put them on again..." ("annoyed", "narrow", "worried", "down")
        gen "Or you could put them on now." ("base", xpos="far_left", ypos="head")
        her "What?" ("open", "base", "base", "mid")
        her "I really would rather not, [genie_name]..." ("soft", "base", "base", "R")

        menu:
            "\"Put them on or lose the points!\"":
                $ her_mood +=7
                her "What?" ("scream", "wide", "base", "mid")
                her "[genie_name], you are joking, right?"
                gen "I am not..." ("base", xpos="far_left", ypos="head")
                her "B-but..." ("open", "base", "base", "mid")
                her "........................................" ("normal", "happyCl", "worried", "mid")
                her "{size=-5}Must you always have your way, [genie_name]?{/size}" ("angry", "base", "angry", "mid")
                gen "What was that, [hermione_name]?" ("base", xpos="far_left", ypos="head")
                her "It's nothing, [genie_name]." ("scream", "closed", "angry", "mid")
                her "Putting my panties back on!"
                hide hermione_main
                call nar(">Hermione hesitantly puts on her panties.","start")

                if hermione.is_equipped("panties"):
                    $ hermione.wear("panties")
                else:
                    $ hermione.equip(her_panties_base1)

                call nar(">A tiny stream of cum trickles down her leg.")
                call nar(">Hermione looks very uncomfortable.","end")
                her "......................" ("angry", "happyCl", "worried", "mid",emote="sweat")

            "\"Well, suit yourself...\"":
                pass

        her "And my payment?" ("open", "base", "base", "mid")

    elif her_tier == 3:
        her "My panties..." ("annoyed", "narrow", "worried", "down",xpos="right",ypos="base")
        her "What happened to them [genie_name]?" ("annoyed", "narrow", "worried", "down")

        menu:
            "\"An experiment went wrong.\"":
                her "*Hmm*..."
                her "I see..."

            "\"You gave them to me like this!\"":
                her "Did I? Oh, well..."

        hide hermione_main
        call nar(">Hermione gives her cum-soaked underwear a quizzical look.")
        her "Seems like these will require some serious cleaning before I can put them on again..." ("annoyed", "narrow", "worried", "down")
        gen "Why not put them on now?" ("base", xpos="far_left", ypos="head")
        her "*Hmm*...?" ("annoyed", "squint", "base", "mid")
        her "Well, I suppose I could wear them one more time before putting them into laundry..." ("annoyed", "narrow", "worried", "down")
        hide hermione_main
        call nar(">Hermione puts on the panties.")

        if hermione.is_equipped("panties"):
            $ hermione.wear("panties")
        else:
            $ hermione.equip(her_panties_base1)

        her "(This feels funny...)" ("angry", "happyCl", "worried", "mid",emote="sweat")
        her "And my payment, [genie_name]?" ("upset", "wink", "base", "mid")


    elif her_tier == 4:
        her "My panties..." ("annoyed", "narrow", "worried", "down",xpos="right",ypos="base")
        her "They are covered in something slimy..."
        her "And they smell funny..."
        her "*Hmm*... That smell..." ("annoyed", "base", "worried", "R")
        her "It's familiar somehow..."
        her "What exactly did you do to them, [genie_name]?" ("base", "base", "base", "mid")

        menu:
            "\"An experiment went wrong\"":
                her "An experiment, *huh*?"
                her "Of what nature?"
                her "No, don't answer that... I think I know..." ("smile", "base", "base", "R")

            "\"You gave them to me like this!\"":
                her "I don't think so, [genie_name]."
                her "But it's alright if you don't want to tell me, [genie_name]..."
                her "I think I know exactly what happened to them..."

            "\"I came all over them!\"":
                her "I knew it..." ("smile", "narrow", "base", "mid_soft")
                her "They reek of semen!"

        her "*Hmm*..." ("grin", "base", "base", "R")
        her "Seems like these will require some serious cleaning before I can put them on..."
        her "Unless you want me to put them on now, [genie_name]...?" ("smile", "narrow", "base", "mid_soft")

        menu:
            "\"Yes! Put them on now, [hermione_name]!\"":
                her "Well, if I must..."

            "\"I don't care. Do what you want.\"":
                her "Why not put them on one more time?"

        her "I am only doing this to give my house a fair chance at winning the cup this year..." ("base", "happyCl", "base", "mid")
        gen "Right..." ("base", xpos="far_left", ypos="head")
        hide hermione_main
        call nar(">Hermione swiftly slides into her drenched panties...")

        if hermione.is_equipped("panties"):
            $ hermione.wear("panties")
        else:
            $ hermione.equip(her_panties_base1)

        gen "You can go now." ("base", xpos="far_left", ypos="head")
        her "What about my points?" ("scream", "closed", "angry", "mid")
        gen "You still want points after I just gave you a gift?" ("base", xpos="far_left", ypos="head")
        her "What gift?"
        gen "You're wearing it." ("base", xpos="far_left", ypos="head")
        her "What, semen soaked panties?"
        gen "If you'd prefer the points then just take them off." ("base", xpos="far_left", ypos="head")
        her "well... I am already wearing them!" ("annoyed", "base", "worried", "R")
        gen "Then say \"thank you\" for the gift." ("base", xpos="far_left", ypos="head")
        her "Thank you, [genie_name]...{w=0.3} for the gift." ("annoyed", "squint", "base", "mid")
        gen "You can go now." ("base", xpos="far_left", ypos="head")
        her "Good night, [genie_name]."

    elif her_tier >= 5:
        her "My panties..." ("base", "narrow", "base", "up",xpos="right",ypos="base")
        her "You came all over them..."
        her "*Hmm*..." ("grin", "base", "base", "R")
        her "Seems like these will require some serious cleaning before I can put them on..."
        her "Unless you want me to put them on now, [genie_name]...?" ("smile", "narrow", "base", "mid_soft")

        menu:
            "\"Yes! Put them on now, [hermione_name]!\"":
                her "Yes [genie_name]..."
                her "I am only doing this to give my house a fair chance at winning the cup this year." ("smile", "happyCl", "base", "mid")
                her "I don't like how it feels at all..." ("base", "narrow", "base", "up")
                gen "Right..." ("base", xpos="far_left", ypos="head")
                hide hermione_main
                call nar(">Hermione swiftly slides her drenched panties on...")

                if hermione.is_equipped("panties"):
                    $ hermione.wear("panties")
                else:
                    $ hermione.equip(her_panties_base1)

                her "..." ("soft", "narrow", "annoyed", "up")
            "\"Why don't you clean them now?\"":
                her "Clean them How? You don't have a wash basin in here." ("open", "base", "base", "mid")
                gen "You're right, you'll have to use your mouth then." ("base", xpos="far_left", ypos="head")
                her "My mouth?!" ("scream", "wide", "base", "mid")
                gen "What's the big deal? It wouldn't be the first time you've tasted my cum." ("base", xpos="far_left", ypos="head")
                her "It's a bit different! I wore these panties before I gave them to you." ("scream", "closed", "angry", "mid")
                her "Not to mention that your cum is all cold and slimy..." ("scream", "happyCl", "worried", "mid")
                gen "Well in that case hand them back." ("base", xpos="far_left", ypos="head")
                her "What? Can't I just put them on?" ("angry", "wink", "base", "mid")
                gen "I'm afraid not, you clean them now or you hand them back." ("base", xpos="far_left", ypos="head")
                her "{size=-4}Fine...{/size}" ("angry", "narrow", "base", "down")
                gen "What was that?" ("base", xpos="far_left", ypos="head")
                her "I said I'll clean them ok!" ("shock", "happyCl", "worried", "mid")
                gen "Well..." ("base", xpos="far_left", ypos="head")
                her "..." ("angry", "narrow", "base", "down")
                call nar(">Hermione reluctantly puts her cum-soaked panties in her mouth.")
                $ renpy.play('sounds/gltch.ogg')
                her "*Mmmmhhhhh*!" ("full_panties", "slit", "worried", "ahegao")
                gen "That's it, not as bad as you thought now is it?" ("base", xpos="far_left", ypos="head")
                her "..." ("full_panties", "slit", "low", "stare")
                gen "Make sure you get them nice and clean now..." ("base", xpos="far_left", ypos="head")
                call play_sound("gulp")
                her "*gulp*" ("full_panties", "narrow", "worried", "down",cheeks="blush")
                gen "That's it. Do you think they're clean yet?" ("base", xpos="far_left", ypos="head")
                her "*Mmmhhhmmm*" ("full_panties", "narrow", "base", "dead")
                gen "Open your mouth, [hermione_name]." ("base", xpos="far_left", ypos="head")
                $ renpy.play('sounds/gltch.ogg')
                her "*Ahhhhh*" ("open_wide_tongue_panties", "narrow", "annoyed", "up")
                gen "That's a good girl, your panties are now nice and clean." ("base", xpos="far_left", ypos="head")
                gen "You can take them out now." ("base", xpos="far_left", ypos="head")
                her "...." ("angry", "happyCl", "worried", "up")

        gen "You can go..." ("base", xpos="far_left", ypos="head")
        her "yes, [genie_name]..." ("angry", "narrow", "base", "down")
        gen "After you say \"thank you\"..." ("base", xpos="far_left", ypos="head")
        her "Thank you for what?" ("angry", "wink", "base", "mid")
        gen "For my cum." ("base", xpos="far_left", ypos="head")
        her "..." ("base", "narrow", "worried", "down")
        her "Thank you for your cum, [genie_name]..." ("grin", "narrow", "base", "dead")
        gen "You may go now." ("base", xpos="far_left", ypos="head")
        her "Good night, [genie_name]."

    $ achievements.unlock("pantiesfap")
    jump back_from_soaked


label hg_ps_get_panties_complete:
    # Hermione returns to get her panties back

    $ hermione.strip("panties")

    call her_walk(action="enter", xpos="mid", ypos="base")

    her "Good evening, [genie_name]..." ("base", "base", "base", "mid",xpos="right",ypos="base")
    call play_music("chipper_doodle")

    menu:
        "\"Here are your panties.\"":
            if her_panties_soaked:
                jump hg_cum_on_panties_response
            else:
                her "And my payment?"

        "\"How was your day, [hermione_name]?\"":
            if her_tier == 2:
                her "Oh..." ("soft", "base", "base", "mid",xpos="base",ypos="base", trans=d5)
                her "Quite ordinary actually..."
                her "Although... I couldn't help but worry that somebody would notice somehow..." ("soft", "base", "base", "R")
                her "....." ("annoyed", "base", "worried", "R")
                her "Can I have my panties back now?" ("open", "base", "base", "mid",xpos="right",ypos="base",trans=fade)
                gen "Of course..." ("base", xpos="far_left", ypos="head")
                hide hermione_main
                with d3
                call nar(">You give Hermione her panties back.")
                if her_panties_soaked:
                    jump hg_cum_on_panties_response
                else:
                    her "And my payment?" ("open", "base", "base", "mid")

            elif her_tier == 3:
                her "Oh..." ("soft", "base", "base", "mid",xpos="base",ypos="base", trans=d5)
                her "It was quite ordinary really..."
                her "I spent some time with my classmates..."
                her "And we had a short \"MRM\" meeting after that..."
                her "I gave a short speech on \"Why it is wrong to sell sexual favours in exchange for house points\"..." ("open", "closed", "base", "mid")
                her "I felt bad that I had to give the speech without any underwear on..." ("annoyed", "narrow", "angry", "R")
                her "" (xpos="right",ypos="base",trans=fade)

                menu:
                    "\"You little hypocrite!\"":
                        $ her_mood +=5
                        her "[genie_name]?" ("open", "base", "base", "mid")
                        gen "You sold your panties to me this morning..." ("base", xpos="far_left", ypos="head")
                        gen "And a couple of hours later you already publicly condemned that exact behaviour..." ("base", xpos="far_left", ypos="head")
                        #gen "What would you call this?" ("base", xpos="far_left", ypos="head")
                        #her "I know you are right, [genie_name]..." ("annoyed", "narrow", "angry", "R")
                        her "(But we need the points...)" ("annoyed", "narrow", "angry", "R")
                        her "Can I have my payment now please?" ("disgust", "narrow", "base", "mid_soft")
                        gen "What about your panties?" ("base", xpos="far_left", ypos="head")
                        her "Oh, them too of course..." ("angry", "happyCl", "worried", "mid",emote="sweat")
                        if her_panties_soaked:
                            jump hg_cum_on_panties_response

                    "\"It's for the greater good...\"":
                        her "Exactly!"
                        her "We need those points badly..."
                        her "It is not my fault that the system is so corrupted..."
                        her "I shall remain a symbol of righteousness to my peers, no matter what!" ("open", "closed", "base", "mid")
                        her "Can I have my panties back now, please?" ("open", "base", "base", "mid")
                        if her_panties_soaked:
                            jump hg_cum_on_panties_response
                        else:
                            her "And my payment."

            elif her_tier >= 4:
                her "Another ordinary day at hogwarts..." ("open", "closed", "base", "mid",xpos="base",ypos="base", trans=d5)
                her "Nothing worth mentioning happened today..."
                her "Although I have to admit..." ("annoyed", "base", "worried", "R")
                her "It was oddly empowering to have no underwear on..."
                her "*Hmm*..."
                her "Can I have my panties back now please?" ("base", "base", "base", "mid",xpos="right",ypos="base",trans=fade)
                gen "Of course..." ("base", xpos="far_left", ypos="head")
                hide hermione_main
                with d3
                call nar(">You give Hermione her panties back.")
                if her_panties_soaked:
                    jump hg_cum_on_panties_response
                else:
                    her "And my payment?" ("base", "base", "base", "mid")

    label back_from_soaked:
    if not her_panties_soaked or her_tier < 4:
        gen "Yes, yes..." ("base", xpos="far_left", ypos="head")
        $ gryffindor +=15
        gen "Fifteen points to Gryffindor, [hermione_name]. Well deserved." ("base", xpos="far_left", ypos="head")
        her "Thank you, [genie_name]..."
        gen "You can go now." ("base", xpos="far_left", ypos="head")
        her "Good night, [genie_name]."
        #gen "Yes, good night..." ("base", xpos="far_left", ypos="head")

    call her_walk(action="leave")

    $ hg_ps_get_panties.counter += 1
    $ hg_ps_get_panties.points += 1

    $ hg_ps_get_panties.inProgress = False
    $ her_panties_soaked = False

    jump end_hermione_event
