

### Tier 3 ###

# Invite Snape

label hg_pf_strip_T3_snape: # Fails
    hide screen blktone
    hide hermione_main
    with d3

    gen "[hermione_name], before you start I have one more favour to ask of you." ("base", xpos="far_left", ypos="head")

    her "Of course, [genie_name]." ("open", "closed", "base", "mid", xpos="base", ypos="base")
    gen "Do you think you could go and fetch professor Snape for me?" ("base", xpos="far_left", ypos="head")
    her "... Professor Snape?" ("annoyed", "squint", "base", "mid")
    her "May I ask, why, [genie_name]?"
    gen "Oh, I just think you could use a bigger audience for your striptease performance." ("base", xpos="far_left", ypos="head")
    her "My striptease performance...?!!" ("shock", "wide", "base", "stare")
    her "Are you completely out of your mind, [genie_name]?" ("angry", "base", "angry", "mid")
    her "Wasn't it enough that I've had to embarrass myself in front my teacher once before?" ("open", "base", "angry", "mid")
    her "And now you expect me to do it again... but willingly?!" ("scream", "closed", "angry", "mid")
    gen "Short answer... yes." ("base", xpos="far_left", ypos="head")
    her "I'm leaving!" ("angry", "base", "angry", "mid")

    call her_walk(action="leave")

    $ her_mood += 15
    $ hg_pf_strip.fail()

    jump end_hermione_event



### Tier 4 ###

# Invite Snape

