
### Give Classmate A Handjob ###

label hg_pr_handjob:

    # Setup
    $ current_payout = 55

    if hg_pr_handjob.counter == 0:
        gen "{size=-4}(Tell her to give a handjob to one of her classmates?){/size}" ("base", xpos="far_left", ypos="head")
        menu:
            "\"(Yes, let's do it!)\"":
                pass
            "\"(Not right now.)\"":
                jump hermione_favor_menu

    her "" (xpos="mid", ypos="base", trans=fade)

    #Intro
    if hg_pr_handjob.counter == 0:

        if her_reputation < 12:
            gen "[hermione_name], I want you to do something different today..." ("base", xpos="far_left", ypos="head")
            her "...?" ("normal", "squint", "angry", "mid")
            gen "I want you to give a handjob to one of your classmates." ("base", xpos="far_left", ypos="head")

            jump too_much_public

        gen "[hermione_name], I want you to do something different today..." ("base", xpos="far_left", ypos="head")
        her "..........." ("soft", "base", "base", "mid")
        gen "I want you to go out there and have sex with one of your classmates." ("grin", xpos="far_left", ypos="head")

        stop music fadeout 0.5
        with hpunch

        her "{size=+5}What?!!{/size}" ("shock", "wide", "base", "stare")
        call play_music("hermione") # Music
        her "Now you have done it, [genie_name]! You crossed the line!" ("angry", "base", "angry", "mid")
        her "I know I did sell you a couple of rather questionable favours in the past..."
        gen "{size=-4}*Heh* a couple she says...{/size}" ("base", xpos="far_left", ypos="head")
        with vpunch
        her "{size=+5}--But THIS?!{/size}" ("scream", "base", "angry", "mid", emote="angry")
        her "I cannot believe that you would ask one of your pupils to... to..."
        her "We are done here, [genie_name]!" ("angry", "base", "angry", "mid", emote="angry")
        gen "Alright, alright, calm down, would you?" ("base", xpos="far_left", ypos="head")
        her "I most certainly will not, [genie_name]! This is beyond inappropriate!" ("scream", "closed", "angry", "mid")
        gen "Alright, fine, maybe I really did cross some sort of line this time..." ("base", xpos="far_left", ypos="head")
        her "You think [genie_name]?! You think!!?" ("angry", "base", "angry", "mid")
        gen "Yes, I apologise..." ("base", xpos="far_left", ypos="head")
        her "........." ("annoyed", "narrow", "annoyed", "mid")
        gen "How about we try something less... engaging instead?" ("base", xpos="far_left", ypos="head")
        her "............" ("upset", "closed", "base", "mid")
        gen "I'll be willing to grant Gryffindor {number=current_payout} points." ("base", xpos="far_left", ypos="head")
        gen "All I ask in return is..." ("base", xpos="far_left", ypos="head")
        her "..........?" ("angry", "base", "angry", "mid", cheeks="blush")
        gen "... that you go out there and give some lucky boy a handjob..." ("base", xpos="far_left", ypos="head")
        her "!!!......" ("angry", "base", "angry", "mid")
        gen "Oh, come on... Just a harmless handjob." ("base", xpos="far_left", ypos="head")
        her "..." ("disgust", "narrow", "base", "mid_soft")
        gen "{number=current_payout} house points..." ("base", xpos="far_left", ypos="head")
        her ".............." ("annoyed", "narrow", "angry", "R")
        her "I am glad that you came to your senses, [genie_name]." ("annoyed", "narrow", "annoyed", "mid")
        gen "Oh, but of course. Thank you for keeping me in check." ("base", xpos="far_left", ypos="head")
        gen "Are you up for it then?" ("base", xpos="far_left", ypos="head")
        her "I am willing to give it a try..." ("annoyed", "narrow", "angry", "R")
        gen "Splendid... See you tonight then." ("base", xpos="far_left", ypos="head")
    else:
        if her_tier >= 6:
            gen "[hermione_name]..." ("base", xpos="far_left", ypos="head")
            gen "What do you think about giving one of your classmates another handjob?" ("base", xpos="far_left", ypos="head")
            her "I don't mind, [genie_name]." ("annoyed", "narrow", "worried", "down")
            gen "Really?" ("base", xpos="far_left", ypos="head")
            her "Yes... I mean, it's just a handjob..." ("grin", "base", "base", "R")
            gen "Great. Go have fun then!" ("base", xpos="far_left", ypos="head")
            gen "And report back to me after your classes, as usual." ("base", xpos="far_left", ypos="head")
            her "Of course, [genie_name]." ("base", "happyCl", "base", "mid")
        elif her_tier >= 5:
            gen "Ready to go have sex with one of your classmates yet?" ("base", xpos="far_left", ypos="head")

            stop music fadeout 1.0

            her "What?" ("scream", "wide", "base", "mid")
            her "Of course not! I would never--" ("scream", "closed", "angry", "mid")
            gen "How about a handjob then?" ("base", xpos="far_left", ypos="head")
            call play_music("hermione") # Music
            her "..............." ("annoyed", "narrow", "angry", "R")
            gen "Oh come on. You did it before." ("base", xpos="far_left", ypos="head")
            her "*Hmm*.........." ("annoyed", "narrow", "annoyed", "mid")
            her "{number=current_payout} house points?"
            gen "Naturally." ("base", xpos="far_left", ypos="head")
            her "Well, alright... I'll see what I can do..." ("angry", "narrow", "base", "down")
        else:
            gen "Today's favour shall be..." ("base", xpos="far_left", ypos="head")
            her "........." ("angry", "base", "base", "mid")
            gen "A Handjob to the boy of your choosing!" ("base", xpos="far_left", ypos="head")
            her "... again?" ("angry", "narrow", "base", "down")
            gen "Sure, why not?" ("base", xpos="far_left", ypos="head")
            gen "And another {number=current_payout} house points for the Gryffindor house of course." ("base", xpos="far_left", ypos="head")
            her ".........." ("annoyed", "base", "worried", "R")
            gen "So... Are you up for that, [hermione_name]?" ("base", xpos="far_left", ypos="head")
            her "I will see what I can do..." ("annoyed", "narrow", "angry", "R")
            gen "Splendid!" ("base", xpos="far_left", ypos="head")

    call her_walk(action="leave")

    $ hg_pr_handjob.inProgress = True
    jump end_hermione_event

