# Cho Talk
label cho_talk:
    menu:
        #"-Working-":

        "-Discuss Quidditch Training-" (icon="interface/icons/small/quidditch.webp") if not cho_quid.lock_training:
            if cho_tier == 1:
                jump cc_ht_talk
            elif cho_tier == 2:
                jump cc_st_talk
            elif cho_tier == 3:
                jump cc_gt_talk

            jump cho_talk

        # Naming
        "\"-Address me only as-\"" if cho_quid.E1_complete:
            menu:
                "\"-Sir-\"":
                    $ cho_genie_name = "Sir"
                "\"-Dumbledore-\"":
                    $ cho_genie_name = "Dumbledore"
                "\"-Professor-\"":
                    $ cho_genie_name = "Professor"
                "\"-Coach-\"":
                    $ cho_genie_name = "Coach"
                "\"-Sergeant-\"":
                    $ cho_genie_name = "Sergeant"
                "\"-Captain-\"":
                    $ cho_genie_name = "Captain"
                "\"-Old Man-\"":
                    $ cho_genie_name = "Old Man"
                "\"-Daddy-\"" if cho_tier >= 4:
                    $ cho_genie_name = "Daddy"
                "-Custom Input-":
                    $ cho_genie_name = renpy.input("(Please enter the name.)", cho_genie_name, ALLOWED_CHARACTERS, length=14).strip() or "Professor"
                "\"-Never mind-\"":
                    jump cho_talk

            jump genie_cho_change

        "\"-From now on I will refer to you as-\"" if cho_quid.E1_complete:
            menu:
                "\"-Miss Chang-\"":
                    $ cho_name = "Miss Chang"
                "\"-Cho-\"":
                    $ cho_name = "Cho"
                "\"-Cadet-\"":
                    $ cho_name = "Cadet"
                "\"-Pilot-\"":
                    $ cho_name = "Pilot"
                "\"-Maggot-\"":
                    $ cho_name = "Maggot"
                "\"-Tomboy-\"":
                    $ cho_name = "Tomboy"
                "\"-Boy-\"":
                    $ cho_name = "Boy"
                "\"-Champ-\"" if cho_tier >= 4:
                    $ cho_name = "Champ"
                "\"-Slut-\"" if cho_tier >= 4:
                    $ cho_name = "Slut"
                "-Custom Input-":
                    $ cho_name = renpy.input("(Please enter the name.)", cho_name, ALLOWED_CHARACTERS, length=14).strip() or "Miss Chang"
                "\"-Never mind-\"":
                    jump cho_talk

            jump cho_name

        "\"-Never mind-\"":
            jump cho_requests

label genie_cho_change:
    if cho_genie_name == "Sir":
        cho "Certainly, sir." ("base", "base", "base", "mid")
    elif cho_genie_name == "Dumbledore":
        cho "Of course Dumbledore..." ("open", "base", "base", "mid")
    elif cho_genie_name == "Professor":
        cho "Yes Professor..." ("open", "base", "base", "mid")
    elif cho_genie_name == "Coach":
        cho "Yes Coach!" ("smile", "base", "base", "mid")
    elif cho_genie_name == "Sergeant":
        gen "Is that clear?" ("base", xpos="far_left", ypos="head")
        cho "Yes Sergeant!" ("smile", "base", "base", "mid")
    elif cho_genie_name == "Captain":
        cho "Yes Captain!" ("smile", "base", "base", "mid")
    elif cho_genie_name == "Old Man":
        cho "You want me to call you an old man?" ("soft", "base", "base", "mid")
        gen "Just \"Old man\" is good for now." ("base", xpos="far_left", ypos="head")
        cho "Okay then..." ("open", "base", "base", "R")
    elif cho_genie_name == "Daddy":
        cho "You want me to--" ("soft", "narrow", "base", "mid", cheeks="blush")
        gen "Call me daddy..." ("base", xpos="far_left", ypos="head")
        cho "..." ("base", "narrow", "base", "downR", cheeks="blush")
        cho "Yes daddy..." ("base", "narrow", "base", "down", cheeks="heavy_blush")
    else: #custom/fallback
        cho "Very well..." (face="neutral")
    jump cho_talk