label hg_pf_strip_T4_snape:
    if hg_strip.ss_counter == 0:
        $ hg_strip.ss_counter += 1

        hide screen blktone
        hide hermione_main
        with d3

        gen "[hermione_name], before you start I have one more favour to ask of you." ("base", xpos="far_left", ypos="head")

        her "Of course, [genie_name]." ("open", "closed", "base", "mid", xpos="base", ypos="base")
        gen "Do you think you could go and fetch professor Snape for me?" ("base", xpos="far_left", ypos="head")
        her "... Professor Snape?" ("annoyed", "squint", "base", "mid")
        her "May I ask, why, [genie_name]?"
        gen "Oh, I just think you could use a bigger audience for your striptease performance." ("base", xpos="far_left", ypos="head")
        her "My striptease performance...?!!" ("shock", "wide", "base", "stare")
        her "With all due respect, [genie_name]..." ("angry", "base", "angry", "mid")
        her "{size=-5}(Which I have oh so little left for you...){/size}" ("normal", "squint", "angry", "mid")
        her "I refuse to degrade myself for professor Snape's amusement!" ("scream", "closed", "angry", "mid")
        gen "No, no, you got it all wrong, [hermione_name]." ("base", xpos="far_left", ypos="head")
        her "*Hmm*...?" ("soft", "base", "base", "mid")
        gen "I want to prove that professor Snape is dirty, and I need your help." ("base", xpos="far_left", ypos="head")
        her "!!!" ("shock", "wide", "base", "stare")
        gen "Yes, I want to catch him in the act!" ("base", xpos="far_left", ypos="head")
        her "[genie_name], I didn't realise..." ("open", "base", "worried", "mid")
        her "I see now..." ("base", "base", "base", "mid")
        her "I am sorry for doubting you [genie_name]..."
        gen "No biggie. Now go find professor Snape and bring him here." ("base", xpos="far_left", ypos="head")
        her "Right away [genie_name]!" ("smile", "base", "angry", "mid")

    else:
        hide screen blktone
        hide hermione_main
        with d3

        gen "[hermione_name], before you start I have one more favour to ask of you." ("base", xpos="far_left", ypos="head")

        her "Of course, [genie_name]." ("open", "closed", "base", "mid", xpos="base", ypos="base")
        gen "Do you think you could go and fetch professor Snape again?" ("base", xpos="far_left", ypos="head")
        her "... professor Snape?" ("annoyed", "squint", "base", "mid")
        her "may I ask, why, [genie_name]?"
        gen "Oh, I just want you to dance for us." ("base", xpos="far_left", ypos="head")
        her "!!!" ("open", "base", "base", "mid")
        gen "I want to prove that professor Snape is dirty, and I need your help." ("base", xpos="far_left", ypos="head")
        her "But didn't we already establish that last time I did this?" ("annoyed", "base", "worried", "R")
        gen "Well, *Ehm*... sure..." ("base", xpos="far_left", ypos="head")
        gen "But I will need more proof if I am to take this issue to the ministry of magic!" ("base", xpos="far_left", ypos="head")
        her "....." ("angry", "base", "angry", "mid")
        gen "So, what do you say [hermione_name]?" ("base", xpos="far_left", ypos="head")
        gen "One more dance for the greater good?" ("base", xpos="far_left", ypos="head")
        her "Well, alright..." ("disgust", "narrow", "base", "mid_soft")
        gen "Good. Go find professor Snape then." ("base", xpos="far_left", ypos="head")

    call her_walk(action="leave")

    show screen blkfade
    with d5

    stop music fadeout 1.0
    pause 2
    ">Hermione returns with Snape a few moments later."

    call play_sound("door")
    call her_chibi("stand","desk","base")
    call sna_chibi("stand","mid","base")
    hide screen blkfade
    with d5
    pause.5

    call play_music("dark_fog")
    sna "Genie... err, I mean Albus, you wanted to see me?" ("snape_01", xpos="base", ypos="base")
    gen "Yes. Are you in the mood for a little striptease?" ("base", xpos="far_left", ypos="head")
    sna "Oh...?" ("snape_05")
    sna "Miss Granger here will be performing I assume?"
    her ".............." ("angry", "happyCl", "worried", "mid", emote="sweat", xpos="mid", ypos="base")
    gen "Yes, our little minx is more than happy to take off her clothes for our entertainment." ("base", xpos="far_left", ypos="head")
    her "............" ("angry", "happyCl", "worried", "mid", emote="sweat")
    gen "Aren't you [hermione_name]?" ("base", xpos="far_left", ypos="head")
    pause.5

    her "" ("angry", "happy", "worried", "R")
    pause 1

    her "" ("angry", "happy", "worried", "mid")
    pause 1.5

    her "Yes, [genie_name]." ("angry", "happyCl", "worried", "mid", emote="sweat")
    gen "Let's get started then!" ("base", xpos="far_left", ypos="head")
    hide hermione_main
    with d3
    pause.2
    sna "" ("snape_13")
    pause.8

    $ hermione.strip("robe", "accessory")
    hide snape_main
    show screen blkfade
    with d5

    $ renpy.play('sounds/08_hop_on_desk.ogg') #Sound of the desk squeaking.
    pause 3
    call her_chibi("dance","on_desk","on_desk")
    call sna_chibi("stand","desk_close","desk_close")

    # her "" (animation=bob)
    her "............." ("open", "closed", "base", "mid", ypos="head", flip=False)
    sna "......................" ("snape_05")
    gen ".........................." ("base", xpos="far_left", ypos="head")

    hide screen bld1
    hide screen blkfade
    with d5
    pause.8

    call bld
    gen "So... Severus... How's life?" ("base", xpos="far_left", ypos="head")
    sna "Well, you know... same old, same old..." ("snape_09")
    sna " The Students are causing me grief..." ("snape_06")
    sna "In fact, miss Granger here managed to cause me more stress than any other student..." ("snape_03")
    pause.2
    her "..............................." ("grin", "base", "base", "R", xpos="mid", ypos="base")
    gen "Oh, I am sure she is very sorry about that..." ("base", xpos="far_left", ypos="head")
    her "{size=-4}(Not even a little bit!){/size}" ("base", "happyCl", "base", "mid")
    gen "And will make up for it today, won't you, [hermione_name]?" ("base", xpos="far_left", ypos="head")
    pause.2

    her "*Ehm*... Yes, [genie_name]." ("base", "happy", "base", "mid")
    pause.2

    call nar(">Hermione starts to sway her hips seductively.")

    if hermione.is_worn("top"):
        call nar(">Hermione reaches to take off her top...")
        $ hermione.strip("top")

    call ctc

    her "..................." ("open", "narrow", "worried", "down")
    sna "*Hmm*... You are being suspiciously quiet, Miss Granger." ("snape_05")
    her "{size=-4}(Oh no! Is he onto us?){/size}" ("shock", "wide", "base", "stare")
    her "I'm just doing what the headmaster told me to, Professor Snape..." ("grin", "happyCl", "worried", "mid", emote="sweat")
    sna "Aren't you going to lecture me on the \"corruption that is taking over Hogwarts\" like you do every other day during classes?" ("snape_03")
    gen "Severus..." ("base", xpos="far_left", ypos="head")
    sna "No Albus, I want to hear what little miss perfect has to say." ("snape_03")
    her "I just want you to have a good time, Professor Snape..." ("grin", "happyCl", "worried", "mid", emote="sweat")
    sna "Oh! It's \"Professor Snape\" now, is it?" ("snape_03")
    sna "What happened to \"snape'o'doodle\" and \"Professor Snivellus\"??!" ("snape_10")
    gen "{size=-5}({i}snape'o'doodle{/i}, heh... that's funny.){/size}" ("grin", xpos="far_left", ypos="head")
    her "............." ("grin", "happyCl", "worried", "mid", emote="sweat")
    sna "Yes, I know what you are calling me behind my back, you wretched girl!" ("snape_08")
    her "Well, maybe that's because you deserve it... {i}Snivellus!{/i}" ("scream", "base", "angry", "mid", emote="angry")
    sna "{size=+2}What did you just say?!{/size}" ("snape_10")
    sna "How dare you....?"
    sna "Who do you think you are? You filthy mudbl--" ("snape_15")
    her "[genie_name], one of your staff members is verbally abusing me!" ("scream", "closed", "angry", "mid")
    her "Are you going to allow this?"
    sna "Verbally abusing...?! You have some nerve, girl!" ("snape_08")
    sna "Albus, will you allow her to talk back to a teacher like that?" ("snape_10")
    her "[genie_name]!" ("scream", "closed", "angry", "mid")
    sna "Albus!" ("snape_10")

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "\"[hermione_name], show some respect!\"":
            $ her_mood += 9
            her "What?" ("annoyed", "base", "angry", "mid")
            her "But [genie_name]!"
            gen "[hermione_name], you {size=+4}will{/size} calm down now." ("base", xpos="far_left", ypos="head")
            her "*Tsk*!" ("disgust", "narrow", "base", "mid_soft")
            if hermione.is_worn("bottom"):
                gen "And take off your bottoms already, would you?" ("base", xpos="far_left", ypos="head")
                her "......." ("annoyed", "narrow", "angry", "R")
            sna "..........." ("snape_13")

        "\"Severus, you started this.\"":
            $ sna_friendship -= 5
            sna "What? Me?!" ("snape_10")
            her "Thank you, [genie_name]." ("base", "base", "base", "mid")
            sna "Albus, you are spoiling the girl! She must be taught a lesson!" ("snape_08")
            gen "............... Severus." ("base", xpos="far_left", ypos="head")
            gen "Did you hit your head?!" ("angry", xpos="far_left", ypos="head")
            sna "I beg your pardon?" ("snape_03")
            gen "The girl is already stripping for you!" ("angry", xpos="far_left", ypos="head")
            gen "What punishment are you talking about?" ("angry", xpos="far_left", ypos="head")
            sna "*Tsk*... How about a flogging?" ("snape_16")
            gen "Severus!" ("angry", xpos="far_left", ypos="head")
            sna "Alright, alright, I see your point..." ("snape_17")
            gen "[hermione_name], are you going to strip or are you going to climb on my desk to give us a better view?" ("base", xpos="far_left", ypos="head")
            her "*Ehm*..." ("open", "narrow", "worried", "down")
            if hermione.is_worn("bottom"):
                gen "Take off your bottoms, [hermione_name]!" ("base", xpos="far_left", ypos="head")
                her "Yes, [genie_name]..." ("soft", "base", "base", "mid")

        "\"Both of you, calm the fuck down.\"":
            gen "You, tall-dark-and-handsome, calm down a bit, would you?" ("base", xpos="far_left", ypos="head")
            sna "I beg your pardon?" ("snape_03")
            her "Yes! You tell him profess--" ("annoyed", "narrow", "angry", "R")
            gen "You as well, you perverted little minx!" ("base", xpos="far_left", ypos="head")
            if hermione.is_worn("bottom"):
                gen "Calm down and take your bottoms off already." ("base", xpos="far_left", ypos="head")
            else:
                gen "Calm down and keep doing what you were paid to do!" ("base", xpos="far_left", ypos="head")
            her "I am not perverted..." ("annoyed", "narrow", "annoyed", "mid")
            if hermione.is_worn("bottom"):
                gen "Your bottoms, [hermione_name]!" ("base", xpos="far_left", ypos="head")
                her "......" ("annoyed", "narrow", "angry", "R")
            sna "............." ("snape_13")

        "-Unleash your rage {size=-2}(Hardcore){/size}-" if game.difficulty >= 3: #Hardcore difficulty dialogue.
            $ her_mood += 18
            $ sna_friendship -= 10
            gen "Both of you..." ("base", xpos="far_left", ypos="head")
            stop music
            with hpunch
            gen "Shut the fuck up!!!" ("angry", xpos="far_left", ypos="head")
            gen "You!... You good for nothing, ugly-faced, crooked-nosed-wannabe-wizard!" ("angry", xpos="far_left", ypos="head")
            with hpunch
            sna "(...)" ("snape_11")
            her "(... yikes!)" ("angry", "wink", "base", "mid")
            sna "(What did he just say to me?!)" ("snape_08")
            gen "Shut your stupid mouth or I will send you flying out that bloody window!" ("angry", xpos="far_left", ypos="head")
            gen "That bitch is already stripping for you, so what more do you want?!" ("angry", xpos="far_left", ypos="head")
            her "That B-Bitc--" ("shock", "wide", "base", "stare")
            gen "And you... stripper-whore!" ("angry", xpos="far_left", ypos="head")
            gen "Do what you are paid for and start stripping already!!!" ("angry", xpos="far_left", ypos="head")
            her "......" ("angry", "closed", "angry", "mid", emote="angry")
            sna "............." ("snape_05")
            her "..." ("mad", "squint", "angry", "mid")

    pause.5

    if hermione.is_worn("bottom"):
        call nar(">Hermione swiftly takes off her bottoms, showing off her muggle-born ass.")
        $ hermione.strip("bottom")
        call ctc

        sna "*Hmm*..."
        her "........................" ("open", "narrow", "worried", "down")
        gen "Yes, much better!" ("base", xpos="far_left", ypos="head")

    if hermione.is_worn("bra") and hermione.is_worn("panties"):
        call nar(">Hermione keeps on dancing, now wearing nothing but her underwear.")
    elif hermione.is_worn("bra"):
        call nar(">Hermione keeps on dancing, now wearing nothing but her bra.")
    elif hermione.is_worn("panties"):
        call nar(">Hermione keeps on dancing, now wearing nothing but her panties.")

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "\"Severus, what about that Potter boy?\"":
            her "(.....?)" ("soft", "base", "base", "mid")
            sna "What about him?" ("snape_09")
            gen "Is he still causing you grief?" ("base", xpos="far_left", ypos="head")
            sna "Oh..." ("snape_09")
            sna "Not really, no..."
            sna "To be honest I never really had a problem with the boy himself..." ("snape_06")
            sna "Although I did plan to make his life here miserable because of his father..."
            sna "But lately I have way more interesting projects to occupy myself with..." ("snape_02")
            her "..................." ("soft", "base", "base", "mid")

        "\"Severus, what about the Weasels?\"":
            sna "Weasels?" ("snape_05")
            sna "Oh you mean Weasley's..." ("snape_09")
            sna "What about them?" ("snape_09")
            gen "Are they still causing you trouble?" ("base", xpos="far_left", ypos="head")
            sna "Yes... More than ever." ("snape_09")
            gen "*Hmm*...?" ("base", xpos="far_left", ypos="head")
            gen "You seem surprisingly indifferent about that..." ("base", xpos="far_left", ypos="head")
            sna "That's because I know that they will get what they deserve eventually..." ("snape_05")
            gen "Revenge? Cool! What do you have in mind?" ("base", xpos="far_left", ypos="head")
            her "!!!" ("soft", "base", "base", "mid")
            sna "*Hmm*... Can't discuss this with \"the enemy\" present." ("snape_06")
            her "*Tsk*!" ("annoyed", "narrow", "angry", "R")
            sna "All I can say is that it involves their beloved little sister Ginny..." ("snape_13")
            gen "Ginny? *Hmm*... What a curious name for a girl..." ("base", xpos="far_left", ypos="head")
            gen "............." ("base", xpos="far_left", ypos="head")
            gen "So, you plan to fuck her then?" ("base", xpos="far_left", ypos="head")
            sna "!!?" ("snape_08")
            sna "Albus, please, not in front of the girl!" ("snape_17")
            gen "Alright, alright..." ("base", xpos="far_left", ypos="head")
            her "{size=-5}(Ginny...){/size}" ("open", "narrow", "worried", "down")

        "\"How would you grade Hermione's butt?\"":
            sna "miss Granger's buttocks?" ("snape_05")
            her "!!!............" ("annoyed", "narrow", "angry", "R")
            gen "Yes! As you would grade a paper." ("base", xpos="far_left", ypos="head")
            sna "*Hmm*..." ("snape_13")
            pause.1
            call nar(">Professor Snape gives Hermione's buttocks an appraising look...")
            her ".........?" ("upset", "wink", "base", "mid")
            sna "I would say..." ("snape_13")
            her "............?!" ("base", "narrow", "worried", "down")
            sna "Yes... \"Dreadful\"." ("snape_09")
            her "(What?!)" ("shock", "wide", "base", "stare")
            sna "Unsatisfactory..." ("snape_09")
            sna "Look at that pitiful thing. Tiny and skinny... That's a boy's butt."
            her "!!!!!!!!!!" ("angry", "narrow", "annoyed", "mid", emote="angry")

    if hermione.is_worn("bra"):
        gen "Why don't you take off your bra now, [hermione_name]?" ("base", xpos="far_left", ypos="head")
        her "............." ("open", "narrow", "worried", "down")
        call nar(">Hermione undoes her bra and then slowly takes it off.")
        pause .5
        $ hermione.strip("bra")

        call ctc
    else:
        call nar(">Hermione cups her breasts playfully, squeezing them in the process.")

    gen "Alright! We Finally get to the good stuff!" ("base", xpos="far_left", ypos="head")
    sna "*Hmm*..." ("snape_13")
    her "........" ("annoyed", "closed", "base", "mid")

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "-Start jerking off-":
            jump hg_pf_strip_T4_snape_masturbate

        "-Just keep on watching-":
            jump hg_pf_strip_T4_snape_watch