label end_hg_pr_handjob:
    $ gryffindor += current_payout #55
    gen "The Gryffindor house gets {number=current_payout} points!" ("base", xpos="far_left", ypos="head")
    her "Thank you, [genie_name]."

    label .no_points:

    call her_walk("door", "base")
    pause.2

    # Inner monologue
    if hg_pr_handjob.counter == 1:

        her ".........." ("upset", "narrow", "angry", "R", ypos="head", flip=False, trans=d3)

        show screen blktone
        with d3

        her "(Do I really have to do this?)" ("upset", "closed", "angry", "mid")

        hide screen blktone
        with d3

        her "*sigh*" ("soft", "closed", "angry", "mid")


    call her_chibi("leave")

    label .quick_end:

    # Increase Points
    if not hg_pr_handjob.is_tier_complete():
        $ her_reputation += 1

    $ hg_pr_handjob.inProgress = False
    jump end_hermione_event

label hg_pr_handjob_intro:
    call her_walk(action="enter", xpos="mid", ypos="base")
    her "Good evening, [genie_name]." ("base", "base", "base", "mid", xpos="mid", ypos="base", trans=fade)
    gen "[hermione_name]..." ("base", xpos="far_left", ypos="head")
    gen "Did you lend a hand to the needy?" ("base", xpos="far_left", ypos="head")
    her "Yes, [genie_name]..."

    if hg_pr_handjob.is_tier_complete():
        menu:
            "\"Great. Here are your points.\"":
                jump end_hg_pr_handjob

            "\"Give me the details.\"":
                pass

    stop music fadeout 3.0

    if hg_pr_handjob.counter == 1:
        her "......" ("annoyed", "narrow", "angry", "R")
        gen ".............." ("base", xpos="far_left", ypos="head")

    gen "[hermione_name], how did it go?" ("base", xpos="far_left", ypos="head")

    return

### Tier 4 ###

