label tonks_summon_setup:

    # Reset doll state
    $ tonks.wear("all")
    $ tonks.set_cum(None)
    $ tonks.animation = None

    if not tonks_strip_happened and cc_pf_strip.is_event_complete(3, 3) and ton_friendship >= 20 and tonks.is_any_worn("top", "bottom", "bra", "panties"):
        $ tonks_strip_happened = True #TODO use to make event not repeat

        $ tonks.strip("all")
        call ton_walk(action="enter", xpos="mid", ypos="base")

        call play_sound("scratch")
        with hpunch
        gen "!!!" ("angry", xpos="far_left", ypos="head")

        ton "" ("grin", "base", "base", "mid", hair="horny", cheeks="heavy_blush", xpos="mid", ypos="base", trans=d5)
        call ctc

        ton "Hello, [ton_genie_name]." ("soft", "narrow", "raised", "mid", hair="horny", cheeks="heavy_blush")
        gen "You're naked!" ("grin", xpos="far_left", ypos="head")
        ton "I am?" ("soft", "narrow", "raised", "mid", hair="horny", cheeks="heavy_blush")
        ton "Oh... Yes it appears so..." ("grin", "narrow", "shocked", "down", hair="horny", cheeks="heavy_blush")
        ton "Is that a problem, [ton_genie_name]?" ("annoyed", "narrow", "raised", "mid", hair="horny", cheeks="heavy_blush")
        ton "Am I going to get fired for inappropriate behaviour?" ("annoyed", "narrow", "base", "down", hair="horny", cheeks="heavy_blush")
        ton "Are you going to report me to the ministry?" ("base", "narrow", "raised", "down", hair="horny", cheeks="heavy_blush")
        gen "..." ("base", xpos="far_left", ypos="head")
        gen "Have you been drinking Wine?" ("base", xpos="far_left", ypos="head")

        call play_sound("giggle")
        ton "*Giggles*" ("grin", "narrow", "base", "stare", hair="horny", cheeks="heavy_blush")
        ton "Maybe..." ("grin", "wink", "base", "mid", hair="horny", cheeks="heavy_blush")

        gen "One of the students could have seen you..." ("base", xpos="far_left", ypos="head")
        ton "Oh, I would love for them to see me like this..." ("horny", "narrow", "shocked", "R", hair="horny", cheeks="heavy_blush")
        ton "Why don't you invite one to your office?" ("soft", "narrow", "shocked", "mid", hair="horny", cheeks="heavy_blush")

        if ag_st_imperio.counter > 0:
            gen "You'd like that wouldn't you..." ("base", xpos="far_left", ypos="head")
            ton "Very much!" ("base", "narrow", "base", "mid", hair="horny", cheeks="heavy_blush")
            gen "Like that Astoria girl you're so infatuated with?" ("base", xpos="far_left", ypos="head")
            gen "Want me to call her up here to have her shame you on your bad behaviour?" ("base", xpos="far_left", ypos="head")
            ton "Oh, yes please!" ("horny", "base", "base", "mid", hair="horny", cheeks="heavy_blush")
            gen "But this sudden behaviour isn't about her is it?" ("base", xpos="far_left", ypos="head")
            ton "*Hmm*... Is it that obvious?" ("base", "narrow", "base", "R", hair="horny", cheeks="heavy_blush")

        gen "Miss Chang?" ("base", xpos="far_left", ypos="head")
        ton "*Mmm*..." ("base", "narrow", "base", "stare", hair="horny", cheeks="heavy_blush")
        gen "Would you like me to bring her up here so you could rub your bodies together some more?" ("base", xpos="far_left", ypos="head")
        ton "Yes please!" ("grin", "narrow", "base", "stare", hair="horny", cheeks="heavy_blush")
        gen "You sure you're ready to find out just how flexible she is?" ("base", xpos="far_left", ypos="head")
        ton "Yes!" ("crooked_smile", "base", "base", "stare", hair="horny", cheeks="heavy_blush")

        gen "(Although that's probably not the best idea in her current state...)" ("base", xpos="far_left", ypos="head")
        gen "(Doesn't mean I can't tease her a bit though...)" ("grin", xpos="far_left", ypos="head")
        gen "I bet you'd love that..." ("base", xpos="far_left", ypos="head")

        menu:
            "-Play nice-":
                gen "How about a bonus instead?" ("grin", xpos="far_left", ypos="head")
                ton "A bonus? For showing off my body to my own boss?" ("soft", "narrow", "raised", "mid", hair="horny", cheeks="heavy_blush")
                gen "That's right." ("base", xpos="far_left", ypos="head")

                call play_sound("giggle")
                ton "*giggles*" ("grin", "narrow", "raised", "stare", hair="horny", cheeks="heavy_blush")

                ton "I've always wanted to find out my worth." ("grin", "base", "base", "stare", hair="horny", cheeks="heavy_blush")
                gen "Alright then... Let's see, how much are you worth to me..." ("base", xpos="far_left", ypos="head")

                menu:
                    "-Zero gold-" if game.gold <= 0:
                        gen "Zero gold." ("base", xpos="far_left", ypos="head")
                        ton "Seriously?" ("soft", "narrow", "raised", "mid", hair="horny", cheeks="heavy_blush")
                        gen "Yes, I'm a cheap bastard." ("base", xpos="far_left", ypos="head")
                        ton "Clearly..." ("upset", "narrow", "base", "mid", hair="horny", cheeks="heavy_blush")

                    "-One gold-" if game.gold > 0:
                        gen "A single gold coin, if anything..." ("base", xpos="far_left", ypos="head")
                        ton "(Bastard... How humiliating.)" ("soft", "narrow", "worried", "up", hair="horny", cheeks="heavy_blush")
                        gen "Well?" ("base", xpos="far_left", ypos="head")
                        ton "Yes?" ("disgust", "narrow", "raised", "mid", hair="horny", cheeks="heavy_blush")
                        gen "Shouldn't you be thanking me for this generous valuation?" ("base", xpos="far_left", ypos="head")
                        ton "Oh... Thank you so much, [ton_genie_name]." ("annoyed", "narrow", "base", "stare", hair="horny", cheeks="heavy_blush")
                        gen "Don't mention it, [tonks_name]." ("base", xpos="far_left", ypos="head")
                        $ game.gold -= 1

                    "-Twenty gold-" if game.gold >= 20:
                        gen "How does twenty gold sound?" ("base", xpos="far_left", ypos="head")
                        ton "(*Hmm*... I kind of expected more.)" ("annoyed", "narrow", "raised", "downR", hair="horny", cheeks="heavy_blush")
                        ton "Thank you, [ton_genie_name]." ("soft", "narrow", "base", "mid", hair="horny", cheeks="heavy_blush")
                        gen "No, [tonks_name]... Thank you." ("grin", xpos="far_left", ypos="head")
                        $ game.gold -= 20

                    "-A hundred gold-" if game.gold >= 100:
                        gen "Does one hundred gold sound nice to you?" ("base", xpos="far_left", ypos="head")
                        gen "With a body like that, you could earn a fortune at a strip club!" ("grin", xpos="far_left", ypos="head")
                        ton "Really..." ("horny", "narrow", "shocked", "mid", hair="horny", cheeks="heavy_blush")
                        ton "You think a noble teacher and auror like me, would quit her highly regarded job to become a cheap stripper?" ("grin", "narrow", "shocked", "mid", hair="horny", cheeks="heavy_blush")
                        gen "Well, no. I still want to keep you as a teacher." ("base", xpos="far_left", ypos="head")
                        gen "I merely suggested that you could." ("base", xpos="far_left", ypos="head")
                        ton "Maybe the duelling stage could find some extra use..." ("base", "narrow", "shocked", "stare", hair="horny", cheeks="heavy_blush")
                        ton "Perhaps some extra curricular activities for a couple of my favourite students could be arranged..." ("horny", "narrow", "raised", "up", hair="horny", cheeks="heavy_blush")
                        gen "I'm sure they would all love to watch their perverted teacher strip!" ("grin", xpos="far_left", ypos="head")
                        $ game.gold -= 100

                gen "Now..." ("base", xpos="far_left", ypos="head")

            "-Scold her-":
                gen "But you know what I have to do, [tonks_name]..." ("base", xpos="far_left", ypos="head")
                gen "What were you thinking, walking into your boss' office, completely naked?" ("base", xpos="far_left", ypos="head")
                ton "I'm terribly sorry, [ton_genie_name]..." ("open", "narrow", "base", "down", hair="horny", cheeks="heavy_blush")
                gen "How's this befitting for a teacher..." ("angry", xpos="far_left", ypos="head")
                gen "That surely calls for some punishment, don't you think?" ("grin", xpos="far_left", ypos="head")
                ton "You are so right, [ton_genie_name]!" ("horny", "narrow", "base", "stare", hair="horny", cheeks="heavy_blush")

                # This section will be under some public check
                # gen "I should make you the school's cum-dumpster instead. How would you like that position?" ("base", xpos="far_left", ypos="head")
                # gen "Boys lining up in front of the school toilets, waiting their turn to dump their cum into their teacher's mouth, day after day!" ("base", xpos="far_left", ypos="head")
                # ton "You're making me so wet, [ton_genie_name]!" ("base", "base", "base", "ahegao")
                # ton "Maybe some day I'll get bored of my current position here at Hogwarts... you never know..." ("horny", "base", "raised", "mid")
                # gen "I'm not done with your punishment, Miss [tonks_name]!" ("base", xpos="far_left", ypos="head")
                gen "You went to this school, didn't you? Which house were you in?" ("base", xpos="far_left", ypos="head")
                ton "My house? I was in Hufflepuff, but why--" ("disgust", "base", "raised", "mid", hair="horny", cheeks="heavy_blush")
                gen "Very well then..." ("base", xpos="far_left", ypos="head")
                gen "Minus ten points from Hufflepuff!" ("base", xpos="far_left", ypos="head")
                $ hufflepuff -=10
                ton "What? But [ton_genie_name]! I'm not even a student--" ("disgust", "base", "base", "mid", hair="upset", cheeks="heavy_blush", trans=hpunch)
                gen "Also--" ("base", xpos="far_left", ypos="head")

        menu:
            "-Those clothes stay off!-":
                $ tonks.unequip("all")

                ton "*Hmm*?" ("soft", "narrow", "raised", "down", hair="horny", cheeks="heavy_blush")
                gen "That's right... If they're so bothersome, why bother wearing them at all?" ("base", xpos="far_left", ypos="head")
                gen "When you're in here with me I want you on full display!" ("base", xpos="far_left", ypos="head")
                ton "Of course [ton_genie_name]..." ("soft", "narrow", "base", "down", hair="horny", cheeks="heavy_blush") #Horny
                ton "If you would allow me to put my clothes back on at any time, just let me know..." ("soft", "narrow", "base", "downR", hair="horny", cheeks="heavy_blush")

            "-Get dressed!-":
                gen "No teacher of mine will strut around naked...{w} unless I say so!" ("base", xpos="far_left", ypos="head")
                ton "Yes [ton_genie_name]..." ("open", "narrow", "shocked", "down", hair="horny", cheeks="heavy_blush")
                gen "Now, put your clothes back on..." ("base", xpos="far_left", ypos="head")
                ton "*Ehm*... Okay..." ("soft", "base", "base", "down", hair="horny", cheeks="heavy_blush")

                call play_sound("magic")
                $ tonks.wear("all")
                ton "" (trans=morph)
                ton "" ("soft", "narrow", "base", "mid", hair="horny", cheeks="heavy_blush")

                if tonks_morph_known:
                    gen "...{w} You used your meta-whatsit ability just then didn't you?" ("base", xpos="far_left", ypos="head")
                    ton "You can tell?" ("soft", "narrow", "base", "down", hair="horny", cheeks="heavy_blush")
                    gen "Whatever, just wear your actual clothing next time..." ("base", xpos="far_left", ypos="head")
                else:
                    gen "Much better..." ("base", xpos="far_left", ypos="head")
                    ton "..." ("soft", "narrow", "base", "downR", hair="horny", cheeks="heavy_blush")

        gen "Now, get back to your room and think about what you've done..." ("base", xpos="far_left", ypos="head")
        ton "Yes [ton_genie_name]..." ("open", "narrow", "base", "down", hair="horny", cheeks="heavy_blush") #look down, blush

        #Tonks leaves
        call ton_walk(action="leave")

        gen "(Hold on... Didn't I call her here for another reason...)" ("base", xpos="far_left", ypos="head")
        gen "(I suppose it'll have to wait till tomorrow...)" ("base", xpos="far_left", ypos="head")

        jump end_tonks_event

    if tonks_outfits_schedule:
        $ tonks.equip_random_outfit()

    call play_sound("door")
    call ton_chibi("stand","mid","base")
    with d3

    #Tonks greeting.
    call play_music("tonks")

    if ton_mood > 0:
        if 5 > ton_mood >= 1:
            ton "Yes, [ton_genie_name]?" ("open", "base", "base", "R", xpos="base", ypos="base", trans=d3)
            ton "" ("base", "base", "base", "R")
        elif 10 > ton_mood >= 5:
            ton "I have classes to teach, please be quick." ("upset", "base", "base", "mid", xpos="base", ypos="base", trans=d3)
        elif 20 > ton_mood >= 10:
            ton "Make it quick, [ton_genie_name]..." ("upset", "base", "base", "R", xpos="base", ypos="base", trans=d3)
        elif 30 > ton_mood >= 20:
            ton "What do you want, \"[ton_genie_name]\", I'm busy." ("mad", "base", "angry", "mid", xpos="base", ypos="base", trans=d3)
        elif 40 > ton_mood >= 30:
            ton "..............." ("upset", "base", "angry", "mid", xpos="base", ypos="base", trans=d3)
        elif 50 > ton_mood >= 40:
            ton "Please stop wasting my time." ("upset", "closed", "angry", "mid", xpos="base", ypos="base", trans=d3)
        elif ton_mood >= 50:
            ton "You have the nerve to call me here after what you did." ("upset", "base", "angry", "mid", xpos="base", ypos="base", trans=d3)

        call describe_mood("Tonks", ton_mood)
        call tutorial("moodngifts")
    else:
        ton "You called, [ton_genie_name]?" ("base", "base", "base", "mid", xpos="base", ypos="base", trans=d3)
    return