label hg_pf_strip_T4_snape_watch:
    call play_music("dark_fog")

    her "I will just keep on dancing then..." ("open", "closed", "base", "mid")

    # her "" (animation=bob)
    call her_chibi("dance","on_desk","on_desk")
    call ctc

    call nar(">Hermione squeezes her breasts and shakes her hips slightly...")

    gen "Yes, [hermione_name]. Very good." ("base", xpos="far_left", ypos="head")
    sna "*Ahem*! Acceptable performance, miss Granger." ("snape_12")
    her "...." ("open", "closed", "base", "mid")
    gen "Heh..." ("base", xpos="far_left", ypos="head")
    gen "So... how would you grade her tits?" ("base", xpos="far_left", ypos="head")
    her "......" ("annoyed", "closed", "base", "mid")
    sna "*Hmm*......" ("snape_20")
    her "........" ("annoyed", "closed", "base", "mid")
    sna "\"B+\"!" ("snape_12")
    her "!!!" ("open", "wide", "base", "stare")
    gen "Really?" ("base", xpos="far_left", ypos="head")
    sna "Yes. I do give credit where it's due." ("snape_12")
    her "(Professor...)" ("angry", "wide", "base", "stare")
    her "(Time for my finishing act then!)" ("open", "closed", "base", "mid")
    pause.1

    if hermione.is_worn("panties"):
        call nar(">Hermione bends over and slides her panties down.","start")
        ">Her movements lack grace..."
        call nar(">But a pretty pussy is always a welcome sight nonetheless...","end")
        pause.5

        $ hermione.strip("panties")

        call ctc

        sna "Yes... Yes..." ("snape_20")
    sna "Now shake those B+ titties for me, you harlot!"
    her "......." ("angry", "happyCl", "worried", "mid")

    pause.5

    call nar(">All of a sudden Hermione breaks into a series of rather complex pirouettes.")
    sna "Yes, such grace..." ("snape_19")
    sna "That lithe, flexible body!" ("snape_20")
    her "{size=-5}(Three-two-one... Three-two-one... And step!){/size}" ("open", "closed", "base", "mid")
    call nar(">Hermione seems very focused on her dancing routine.")
    sna "Yes, and now another pirouette!" ("snape_19")
    sna "Magnificent!"
    show screen blkfade
    with d5

    ">Hermione performs another set of movements and pirouettes..."
    ">Gives a little curtsy bow to the imaginary audience..."
    ">And then exhaustedly slumps down on her butt."

    call her_chibi("sit_naked","on_desk","on_desk")

    call hide_characters
    hide screen blktone
    hide screen bld1
    hide screen blkfade
    with d5
    call ctc

    show screen bld1
    sna "Good job, you harlot!" ("snape_22")
    her "............." ("soft", "happy", "base", "R", animation=None)

    if game.daytime:
        sna "Well, my class is about to start so I will be leaving now." ("snape_22")
        sna "Don't you have potion class with me today, Miss Granger?"
        her "Yes, [genie_name]..." ("annoyed", "narrow", "base", "dead")
        sna "Well, don't be late, girl..." ("snape_22")
        sna "Albus..." ("snape_02")
        gen "See you soon, Severus." ("grin", xpos="far_left", ypos="head")
    else:
        sna "Well, it is getting rather late. I think I will be leaving now." ("snape_22")
        sna "Good night, Albus."
        gen "Severus." ("base", xpos="far_left", ypos="head")
        sna "Harlot." ("snape_22")
        her "Professor..." ("annoyed", "narrow", "base", "dead")

    call ctc

    call hide_characters
    show screen blkfade
    with d5

    ">Professor Snape leaves..."
    stop music fadeout 1.0
    her "...................." ("annoyed", "narrow", "base", "dead", ypos="head", flip=False)
    pause.5

    her "May I... may I get paid now... [genie_name]...?" ("normal", "happyCl", "worried", "mid")

    jump end_hg_pf_strip