label hg_pr_handjob_T4_E1:

    call hg_pr_handjob_intro

    call play_music("hermione") # Music
    her "Quite awful... of course..." ("annoyed", "squint", "angry", "mid")
    gen "Just tell me what happened, [hermione_name]..." ("base", xpos="far_left", ypos="head")
    her "I made a complete fool out of myself, that's what happened, [genie_name]." ("disgust", "narrow", "base", "mid_soft")
    her "....."
    gen "..." ("base", xpos="far_left", ypos="head")
    her ".........." ("annoyed", "base", "worried", "R")
    her "I don't want to talk about it..." ("annoyed", "narrow", "angry", "R")
    her "You told me to go and touch a boy's penis and I did just that, [genie_name]."
    her "Please, just let me have my points now, [genie_name]..." ("open", "base", "base", "mid")
    gen "I did not tell you to \"go and touch a boy's penis\", [hermione_name]." ("base", xpos="far_left", ypos="head")
    gen "I told you to give one of your classmates a proper handjob." ("base", xpos="far_left", ypos="head")
    her "Well, yes... that was what I meant of course..." ("annoyed", "narrow", "annoyed", "mid")
    gen "Did you make him cum, then?" ("base", xpos="far_left", ypos="head")
    her "[genie_name]?" ("open", "base", "base", "mid")
    gen "Did his \"wee-wee\" shoot white stuff at you, [hermione_name]?" ("base", xpos="far_left", ypos="head")
    her "Well..." ("annoyed", "base", "worried", "R")
    her "No, it did not..." ("normal", "happyCl", "worried", "mid")
    gen "Poor guy... Must've blue-balled him." ("base", xpos="far_left", ypos="head")

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "\"Well, this doesn't count then.\"":
            stop music fadeout 4.0
            her "What?" ("angry", "wide", "base", "stare")
            her "But, [genie_name], I..."
            gen "If you didn't make him cum then that wasn't a proper handjob. Period." ("base", xpos="far_left", ypos="head")
            her "But... But what was it then...?" ("angry", "base", "base", "mid")
            gen "How should I know? A cock massage?" ("base", xpos="far_left", ypos="head")
            her "*Aww*..." ("angry", "narrow", "base", "down")
            her "But I really tried my best..."
            gen "No handjob - no payment, [hermione_name]." ("base", xpos="far_left", ypos="head")
            her "....." ("angry", "base", "base", "mid")
            gen "You are free to go, [hermione_name]." ("base", xpos="far_left", ypos="head")
            her "........." ("annoyed", "narrow", "angry", "R")

            $ her_mood +=9
            jump end_hg_pr_handjob.no_points

        "\"You shall only get half the payment then.\"":
            $ current_payout = int(current_payout/2)

            her "Oh...?" ("open", "base", "base", "mid")
            gen "Is that a Problem, [hermione_name]?" ("base", xpos="far_left", ypos="head")
            her "N-No [genie_name]... It's only fair I suppose..." ("angry", "narrow", "base", "down")
            gen "Of course it is!" ("base", xpos="far_left", ypos="head")

        "\"Well, you did try. Here are your points.\"":
            her "Really?" ("angry", "base", "base", "mid")
            her "Thank you, [genie_name]!" ("open", "narrow", "worried", "down")
            her "I promise, I will try harder next time!" ("base", "base", "base", "mid")
            her "*Ehm*... Should you request a similar favour in the future, I mean..." ("upset", "wink", "base", "mid")

    jump end_hg_pr_handjob

label hg_pr_handjob_T4_E2:

    call hg_pr_handjob_intro

    call play_music("playful_tension") # Music
    her "It went well, [genie_name]..." ("open", "base", "base", "mid")
    her "I asked one of the Gryffindor boys to let me do \"it\" to him..."
    her "To my surprise he agreed eagerly." ("open", "base", "base", "mid", cheeks="blush")
    gen "Shocker..." ("base", xpos="far_left", ypos="head")
    her "So we hid behind one of those huge tapestries in the east wing..." ("open", "closed", "base", "mid", cheeks="blush")
    her "And I... wanked him until he came..." ("annoyed", "narrow", "angry", "R", cheeks="blush")
    her "........."
    her "And I asked him to keep the whole thing a secret, but..." ("angry", "base", "base", "mid", cheeks="blush")
    gen "What's the matter, [hermione_name]?" ("base", xpos="far_left", ypos="head")
    gen "Doubting the honesty of your fellow Gryffindor?" ("base", xpos="far_left", ypos="head")
    her "Of course not, [genie_name]." ("upset", "closed", "base", "mid")
    her "..........................." ("angry", "narrow", "base", "down", cheeks="blush")
    her "Still... Performing this sort of task could really damage my reputation..." ("angry", "base", "base", "mid", cheeks="blush")
    gen "Is this your way of asking for a raise, [hermione_name]?" ("base", xpos="far_left", ypos="head")
    gen "{number=current_payout} points is as high as I can go with this one." ("base", xpos="far_left", ypos="head")
    her "Oh... Of course..." ("angry", "narrow", "base", "down")
    gen "Unless, you've changed your mind about having sex with one of your classmates?" ("base", xpos="far_left", ypos="head")
    her "What?" ("shock", "wide", "base", "stare")
    her "[genie_name], I am not a prostitute!" ("angry", "narrow", "base", "down", cheeks="blush")
    gen "Well, in that case..." ("base", xpos="far_left", ypos="head")

    jump end_hg_pr_handjob