label cho_name:
    if cho_name == "Miss Chang":
        cho "Of course [cho_genie_name]." ("base", "base", "base", "mid")
    elif cho_name == "Cho":
        cho "Of course [cho_genie_name]." ("base", "base", "base", "mid")
    elif cho_name == "Cadet":
        cho "Yes [cho_genie_name]!" ("smile", "base", "base", "mid")
    elif cho_name == "Pilot":
        cho "Yes [cho_genie_name]!" ("base", "base", "base", "mid")
    elif cho_name == "Maggot":
        cho "I--" ("angry", "narrow", "base", "mid")
        gen "..." ("base", xpos="far_left", ypos="head")
        cho "Yes [cho_genie_name]!" ("angry", "happyCl", "base", "mid")
    elif cho_name == "Tomboy":
        if cho_tier <= 3:
            cho "Tomboy?" ("soft", "base", "base", "mid")
            gen "Is that not accurate?" ("base", xpos="far_left", ypos="head")
            cho "I--{w=0.4} I suppose..." ("angry", "narrow", "base", "down")
            gen "Great! Tomboy it is!" ("base", xpos="far_left", ypos="head")
        else:
            cho "Am I not feminine enough for you?" ("annoyed", "narrow", "base", "mid", cheeks="blush")
            gen "Nonsense! You are feminine in all the right places." ("grin", xpos="far_left", ypos="head")
            gen "Except your personality..." ("base", xpos="far_left", ypos="head")
            cho "*Hmph*..." ("annoyed", "narrow", "base", "R", cheeks="blush")
            cho "Fine... I guess that's fair..." ("open", "narrow", "base", "R", cheeks="blush")
    elif cho_name == "Boy":
        if cho_tier <= 3:
            cho "You want to call me what?!" ("angry", "base", "base", "mid")
            gen "Boy!" ("base", xpos="far_left", ypos="head")
            cho "But [cho_genie_name]!" ("disgust", "narrow", "base", "mid")
            cho "I'm not a boy!" ("clench", "narrow", "base", "mid")
            gen "I know that..." ("base", xpos="far_left", ypos="head")
            cho "Then why--" ("angry", "base", "base", "mid")
            gen "Don't you wanna be one of the boys?" ("base", xpos="far_left", ypos="head")
            cho "...{w=0.4} What's that's supposed to mean?" ("disgust", "narrow", "base", "mid")
            gen "Well, I suppose maybe you're not fit to be one of the boys..." ("base", xpos="far_left", ypos="head")
            cho "No! I am! I can be one of the boys!" ("clench", "base", "base", "mid")
            gen "Great, then boy it is!" ("base", xpos="far_left", ypos="head")
            cho "..." ("smile", "base", "base", "mid") #smiles
            cho "..." ("disgust", "base", "base", "stare") #Hold on a minute...
        else:
            cho "Boy?" ("soft", "narrow", "base", "mid", cheeks="blush")
            cho "But [cho_genie_name]... Won't that be weird?" ("soft", "base", "base", "mid", cheeks="blush")
            gen "..." ("base", xpos="far_left", ypos="head")
            cho "Alright then... If that's what you're into..." ("base", "base", "base", "R", cheeks="blush")
    elif cho_name == "Champ":
        cho "Champ?" ("open", "base", "raised", "mid")
        gen "Yep... Gotta give some credit where it's due." ("base", xpos="far_left", ypos="head")
        cho "Oh... Thank you [cho_genie_name]..." ("smile", "base", "base", "mid")
    elif cho_name == "Slut":
        cho "You want to call me..." ("soft", "narrow", "base", "down", cheeks="heavy_blush")
        gen "A slut!" ("base", xpos="far_left", ypos="head")
        cho "..." ("horny", "narrow", "base", "stare", cheeks="heavy_blush") #horny
        cho "*Ah*...{w=0.4} Yes, I suppose that's fine..." ("soft", "narrow", "base", "mid", cheeks="heavy_blush")
    elif cho_name == "Princess": #Custom choice
        if cho_tier <= 3:
            cho "Princess?!" ("angry", "base", "base", "mid")
            gen "Yes, is that a problem?" ("base", xpos="far_left", ypos="head")
            cho "It's... It's a bit girly don't you think?" ("clench", "narrow", "base", "mid", cheeks="blush")
            gen "You're a girl, I see nothing wrong with it." ("base", xpos="far_left", ypos="head")
            cho "..." ("disgust", "narrow", "base", "mid", cheeks="blush")
            cho "Yes I suppose I am." ("disgust", "narrow", "base", "mid", cheeks="blush")
            cho "Fine..." ("annoyed", "base", "base", "mid", cheeks="blush")
        else:
            cho "You want to call me..." ("angry", "narrow", "base", "mid", cheeks="blush")
            gen "Princess." ("base", xpos="far_left", ypos="head")
            cho "..." ("angry", "narrow", "base", "downR", cheeks="blush")
            cho "Okay... I suppose you could call me that..." ("angry", "narrow", "base", "down", cheeks="blush")
    else: #custom/fallback
        cho "Very well..." (face="neutral")

    jump cho_talk