label hg_pf_strip_T4_snape_masturbate:
    call play_music("playful_tension")
    pause.2

    call hide_characters
    show screen blkfade
    with d5
    pause.2

    her "[genie_name]?!" ("open", "wide", "base", "stare", ypos="head", flip=False)
    gen "It's alright, [hermione_name]. Don't mind me..." ("base", xpos="far_left", ypos="head")
    sna "Oh, we're doing it like this then?" ("snape_12", ypos="head")
    sna "Well, don't mind if I do..." ("snape_12")
    her "!!!" (animation=None)

    call gen_chibi("jerk_off","behind_desk","base")
    call her_chibi("dance_pause","on_desk","on_desk")
    call sna_chibi("jerk_off","desk_close", "desk_close")
    hide screen blktone
    hide screen blkfade
    with d5
    call ctc

    her "No, guys... *Err*... I mean, sirs! *Ehm*... professors!" ("angry", "wide", "base", "stare", xpos="mid", ypos="base")
    gen "Don't you mind us [hermione_name], just keep on doing your thing." ("base", xpos="far_left", ypos="head")
    her "But..."
    her "No! I refuse to dance with those things pointed at me!" ("angry", "happyCl", "worried", "mid")
    her "You need to put them away or the dance is over!"
    gen "You aren't in any position to give us orders, [hermione_name]." ("base", xpos="far_left", ypos="head")
    her "that was not an order, [genie_name]. It was an ultimatum." ("clench", "base", "angry", "mid", emote="angry")

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "\"Alright Severus, let's be civil...\"":
            hide hermione_main
            with d3
            pause.2
            sna "I see Miss Granger manages to remain exceptionally stubborn in any situation..." ("snape_03")
            call hide_characters
            hide screen bld1
            with d5

            call gen_chibi("sit_behind_desk")
            call sna_chibi("stand","desk","base")
            with fade
            pause.3

            jump hg_pf_strip_T4_snape_watch

        "\"(Psst, Hermione! Remember why we are doing this!)\"":
            pass


    if her_tier < 5: # Hermione is NOT ok with it.
        $ her_mood += 15
        her "Oh..." ("open", "wide", "base", "stare")
        her "No, I can't! This is just not worth it!" ("angry", "happyCl", "worried", "mid")
        call hide_characters
        show screen blkfade
        with d5

        $ hermione.wear("all")
        ">Hermione jumps off the desk and starts to put her clothes back on."
        sna "Well, this was awfully anticlimactic..." ("snape_03")
        gen "You don't say..." ("angry", xpos="far_left", ypos="head")
        sna "May as well leave now I suppose. I will talk to you later, Albus." ("snape_03")
        gen "Yes, later, Severus." ("base", xpos="far_left", ypos="head")
        sna "Miss Granger..." ("snape_04")
        her "Professor..." ("angry", "happyCl", "worried", "mid", ypos="head", flip=False)

        call sna_chibi("hide")
        call gen_chibi("sit_behind_desk")
        call her_chibi("stand","desk","base")
        call play_sound("door")
        ">Professor Snape leaves."
        stop music fadeout 1.0
        hide screen blkfade
        with d5

        her "...................." ("annoyed", "narrow", "base", "dead", xpos="mid", ypos="base")
        call ctc

        her "... Can I get paid now... [genie_name]...?" ("normal", "happyCl", "worried", "mid")

        jump end_hg_pf_strip


    else: # Hermione IS ok with it.
        her "Oh, right..." ("shock", "wide", "base", "stare")
        sna "What was that?" ("snape_05")
        her "Please don't mind what I just said..." ("silly", "happyCl", "worried", "mid", emote="sweat")
        sna "*Hmm*...?" ("snape_05")
        her "I do not mind you touching yourself in front of me..." ("silly", "happyCl", "worried", "mid", emote="sweat")
        her "Yes, I do not mind it at all..."
        her "I will just keep on dancing then..."

        call her_chibi("dance","on_desk","on_desk")
        # her "" (animation=bob)

        call nar(">You keep on jerking off while you're watching Hermione dance.","start")
        call nar(">Hermione squeezes her breasts and shakes her hips slightly.","end")

        gen "Yes, [hermione_name]. Very good." ("base", xpos="far_left", ypos="head")
        sna "*Ahem*! Acceptable performance, miss Granger." ("snape_12")
        her "...................." ("angry", "happyCl", "worried", "mid")
        gen "Heh..." ("base", xpos="far_left", ypos="head")
        gen "So, how would you grade her tits?" ("base", xpos="far_left", ypos="head")
        her "......" ("open", "wide", "base", "stare")
        sna "*Hmm*......" ("snape_13")
        her "........" ("annoyed", "narrow", "angry", "R")
        sna "\"B+\"!" ("snape_12")
        her "!!!" ("open", "wide", "base", "stare")
        gen "Really?" ("base", xpos="far_left", ypos="head")
        sna "Yes. I do give credit where credit is due." ("snape_12")
        her "(Professor...)" ("annoyed", "closed", "base", "mid")
        her "(Time for my finishing act then!)" ("open", "closed", "base", "mid")
        pause.1

        if hermione.is_worn("panties"):
            pause.5
            $ hermione.strip("panties")
            call nar(">Hermione bends over and slides her panties down.","start")
            ">Her movements lack grace..."
            ">But a pretty pussy is always a welcome sight nonetheless..."
            call nar(">You show your appreciation by stroking your cock even faster...","end")
            call ctc

        sna "Yes... Yes!!!" ("snape_18")
        sna "Now shake those B+ titties for me, you harlot!"
        her "......." ("angry", "happyCl", "worried", "mid")
        pause.5

        call nar(">All of a sudden Hermione breaks into a series of rather complex pirouettes.")
        sna "Yes, such grace..." ("snape_19")
        sna "That lithe, flexible body!" ("snape_20")
        her "........." ("grin", "narrow", "annoyed", "up")
        sna "Oh, yes!" ("snape_20")
        her "{size=-5}(Three-two-one... Three-two-one... And step!){/size}" ("grin", "narrow", "annoyed", "up")
        call nar(">Hermione seems very focused on her dancing routine.")
        sna "Yes, and now another pirouette!" ("snape_19")
        sna "Magnificent!"
        sna "I would applaud you but one of my hands is very busy at the moment." ("snape_13")
        gen "{size=-4}(Was that an attempt at a joke?){/size}" ("base", xpos="far_left", ypos="head")
        gen "{size=-4}(Man, horny Snape is weird...){/size}" ("base", xpos="far_left", ypos="head")

        her "" (animation=None)
        call hide_characters
        show screen blkfade
        with d5

        ">Hermione performs another set of movements and pirouettes..."
        ">Gives a little curtsy bow to the imaginary audience..."
        ">And then exhaustedly slumps down on her butt."

        call her_chibi("sit_naked","on_desk","on_desk")

        hide screen blktone
        hide screen bld1
        hide screen blkfade
        with d5
        call ctc

        her "Whew... This was--" ("open", "closed", "base", "mid")
        with hpunch

        gen "*ARGH*! YOU FUCKING WHORE!" ("angry", xpos="far_left", ypos="head")
        hide screen bld1
        with d3

        call cum_block
        call gen_chibi("cum","behind_desk","base")
        pause.2

        $ hermione.set_cum(face="light")
        pause 0.7
        $ hermione.set_cum(breasts="light")
        pause 1
        $ hermione.set_cum(hair="light")


        her "??!!!" ("shock", "wide", "base", "stare")
        her "" ("angry", "happyCl", "worried", "mid")
        hide screen bld1
        with d3
        call ctc

        sna "Good job, you harlot!" ("snape_18")
        sna "Here is your reward!" ("snape_21")

        call cum_block
        call sna_chibi("cum","desk_close","desk_close")
        pause.2

        $ hermione.set_cum(face="heavy")
        pause 0.7
        $ hermione.set_cum(breasts="heavy", body="heavy")
        pause 1
        $ hermione.set_cum(crotch="light")

        her "!!!!!!!!!!!" ("shock", "wide", "base", "stare")
        hide screen bld1
        with d3
        call ctc

        sna "Oh... Yes..." ("snape_21")
        gen "Little slut!" ("angry", xpos="far_left", ypos="head")
        her "..............................." ("grin", "narrow", "annoyed", "up")

        sna "Ha-ha-ha! This is magnificent!" ("snape_21")
        gen "I know, right!?" ("grin", xpos="far_left", ypos="head")

        call gen_chibi("cum_done","behind_desk","base")
        call sna_chibi("cum_done","desk_close","desk_close")

        sna "Yes... We should do this more often." ("snape_22")
        her "................." ("grin", "narrow", "annoyed", "up")

        sna "Your performance was acceptable, miss Granger..." ("snape_20")
        her "Thank you........." ("annoyed", "narrow", "base", "dead")
        sna "But if I were to grade it..." ("snape_19")
        her "..........." ("annoyed", "narrow", "base", "dead")
        sna "*Hmm*...." ("snape_22")
        her "............" ("annoyed", "narrow", "base", "dead")
        sna "{size=+5}F+!{/size}" ("snape_10")
        stop music

        her "{size=+5}WHAT?!!!{/size}" ("shock", "wide", "base", "stare")
        sna "Yes... Quite a few things could use some improvement actually." ("snape_09")
        call play_music("chipper_doodle")
        her "I cannot believe this!" ("clench", "base", "angry", "mid", emote="angry")
        pause.5

        call hide_characters
        show screen blkfade
        with d5

        ">Hermione furiously jumps off your desk."
        pause 2
        hide hermione_main

        call sna_chibi("hold_dick","mid","base")
        call gen_chibi("sit_behind_desk")
        call her_chibi("stand","desk","base", flip=True)

        hide screen bld1
        hide screen blktone
        hide screen blkfade
        with d5
        call ctc

        her "I demand a higher grade than that!" ("soft", "base", "angry", "mid", xpos="right", ypos="base", flip=True)
        sna "You do not demand a grade miss Granger, you earn it." ("snape_09")
        her "I did earn it!" ("open", "base", "base", "R")
        her "And could you at least have the decency to stop touching yourself, professor!" ("annoyed", "narrow", "angry", "R")
        sna "*Tch*..." ("snape_12")
        hide hermione_main
        with d3

        gen "(Are they for real?)" ("base", xpos="far_left", ypos="head")
        hide screen bld1
        with d3
        pause.2

        show screen blkfade
        with d5

        ">You watch Snape with his dick still hanging out and the cum-covered Hermione argue loudly about her imaginary grade."
        ">After a while Professor Snape agrees to change Hermione's grade from \"F+\" to \"D-\"."
        ">Then he beats a hasty retreat before Hermione has a chance to start another argument."
        pause 1

        call sna_chibi("stand","mid","base", flip=True)
        hide screen blkfade
        with d5

        call sna_walk(action="leave")
        pause.5

        call her_chibi("stand","desk","base")
        pause.2

        her "Well..." ("annoyed", "base", "worried", "R", xpos="mid", ypos="base", flip=False)
        her "Was our mission a success, [genie_name]?"

        menu:
            gen "..." ("base", xpos="far_left", ypos="head")
            "\"*huh*? What mission?\"":
                $ her_mood += 7
                her "I only agreed to this so that you could catch professor Snape in the act, [genie_name]!" ("scream", "happyCl", "worried", "mid")
                her "So that we would have definite proof that he is \"dirty\"!" ("normal", "happyCl", "worried", "mid")
                gen "Oh, that mission..." ("base", xpos="far_left", ypos="head")
                gen "Yes. Mission accomplished!" ("base", xpos="far_left", ypos="head")
            "\"Yes! Thanks to you!\"":
                pass

        gen "Good job, [hermione_name]." ("base", xpos="far_left", ypos="head")
        her "I am happy to have been of help, [genie_name]!" ("normal", "happyCl", "worried", "mid")
        pause.5
        show screen blkfade
        with d5

        her "... Can I get paid now, please?" ("angry", "happyCl", "worried", "mid", emote="sweat", ypos="head", flip=False)

        jump end_hg_pf_strip