label hg_pr_handjob_T4_E3:

    # Special intro
    stop music fadeout 3.0
    call her_walk(action="enter", xpos="mid", ypos="base")

    gen "[hermione_name], how did it--" ("base", xpos="far_left", ypos="head")
    $ hermione.set_cum(hair="light")
    show screen blktone
    with d3
    her "" ("angry", "narrow", "angry", "R", xpos="mid", ypos="base", trans=d3)
    gen "...-go." ("base", xpos="far_left", ypos="head")

    call play_music("hermione") # Music
    her "Awful, [genie_name]. Simply awful..." ("scream", "happyCl", "worried", "mid")
    gen "You've got something... in your hair there..." ("base", xpos="far_left", ypos="head")
    her "*huh*?" ("open", "base", "angry", "mid")
    her "Oh, no! I thought I got it all off..." ("angry", "happyCl", "base", "mid", cheeks="blush")
    her "One moment..."

    show screen blkfade
    with d3
    pause.5
    $ hermione.set_cum(None)
    her "" ("upset", "closed", "base", "mid")
    hide screen blkfade
    with d3

    gen "*Hmm*... So I suppose you have completed your task?" ("base", xpos="far_left", ypos="head")
    her "I did, [genie_name]..." ("annoyed", "narrow", "angry", "R")
    gen "What's the problem, then?" ("base", xpos="far_left", ypos="head")
    her ".........." ("annoyed", "base", "worried", "R")
    her "All boys are jerks! That is the problem, [genie_name]!" ("scream", "closed", "angry", "mid")
    her "I gave this one boy a good wanking..." ("open", "narrow", "worried", "down")
    her "And do you know how he thanked me?"
    her "He got his spunk all over me..." ("scream", "base", "angry", "mid", emote="angry")
    her "And he did that on purpose, I know he did!" ("scream", "closed", "angry", "mid")
    her "Nasty, good for nothing Ravenclaws..." ("annoyed", "base", "worried", "R")
    gen "Well, I'd say a job well done." ("base", xpos="far_left", ypos="head")

    jump end_hg_pr_handjob

### Tier 5 ###

label hg_pr_handjob_T5_E1:

    call hg_pr_handjob_intro

    call play_music("hermione") # Music
    her "*Ehm*..." ("open", "base", "base", "mid")
    her "Not that good to be honest, [genie_name]..."
    gen "Oh?" ("base", xpos="far_left", ypos="head")
    her "Yes... Let me explain, [genie_name]..." ("annoyed", "base", "worried", "R")
    her "*Ehm*... Well..." ("open", "base", "base", "mid")
    her "I was jerking this one boy off, in one of the empty classrooms..."
    her "And that nasty ghost Peeves walked in..."
    her "Or rather flew in on us..." ("annoyed", "base", "worried", "R")
    her "And as soon as he realised what I was doing to the boy..." ("open", "base", "base", "mid")
    her "He started to yell obscenities at us..."
    her "So we had to leave in a hurry..."
    gen "I see..." ("base", xpos="far_left", ypos="head")
    her "That is not all, [genie_name]..." ("annoyed", "narrow", "angry", "R")
    gen "Go on..." ("base", xpos="far_left", ypos="head")
    her "Well, I sort of made a promise to the boy..." ("open", "narrow", "worried", "down")
    her "I promised to meet him after my classes and..."
    her "... and finish what I have started..." ("annoyed", "narrow", "annoyed", "mid")
    gen "I see..." ("base", xpos="far_left", ypos="head")
    gen "Did you?" ("base", xpos="far_left", ypos="head")
    her "No, [genie_name]. Not yet at least..." ("angry", "base", "base", "mid")
    her "I am supposed to meet him as soon as we are done here, [genie_name]."
    gen "*Hmm*..." ("base", xpos="far_left", ypos="head")
    her "So if you could just give those points in advance..." ("angry", "narrow", "base", "down")
    her "I would go meet with the boy right away and..."
    her "And give him a proper handjob...?" ("open", "base", "base", "R", cheeks="blush")

    menu:
        "\"No. You failed this favour, [hermione_name].\"":
            stop music fadeout 3.0

            her "B-but..." ("open", "base", "base", "mid", cheeks="blush")
            her "But I gave him my word..." ("angry", "wide", "base", "stare")
            her "I swore on Godric Gryffindor's name..."
            her "And now I will have to give him a wank no matter what..." ("angry", "narrow", "base", "down")
            gen "Well, I didn't force you to give him that promise, did I?" ("base", xpos="far_left", ypos="head")
            her "......" ("angry", "base", "base", "mid")
            her "This is just not fair!" ("scream", "happyCl", "worried", "mid")

            $ her_mood += 20
            jump end_hg_pr_handjob.no_points

        "\"Alright, I think I can trust you.\"":
            her "Thank you, [genie_name]." ("base", "base", "base", "mid")
            her "I knew you would understand."
            gen "Just make sure you finish your job properly this time." ("base", xpos="far_left", ypos="head")
            her "Of course, [genie_name]. I will give him the wank of his life, I promise!" ("base", "happyCl", "base", "mid")

    jump end_hg_pr_handjob

label hg_pr_handjob_T5_E2:

    call hg_pr_handjob_intro

    call play_music("hermione") # Music
    her "Fine I suppose..." ("open", "closed", "base", "mid")
    her "Although I am still not sure how I feel about all of this..." ("annoyed", "base", "worried", "R")
    gen "Your personal feelings are of no concern to me, [hermione_name]." ("base", xpos="far_left", ypos="head")
    gen "Just tell me more about how it went." ("base", xpos="far_left", ypos="head")
    her "Well, there is not much to tell. [genie_name]..." ("open", "base", "base", "mid")
    call play_music("playful_tension") # Music
    her "Today I gave another handjob to one of my classmates..."
    her "Me, Hermione Granger..." ("open", "narrow", "worried", "down")
    her "Giving free handjobs in the school's restroom..." ("angry", "narrow", "base", "down")
    gen "Wait. What do you mean by \"free\"?" ("base", xpos="far_left", ypos="head")
    her "Oh, of course... I get paid with house points for this..." ("angry", "base", "base", "mid")
    her "But nobody knows about that..."
    her "And to everyone else this just looks like some harlot who does this for fun..."
    her "They must think I am a slut..." ("open", "narrow", "worried", "down")
    her ".............." ("clench", "narrow", "base", "down")
    her "Do you think I'm a slut, [genie_name]?" ("open", "happy", "base", "mid", cheeks="blush")

    menu:
        gen "(*Hmm*..)" ("base", xpos="far_left", ypos="head")
        "\"What? Of course not, [hermione_name]!\"":
            her ".............." ("base", "base", "base", "R", cheeks="blush")
            her "You are right, [genie_name]..." ("base", "narrow", "worried", "down")
            her "I am making this sacrifice for the glory of the Gryffindor house."
            her "I am not taking pleasure in this sort of activity..." ("soft", "narrow", "annoyed", "up")
            her "Because if I would..." ("annoyed", "narrow", "angry", "R")
            her "That would mean I really am a slut..."
            her "And I am not..." ("angry", "narrow", "base", "down")
            her "......"
            her "I am not a slut..."

        "\"A slut? No... Not yet.\"":
            her "\"Not yet\"??!" ("angry", "base", "base", "mid")
            her ".........." ("angry", "narrow", "base", "down")
            her "Well, of course!" ("scream", "wide", "base", "mid")
            her "You are right, as usual, [genie_name]!" ("soft", "base", "base", "mid")
            gen "*huh*?" ("base", xpos="far_left", ypos="head")
            her "I have done a few... naughty things..." ("open", "base", "base", "mid")
            her "But that does not mean anything!"
            her "..........." ("annoyed", "narrow", "angry", "R")

        "\"Yes, that's exactly what you are.\"":
            her "I was afraid that you would say that, [genie_name]..." ("mad", "happyCl", "worried", "mid", tears="soft_blink")
            her "But you are wrong, [genie_name]."
            her "You of all people should understand that I take no pleasure in this..." ("angry", "base", "base", "mid", tears="soft")
            her "I just do what needs to be done..." ("normal", "base", "base", "R", tears="soft")
            $ her_mood = 10

    her "[genie_name], can I just get paid now, please?" ("soft", "base", "base", "R")
    gen "Get paid? But you didn't tell me how it went yet?" ("base", xpos="far_left", ypos="head")
    her "I did not?"
    her "[genie_name], I gave a handjob to one of my classmates today..." ("open", "base", "base", "mid", cheeks="blush")
    her "I wanked his cock until he came..."
    her "Is that not what you told me to do?" ("disgust", "narrow", "base", "mid_soft")
    gen "That's exactly what I told you to do, [hermione_name]." ("base", xpos="far_left", ypos="head")
    her "Then I would like to get paid now, please." ("annoyed", "closed", "base", "mid")
    gen "........" ("base", xpos="far_left", ypos="head")
    gen "Fine..." ("base", xpos="far_left", ypos="head")

    jump end_hg_pr_handjob

label hg_pr_handjob_T5_E3:

    call hg_pr_handjob_intro

    call play_music("hermione") # Music
    her "Pretty well, [genie_name]." ("open", "closed", "base", "mid")
    gen "Great. Tell me more." ("base", xpos="far_left", ypos="head")
    call play_music("playful_tension") # Music
    her "Well, today was a rather busy day..." ("open", "base", "base", "mid")
    her "And I had to catch up on some studying..."
    her "So I really had no time to plan this out properly, like I normally would..."
    her "I pretty much just approached the first boy I saw..."
    her "And asked him if he wants me to jerk him off." ("annoyed", "narrow", "angry", "R")
    her "a Few minutes later I was already stroking his hard cock in the restroom stall..."
    gen "How very efficient of you..." ("base", xpos="far_left", ypos="head")
    her "Thank you, [genie_name]." ("annoyed", "narrow", "annoyed", "mid")
    her "So, as I was saying..." ("annoyed", "narrow", "angry", "R")
    her "I stroked his cock until he came..."
    her "But after that he said: \"Good job, slut\" and just left me there..." ("disgust", "narrow", "base", "mid_soft")
    her "Such a mean thing to do..." ("annoyed", "narrow", "angry", "R")
    her "It made me feel so cheap... and used." ("upset", "closed", "base", "mid")
    her "But it gets worse..."
    her "......."
    her "I think on some level it also made me feel good somehow..." ("angry", "narrow", "base", "down")
    her "All these favours I have been selling to you lately, [genie_name]..."
    her "... it's starting to affect me." ("angry", "base", "base", "mid")
    her "[genie_name], what is happening to me?"

    menu:
        "\"This is nothing. Stop over-thinking it!\"":
            her "......." ("open", "happy", "base", "mid", cheeks="blush")
            her "You are probably right, [genie_name]. As usual..." ("base", "base", "base", "R", cheeks="blush")
            her "This does not have to mean anything..."

        "\"That is a natural response...\"":
            her "It is?" ("open", "happy", "base", "mid", cheeks="blush")
            gen "Of course." ("base", xpos="far_left", ypos="head")
            gen "You are a girl and he is a boy..." ("base", xpos="far_left", ypos="head")
            gen "You got excited and it made you feel good..." ("base", xpos="far_left", ypos="head")
            her "*Hmm*..." ("base", "base", "base", "R", cheeks="blush")
            gen "Now if you were to give a handjob and feel completely indifferent about it..." ("base", xpos="far_left", ypos="head")
            gen "... that would be... unnatural." ("base", xpos="far_left", ypos="head")
            her "I think you are right, [genie_name]." ("open", "happy", "base", "mid", cheeks="blush")
            her "As usual." ("base", "base", "base", "R", cheeks="blush") # :)

        "\"Yes! All goes according to plan!\"":
            her "What?" ("angry", "wide", "base", "stare")
            gen "What?" ("base", xpos="far_left", ypos="head")
            her "[genie_name], did you just say \"All goes according to plan\"?" ("angry", "base", "angry", "mid", cheeks="blush")
            gen "Did I?" ("base", xpos="far_left", ypos="head")
            gen "Oh, yes, of course." ("base", xpos="far_left", ypos="head")
            gen "Ensuring that Gryffindor gets the house cup this year." ("base", xpos="far_left", ypos="head")
            gen "That's the plan And thanks to your hard work, [hermione_name]..." ("base", xpos="far_left", ypos="head")
            gen "All goes according to my-- I mean, our plan..." ("base", xpos="far_left", ypos="head")
            her "*Hmm*..." ("upset", "closed", "base", "mid")

            $ her_mood += 5

    jump end_hg_pr_handjob

### Tier 6 ###

label hg_pr_handjob_T6_intro_E1:

    # Special intro
    stop music fadeout 3.0
    call her_walk(action="enter", xpos="mid", ypos="base")

    $ hermione.set_cum(hair="light")

    her "[genie_name]..." ("open", "base", "worried", "mid", xpos="mid", ypos="base", trans=d3)
    gen "[hermione_name]..." ("base", xpos="far_left", ypos="head")
    her "I did a bad thing today, [genie_name]..." ("open", "base", "worried", "R")
    gen "Did you now? Do tell..." ("base", xpos="far_left", ypos="head")
    call play_music("playful_tension") # Music
    her "Yes, I did a bad thing... a very bad thing..."
    her "A very bad and foolish thing..." ("annoyed", "squint", "angry", "mid")
    her "..."
    gen "...................." ("base", xpos="far_left", ypos="head")
    her "......................"
    her "I wanked off one of my best friend's brothers..." ("angry", "base", "base", "mid", tears="soft")
    gen "Interesting..." ("base", xpos="far_left", ypos="head")
    her "Seemed like such a great idea at first..." ("angry", "base", "base", "mid", tears="soft")
    her "And Ron was so up for it..."
    her "But if Ginny were to find out... She..." ("shock", "base", "base", "R", cheeks="blush", tears="soft")
    her "She would most certainly kill me, [genie_name]..." ("angry", "base", "base", "mid", tears="soft")
    gen "A handjob, *huh*? Are you sure that was all you did?" ("base", xpos="far_left", ypos="head")
    her "[genie_name]?" ("angry", "base", "base", "mid", tears="soft")
    gen "There is something in your hair..." ("base", xpos="far_left", ypos="head")
    her "What? But I swallowed it all... err..." ("soft", "base", "base", "mid", tears="soft")
    her "I mean..." ("clench", "base", "worried", "mid", cheeks="blush", tears="soft")
    her "*Sigh*" ("shock", "base", "base", "R", cheeks="blush", tears="soft")
    her "... I sucked him off, [genie_name]."
    her "I did not plan to... but..."
    her "Ron is always so nice to me..." ("clench", "base", "worried", "mid", cheeks="blush", tears="soft")
    her "And I wanted to thank him...*Sob*!" ("shock", "narrow", "base", "down", cheeks="blush", tears="crying")
    her "And now Ginny will kill me! *Sob*!" ("angry", "base", "base", "mid", tears="soft")
    her "She will kill me, [genie_name]!"
    her "And if she does not I will probably die of shame anyway." ("shock", "narrow", "base", "down", cheeks="blush", tears="crying")
    her "No, no, no... How will I ever face her...?"
    gen "Calm down, [hermione_name]." ("base", xpos="far_left", ypos="head")
    gen "I assure you, this is not something a boy would be eager to brag about to his sister." ("base", xpos="far_left", ypos="head")
    her "It is not?" ("clench", "base", "worried", "mid", cheeks="blush", tears="soft")
    gen "Don't be silly, [hermione_name]." ("base", xpos="far_left", ypos="head")
    her "*Hmm*..." ("normal", "base", "base", "R", tears="soft")
    her "You are probably right, [genie_name]..." ("soft", "base", "base", "mid", tears="soft")
    her "And I made Ron give me his word that he will keep the whole incident a secret..."
    her "So, I think I should just trust him to keep his word..." ("open", "base", "worried", "R")
    her ".........." ("soft", "base", "base", "R")
    her "..."
    her "Will I get paid for this, [genie_name]?" ("base", "base", "base", "mid")
    gen "Of course." ("base", xpos="far_left", ypos="head")

    jump end_hg_pr_handjob

label hg_pr_handjob_T6_E2:

    call hg_pr_handjob_intro

    call play_music("hermione") # Music
    her "It went... Particularly well..." ("base", "squint", "base", "mid")
    her "I did it more than once actually..."
    gen "More than once?" ("base", xpos="far_left", ypos="head")
    her "Five times, [genie_name]..." ("base", "narrow", "base", "mid_soft")
    her "I... got carried away a little I suppose..."
    gen "What do you mean \"five times\", [hermione_name]?" ("base", xpos="far_left", ypos="head")
    gen "Like... at once?" ("base", xpos="far_left", ypos="head")
    her "No silly. I mean I wanked off five boys today in total, [genie_name]." ("base", "squint", "base", "mid")
    gen "Very impressive nonetheless, [hermione_name]." ("base", xpos="far_left", ypos="head")
    her "Thank you, [genie_name]." ("base", "narrow", "base", "mid_soft")
    gen "You don't expect me to multiply your payment by seven or anything, do you?" ("base", xpos="far_left", ypos="head")
    her "Of course not, [genie_name]." ("base", "base", "base", "R", cheeks="blush")
    gen "Then why did you do it? Five times no less!" ("base", xpos="far_left", ypos="head")
    her "Well, it sort of just happened..." ("open", "happy", "base", "mid", cheeks="blush")
    her "I was jerking off this one boy..."
    her "And another boy walked in on us..."
    her "He called his friends..."
    her "One thing lead to another..." ("base", "narrow", "base", "mid_soft")
    gen "And you ended up jerking off five cocks..." ("base", xpos="far_left", ypos="head")
    her "... yes." ("soft", "narrow", "annoyed", "up")
    gen "At the same time?" ("base", xpos="far_left", ypos="head")
    her "*Mhmm*!" ("base", "narrow", "annoyed", "mid_soft")
    gen "And they came on you?!" ("grin", xpos="far_left", ypos="head")
    her "You have no idea." ("base", "base", "base", "mid_soft")
    gen "Well done, miss Granger, absolutely fantastic!" ("grin", xpos="far_left", ypos="head")
    her "" ("base", "narrow", "base", "mid_soft")

    jump end_hg_pr_handjob

label hg_pr_handjob_T6_E3:

    call hg_pr_handjob_intro

    her "It went well, [genie_name]." ("base", "base", "base", "mid")
    her "But, *Ehm*..." ("open", "base", "worried", "mid")
    gen "...?" ("base", xpos="far_left", ypos="head")
    her "Well, I did not wank off one of my classmates during break period..." ("open", "base", "base", "mid")
    her "I........."
    her "..............." ("clench", "narrow", "base", "down")
    gen "Spit it out, [hermione_name]. The suspense is killing me." ("base", xpos="far_left", ypos="head")
    call play_music("playful_tension") # Music
    her "I sort of did it during class..." ("open", "narrow", "worried", "down")
    gen "Impressive..." ("base", xpos="far_left", ypos="head")
    her "Sir, you don't understand.... Let me try and explain!" ("angry", "narrow", "base", "down")
    her "I don't even know what came over me."

    hide hermione_main
    show screen dual_hand_job # CG
    with d5

    her "I was trying to act as nonchalant as I could..." (ypos="head", flip=False)
    her "But, I suddenly had this incredibly pleasant urge to do it during Professor Snape's class."
    her "I couldn't even take notes with my other hand..."
    her "It was wrapped around another thick hot cock too."
    gen "You gave two boys handjobs at the same time?!" ("base", xpos="far_left", ypos="head")
    her "Yes Sir." ("angry", "wink", "base", "mid")
    her "And I think I gave them the wank of their life too..." ("base", "narrow", "worried", "down")
    her "Because they did not just cum."
    her "Their cocks simply exploded with spunk."
    gen "You enjoyed it, didn't you?" ("base", xpos="far_left", ypos="head")
    her "To be completely honest with you, sir... I did." ("grin", "narrow", "base", "dead")
    her "It was exciting." ("smile", "base", "angry", "mid")
    her "God, there was so much.  My hands looked like a candle had dripped hot wax all over them." ("grin", "narrow", "base", "dead")
    her "I didn't know what to do I couldn't just go about the rest of class with huge globs of cum all over my hands." ("angry", "narrow", "base", "down")
    her "So I decided to rub it all over the inside of my thighs to keep from having to stain my clothes."
    her "Every time I walked I could smell their cum from between my legs." ("silly", "narrow", "annoyed", "up")
    gen "That's quite an interesting story miss Granger." ("base", xpos="far_left", ypos="head")

    hide screen dual_hand_job
    with d5

    her "I definitely want them both at the same time." ("silly", "narrow", "base", "dead")
    gen "..." ("base", xpos="far_left", ypos="head")
    her "Yeah, two huge cocks exploding massive loads of cum everywhere." ("silly", "narrow", "annoyed", "up")
    gen "........" ("base", xpos="far_left", ypos="head")
    her "......." ("silly", "narrow", "annoyed", "up")
    gen "*Ehm*....." ("base", xpos="far_left", ypos="head")
    her "Oh god, I'm sorry [genie_name], I was thinking of something else." ("angry", "wide", "base", "stare")
    gen "Yes... sure, okay." ("base", xpos="far_left", ypos="head")
    her "" ("base", "base", "base", "mid")

    jump end_hg_pr_handjob
