

### Hermione Admire Panties ###

label hg_pf_admire_panties:

    gen "{size=-4}(I will ask her to show me her panties. Plain and simple.){/size}" ("base", xpos="far_left", ypos="head")

    if hg_pf_admire_panties.counter < 1:
        menu:
            "\"(Yes, let's do it!)\"":
                pass
            "\"(Not right now.)\"":
                jump hermione_favor_menu

    # Start Event
    $ current_payout = 10
    $ hg_pf_admire_panties.start()

    # End Event
    label end_hg_pf_admire_panties:

    # Setup
    stop music fadeout 2.0
    call hide_characters
    show screen blkfade
    with d3

    call her_chibi("stand","desk","base", flip=False)
    call gen_chibi("sit_behind_desk")

    $ hermione.wear("all")

    hide screen blkfade
    if her_tier <= 2:
        her ".................." ("annoyed", "base", "base", "R", trans=fade)
    elif her_tier <= 3:
        her "" ("annoyed", "narrow", "base", "down", cheeks="blush", trans=fade)
    elif her_tier <= 5:
        her "" ("base", "base", "base", "mid", trans=fade)
    else:
        her "" ("smile", "narrow", "base", "mid_soft", trans=fade)

    # If Hermione is at tier 4+, she does not care about points.
    if her_tier < 4 and current_payout > 0:
        $ gryffindor += current_payout
        gen "{number=current_payout} points to Gryffindor, [hermione_name]. Well done." ("base", xpos="far_left", ypos="head")

        if hg_pf_admire_panties.counter == 1: # First time
            her "Another {number=current_payout} points..." ("base", "narrow", "worried", "down")
            her "Can't wait to tell the guys!" ("smile", "happyCl", "base", "mid")
            her "Except that I can't actually tell them about any of this..." ("annoyed", "narrow", "angry", "R")

    pause 1.0
    if game.daytime:
        her "Well, my classes are about to start..." ("open", "closed", "base", "mid")
    else:
        her "It's getting pretty late, [genie_name]..." ("open", "closed", "base", "mid")
    her "Will this be all?" ("open", "base", "base", "mid")
    gen "Yes, you can go now." ("base", xpos="far_left", ypos="head")

    # Hermione stops at the door
    call her_walk("door", "base")

    # If Hermione is at tier 4+, she does not care/forgets about points.
    if her_tier >= 4:
        her "What about my points..."
        her "Eh... Who cares..."

    # Hermione leaves
    call her_chibi("leave")

    # Increase level
    if her_tier == 1:
        if her_whoring < 3: # Points til 3
            $ her_whoring += 1

    elif her_tier == 2:
        if her_whoring < 9: # Points til 9
            $ her_whoring += 1

    elif her_tier == 3:
        if her_whoring < 12: # Points til 12
            $ her_whoring += 1

    elif her_tier == 4:
        if her_whoring < 18: # Points til 18
            $ her_whoring += 1

    jump end_hermione_event

### Tier 1 ###

# Hermione reluctantly lifts her skirt for you.
# Event 1 (i) - Hermione is shocked about your suggestion.
# Event 2 (r) - Hermione still can't believe what you ask her to do.

label hg_pf_admire_panties_T1_intro_E1:
    gen "Nothing drastic, really..." ("base", xpos="far_left", ypos="head")
    gen "I just want you to show me your panties." ("base", xpos="far_left", ypos="head")
    her "My... panties...?" ("open", "base", "base", "mid")
    her "[genie_name]!" ("angry", "base", "angry", "mid")
    gen "I know, I know, this a little weird..." ("base", xpos="far_left", ypos="head")
    her "{size=+7}A little !?{/size}" ("shock", "wide", "base", "stare")
    her "This is completely inappropriate!"
    gen "Listen, we need to go through this phase before we get to the good stuff, alright?" ("base", xpos="far_left", ypos="head")
    her "The \"good stuff\"? [genie_name], I don't understand..." ("angry", "base", "base", "mid")
    gen "What don't you understand, [hermione_name]?" ("base", xpos="far_left", ypos="head")
    gen "Do you need these points or not?" ("base", xpos="far_left", ypos="head")
    her "I do..." ("disgust", "base", "base", "down")
    gen "Get up here and show them to me then..." ("base", xpos="far_left", ypos="head")
    her "............." ("angry", "base", "angry", "mid")

    call hg_pf_admire_panties_T1

    jump end_hg_pf_admire_panties


label hg_pf_admire_panties_T1_E1:
    gen "Nothing drastic, really..." ("base", xpos="far_left", ypos="head")
    gen "I just want you to show me your panties." ("base", xpos="far_left", ypos="head")
    her "This again?" ("angry", "base", "angry", "mid")
    gen "Yes. Show them to me..." ("base", xpos="far_left", ypos="head")
    her "............." ("angry", "base", "angry", "mid")

    call hg_pf_admire_panties_T1

    jump end_hg_pf_admire_panties


label hg_pf_admire_panties_T1: # Call label
    call hide_characters
    hide screen bld1
    with d3

    if hermione.is_any_worn("robe", "accessory"):
        $ hermione.strip("robe", "accessory")
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        pause 1.4

    call her_walk("desk", "base", reduce=0.8)
    pause .7

    if hermione.is_worn("bottom"):
        $ hermione.strip("bottom")
        call her_chibi("lift_skirt","desk","base")
        with d3
        call ctc
    else:
        call her_chibi("stand", "desk", "base")

    call play_music("playful_tension")
    her "....................." ("angry", "base", "angry", "mid", xpos="mid", ypos="base", trans=d3)
    call ctc

    menu:
        "-Stare at her face-":
            ">You study Hermione's face--"
            ">Wondering what's going through her mind right now."
            her "......................." ("angry", "narrow", "annoyed", "mid", emote="angry")

        "-Stare at her panties-":
            ">It's plain girlish underwear, nothing that an ordinary girl wouldn't wear."

    if hg_pf_admire_panties.counter > 1: # Second time
        her "......................." ("angry", "narrow", "base", "R", emote="angry")
    else: # First time
        her "......................." ("angry", "narrow", "annoyed", "mid", emote="angry")

    call ctc
    return

### Tier 2 ###

# Hermione lifts her skirt for you.
# Event 1 (i) - Hermione is embarrassed about what she's about to do.
# Event 2 (r) - Hermione is still not happy.

label hg_pf_admire_panties_T2_intro_E1:
    her "So, what will it be, [genie_name]?"
    gen "Nothing drastic, really..." ("base", xpos="far_left", ypos="head")
    gen "I just want you to show me your panties." ("base", xpos="far_left", ypos="head")

    if hg_pf_admire_panties.counter == 1:
        her "My Panties?!" ("clench", "base", "worried", "mid")
    else:
        her "Oh... again?" ("annoyed", "base", "worried", "R")

    gen "Just do it..." ("base", xpos="far_left", ypos="head")
    her ".................." ("annoyed", "base", "worried", "mid")

    call hg_pf_admire_panties_T2

    jump end_hg_pf_admire_panties

label hg_pf_admire_panties_T2_E1:
    her "What will it be, [genie_name]?"
    gen "I'd like you to show me your panties again." ("base", xpos="far_left", ypos="head")
    her ".................." ("annoyed", "base", "worried", "R")
    her "Alright..." ("open", "base", "worried", "R")

    call hg_pf_admire_panties_T2

    jump end_hg_pf_admire_panties

label hg_pf_admire_panties_T2: # Call label

    call hide_characters
    hide screen bld1
    with d3

    if hermione.is_any_worn("robe", "accessory"):
        $ hermione.strip("robe", "accessory")
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        pause 1.4

    call her_walk("desk", "base", reduce=0.8)
    pause .7

    if hermione.is_worn("bottom"):
        $ hermione.strip("bottom")
        call her_chibi("lift_skirt","desk","base")
        with d3
        call ctc
    else:
        call her_chibi("stand", "desk", "base")


    call play_music("playful_tension")
    her "Here, [genie_name]..." ("base", "base", "base", "mid", xpos="mid", ypos="base", trans=d3)
    call ctc

    menu:
        "\"You don't look too embarrassed...\"":
            her "That's not true..." ("base", "happy", "base", "mid")
            her "But it is a small price to pay if it means the Gryffindor house keeps the cup this year." ("base", "base", "base", "R")
            her "I know everyone will be so happy..."

        "\"I like your panties...\"":
            her "Thank you, [genie_name]..." ("base", "happy", "base", "mid")

        "-Keep looking into her eyes-":
            her ".............................." ("soft", "base", "base", "mid")
            her "...........................?"
            her "................................" ("grin", "base", "base", "R")
            her "[genie_name], please... You are embarrassing me." ("grin", "happyCl", "worried", "mid",emote="sweat")
    call ctc
    return

### Tier 3 ###
# Event 1 (i) - Ask her to take off her panties, she agrees to flash you quickly + variation if she has stripped.
# Event 2 (r) - Ask her to take off her panties, you make her stand for longer + variation if she has stripped.

label hg_pf_admire_panties_T3_intro_E1:
    if hg_pf_admire_panties.counter == 1:
        gen "[hermione_name], could you show me your panties?" ("base", xpos="far_left", ypos="head")
        if not hg_strip.trigger:
            her "My panties?" ("open", "narrow", "base", "mid")
            gen "If it's not too much trouble..." ("base", xpos="far_left", ypos="head")
            her "*Hmm*... I suppose not..." ("angry", "squint", "base", "R")
        else:
            her "I suppose... If it's just my panties..." ("angry", "squint", "base", "R")
            gen "(You'd be so lucky...)" ("base", xpos="far_left", ypos="head")
    else:
        gen "[hermione_name], I think it's time I took another look at your panties." ("base", xpos="far_left", ypos="head")
        if not hg_strip.trigger:
            her "Again?" ("open", "narrow", "base", "mid")
            gen "Yes, [hermione_name]." ("base", xpos="far_left", ypos="head")
            her "Okay." ("angry", "squint", "base", "R")
        else:
            her "Just my panties, right?" ("open", "squint", "base", "mid")
            gen "We'll see..." ("base", xpos="far_left", ypos="head")
            her "Right..." ("angry", "narrow", "base", "down")

    call hide_characters
    hide screen bld1
    with d3

    if hermione.is_any_worn("robe", "accessory"):
        $ hermione.strip("robe", "accessory")
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        pause 1.4

    call her_walk("desk", "base", reduce=0.8)
    pause .7

    if hermione.is_worn("bottom"):
        $ hermione.strip("bottom")
        call her_chibi("lift_skirt","desk","base")
        with d3
        call ctc
    else:
        call her_chibi("stand", "desk", "base")

    call play_music("playful_tension")
    her "There you go." ("base", "squint", "base", "mid", xpos="mid", ypos="base", trans=dissolve)

    gen "Very good, [hermione_name]." ("base", xpos="far_left", ypos="head")

    menu:
        "\"How are you feeling?\"":
            her "[genie_name]?" ("soft", "squint", "base", "mid")
            gen "How does it feel, knowing you're earning your house a lot of points." ("base", xpos="far_left", ypos="head")
            her "*Ehm*... Good?" ("angry", "happy", "base", "mid")
            her "I mean, as good as you could feel when you're showing the headmaster your panties." ("angry", "squint", "base", "R", cheeks="blush")
            gen "Glad to hear it." ("base", xpos="far_left", ypos="head")
        "-Stare at her face-":
            gen "You've got a very pretty face, [hermione_name]." ("base", xpos="far_left", ypos="head")
            her "[genie_name]?" ("angry", "base", "base", "mid")
            her "I thought you were supposed to be looking at my panties." ("angry", "narrow", "base", "mid")
            gen "Does it matter where I'm looking?" ("base", xpos="far_left", ypos="head")
            her "*Hmm*...{w=0.4} Well as long as you're still paying me..." ("angry", "narrow", "base", "R", cheeks="blush")
        "-Stare at her panties-":
            her "..." ("base", "squint", "base", "mid")
            her "...{fast}..." ("normal", "squint", "base", "mid")
            her "[genie_name]?" ("open", "squint", "base", "mid", cheeks="blush")
            gen "Yes, [hermione_name]?" ("base", xpos="far_left", ypos="head")
            her "You're staring very intently..." ("angry", "narrow", "base", "R", cheeks="blush")
            gen "Of course, I'm savouring every moment." ("base", xpos="far_left", ypos="head")
            her "Right..." ("open", "narrow", "base", "down", cheeks="blush")
            her "" ("normal", "narrow", "base", "down", cheeks="blush")
            call ctc

    her "Are we done?" ("open", "base", "base", "mid", cheeks="blush")
    gen "Not quite." ("base", xpos="far_left", ypos="head")
    her "[genie_name]?" ("angry", "base", "base", "mid", cheeks="blush")
    gen "First I'd like you to take those panties off." ("base", xpos="far_left", ypos="head")

    if not hg_strip.trigger:
        her "You want me to--" ("clench", "squint", "base", "mid", cheeks="blush")
        gen "Take them off for me, yes." ("base", xpos="far_left", ypos="head")
        her "..." ("disgust", "narrow", "base", "mid", cheeks="blush")
        gen "For Gryffindor, obviously." ("base", xpos="far_left", ypos="head")
        her "So I will get extra points for this?" ("open", "closed", "worried", "mid", cheeks="blush")
        gen "Of course, you shall receive twenty extra points..." ("base", xpos="far_left", ypos="head")
        her "*Hmm*..." ("annoyed", "narrow", "worried", "R", cheeks="blush")
        her "For how long?" ("open", "narrow", "base", "mid", cheeks="blush")
        gen "Just a quick peek shall suffice." ("base", xpos="far_left", ypos="head")
        her "Alright then..." ("open", "closed", "base", "mid", cheeks="blush")

        $ current_payout += 20
    else:
        her "I thought you just wanted me to show you my panties..." ("angry", "narrow", "base", "mid", cheeks="blush")
        gen "Yes, and now I want to see them slide off your legs." ("base", xpos="far_left", ypos="head")
        her "..." ("disgust", "narrow", "base", "down", cheeks="blush")
        gen "You'll get paid extra obviously..." ("base", xpos="far_left", ypos="head")
        her "...{w=0.4} How much extra?" ("open", "narrow", "base", "R", cheeks="blush")
        gen "Ten points." ("base", xpos="far_left", ypos="head")
        her "Just ten?" ("clench", "narrow", "base", "mid", cheeks="blush")
        gen "Ten points not good enough for a quick glance of what's under those panties?" ("base", xpos="far_left", ypos="head")
        gen "It's not like I haven't gotten a good look already..." ("base", xpos="far_left", ypos="head")
        her "..." ("annoyed", "narrow", "base", "down", cheeks="blush")
        her "I suppose... If it's just a quick glance..." ("open", "narrow", "base", "down", cheeks="blush")

        $ current_payout += 10

    her "..." ("normal", "narrow", "base", "down", cheeks="blush")

    $ renpy.sound.play("sounds/cloth_sound3.ogg")
    $ hermione.strip("panties")
    with d3

    her "" ("normal", "narrow", "base", "down", cheeks="blush")
    pause 4
    her "" ("angry", "narrow", "base", "mid", cheeks="blush")
    pause 3

    her "Okay, that's{nw}" ("open", "squint", "base", "mid", cheeks="blush")
    $ renpy.sound.play("sounds/cloth_sound3.ogg")
    $ hermione.wear("panties")
    her "Okay, that's{fast} enough..." ("open", "squint", "base", "mid", cheeks="blush")

    gen "Very well, [hermione_name]." ("base", xpos="far_left", ypos="head")

    jump end_hg_pf_admire_panties

label hg_pf_admire_panties_T3_E1:
    gen "[hermione_name], I think it's time I took another look at your panties." ("base", xpos="far_left", ypos="head")
    her "Just my panties?" ("open", "narrow", "base", "mid")
    gen "*Hmm*... We'll see..." ("base", xpos="far_left", ypos="head")
    her "Alright..." ("open", "squint", "base", "mid")

    call hide_characters
    hide screen bld1
    with d3

    if hermione.is_any_worn("robe", "accessory"):
        $ hermione.strip("robe", "accessory")
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        pause 1.4

    call her_walk("desk", "base", reduce=0.8)
    pause .7

    if hermione.is_worn("bottom"):
        $ hermione.strip("bottom")
        call her_chibi("lift_skirt","desk","base")
        with d3
        call ctc
    else:
        call her_chibi("stand", "desk", "base")

    call play_music("playful_tension")
    her "Here you go." ("base", "squint", "base", "mid", xpos="mid", ypos="base", trans=dissolve)
    call ctc

    gen "Excellent." ("base", xpos="far_left", ypos="head")

    menu:
        "\"You look pretty comfortable...\"":
            her "I guess..." ("open", "squint", "base", "R")
            her "It's not really that different from wearing bikini bottoms..." ("open", "closed", "base", "mid")
            her "I can just pretend that I'm at the lake." ("base", "closed", "base", "mid")
            gen "Right..." ("base", xpos="far_left", ypos="head")
            gen "(Then why not just pretend you're in the shower and bare it all.)" ("base", xpos="far_left", ypos="head")
        "\"Do you like showing off your panties?\"":
            her "Like, [genie_name]?" ("open", "squint", "base", "mid")
            gen "Yes [hermione_name]... Do you enjoy it?" ("base", xpos="far_left", ypos="head")
            her "*Hmm*... I don't mind it I guess..." ("open", "squint", "base", "R")
            her "As long as it makes my house happy." ("base", "base", "base", "mid")
            gen "I'm sure it does." ("base", xpos="far_left", ypos="head")
        "-Stare at her panties-":
            her "..." ("base", "squint", "base", "mid")
            her "...{fast}..." ("normal", "squint", "base", "mid")
            her "[genie_name]?" ("open", "squint", "base", "mid")
            gen "Yes, [hermione_name]?" ("base", xpos="far_left", ypos="head")
            her "Do you have to stare so intently at them?" ("angry", "squint", "base", "mid")
            gen "I don't." ("base", xpos="far_left", ypos="head")
            gen "..." ("base", xpos="far_left", ypos="head")
            her "You're still staring..." ("annoyed", "narrow", "base", "mid")
            gen "I don't have to... But I want to." ("base", xpos="far_left", ypos="head")
            her "Right..." ("angry", "narrow", "base", "R")

    menu:
        "\"Now take them off.\"":
            her "[genie_name]!" ("angry", "narrow", "base", "mid", cheeks="blush")
            gen "What?" ("base", xpos="far_left", ypos="head")
            gen "Surely you knew this was coming..." ("base", xpos="far_left", ypos="head")
            her "*Hmph*... I suppose..." ("clench", "narrow", "base", "R", cheeks="blush")
            gen "So?" ("base", xpos="far_left", ypos="head")
            her "Just a flash, right?" ("annoyed", "narrow", "base", "mid", cheeks="blush")
            gen "Right." ("base", xpos="far_left", ypos="head")

            $ renpy.sound.play("sounds/cloth_sound3.ogg")
            $ hermione.strip("panties")
            call ctc

            her "There--" ("angry", "narrow", "base", "mid", cheeks="blush") #Looks away
            call nar(">You stare intently at Hermione's exposed pussy.")
            her "..." ("angry", "narrow", "base", "R", cheeks="blush") #Looks at genie
            her "Okay, that's--" ("clench", "narrow", "base", "down", cheeks="blush")
            gen "Wait!" ("base", xpos="far_left", ypos="head")
            her "[genie_name]?" ("angry", "squint", "base", "mid", cheeks="blush")
            gen "I'm not done yet." ("base", xpos="far_left", ypos="head")
            her "But you said--" ("open", "squint", "worried", "mid", cheeks="blush")
            gen "Quiet." ("base", xpos="far_left", ypos="head")
            her "..." ("annoyed", "closed", "base", "mid", cheeks="blush")
            call ctc
            gen "Okay I'm done..." ("base", xpos="far_left", ypos="head")
        "-Let her go-":
            gen "Alright then, that shall do for now." ("base", xpos="far_left", ypos="head")

    jump end_hg_pf_admire_panties

### Tier 4 ###

# Event 1 (i) - Hermione is not wearing her panties.
# Event 2 (r) - No panties. You get to call her a slut.
# Event 3 (r) - Panties may or may not be equipped. Hermione asks to remove them or keep them on.

## Can unequip underwear in wardrobe at this stage ##
label hg_pf_admire_panties_T4_intro_E1:
    if hg_pf_admire_panties.counter == 1:
        gen "[hermione_name], I'd like you to show me your panties, if that's not too much trouble." ("base", xpos="far_left", ypos="head")
    else:
        gen "[hermione_name], I'd like you to show me your panties again, if that's not too much trouble." ("base", xpos="far_left", ypos="head")
    her "My panties?" ("open", "narrow", "worried", "down")
    gen "Yes [hermione_name]... Get up here will you..." ("base", xpos="far_left", ypos="head")
    her "Oh, Okay..." ("base", "narrow", "base", "down", cheeks="blush")

    call hide_characters
    hide screen bld1
    with d3

    if hermione.is_any_worn("robe", "accessory"):
        $ hermione.strip("robe", "accessory")
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        pause 1.4

    call her_walk("desk", "base", reduce=0.8)
    pause .7

    if not hermione.is_worn("bottom") and hermione.is_worn("panties"):
        call her_chibi("stand", "desk", "base")
        her "*Hmm*... You know what..." ("normal", "narrow", "base", "R", cheeks="blush", xpos="mid", ypos="base")
        $ hermione.strip("panties")
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        pause 1.4
        her "" ("base", "narrow", "base", "mid", cheeks="blush")
        call ctc

        gen "Looking to get extra points are you?" ("base", xpos="far_left", ypos="head")
        her "Perhaps..." ("base", "narrow", "worried", "down", cheeks="blush")
    else:
        if hermione.is_any_worn("bottom", "panties"):
            if hermione.is_worn("bottom", "panties"):
                call her_chibi("lift_skirt","desk","base")
            else:
                call her_chibi("stand", "desk", "base")
            $ hermione.strip("bottom", "panties")
            with d3
            pause.8

            her ".........................." ("base", "base", "base", "R", cheeks="blush", xpos="mid", ypos="base")
            gen "!!?" ("angry", xpos="far_left", ypos="head")

            her "" ("base", "narrow", "base", "mid_soft", cheeks="blush")
            call ctc

            # No Panties!
            gen "Where are your panties, [hermione_name]?" ("angry", xpos="far_left", ypos="head")
            her "Oh, lately I just don't feel like wearing them..." ("base", "narrow", "worried", "down", cheeks="blush")
        else:
            call her_chibi("stand", "desk", "base")

            her "*Ehm*..." ("open", "squint", "base", "R", cheeks="blush", xpos="mid", ypos="base")
            her "You asked me not to wear any panties [genie_name]..." ("base", "narrow", "worried", "down", cheeks="blush")
            gen "Oh... So I did..." ("base", xpos="far_left", ypos="head")
            gen "I just wanted to make sure you followed my instructions..." ("base", xpos="far_left", ypos="head")
            gen "Well done [hermione_name]!" ("base", xpos="far_left", ypos="head")
            her "Thank you [genie_name]..." ("base", "narrow", "worried", "mid", cheeks="blush")

    menu:
        "\"You little slut!\"":
            her "*Hmm*..."
            her "I suppose I am..." ("base", "narrow", "base", "mid_soft")
            her "Do I get extra points for that?"

            menu:
                "\"Absolutely!\"":
                    gen "Ten additional points to Gryffindor!" ("base", xpos="far_left", ypos="head")
                    her "Thank you, [genie_name]!" ("base", "happyCl", "worried", "mid")

                    $ gryffindor+= 10

                    call ctc

                "\"Absolutely not!\"":
                    her "Why not!?" ("scream", "closed", "angry", "mid")
                    gen "Sluts aren't getting paid." ("base", xpos="far_left", ypos="head")
                    gen "That's what makes them sluts." ("base", xpos="far_left", ypos="head")
                    her "Well are you even going to pay me {number=current_payout} points?" ("annoyed", "base", "angry", "mid")
                    gen "Are you a slut or are you a prostitute?" ("base", xpos="far_left", ypos="head")
                    her "{size=-4}... A slut. {/size}"
                    gen "Good girl." ("base", xpos="far_left", ypos="head")

                    $ current_payout = 0
                    $ her_mood +=5

                    call ctc

        "\"Good! {number=current_payout} points!\"":
            pass

    jump end_hg_pf_admire_panties

label hg_pf_admire_panties_T4_E1:
    gen "[hermione_name], I'd like you to show me your panties again if possible." ("base", xpos="far_left", ypos="head")
    her "Oh..." ("open", "narrow", "worried", "down")
    her "Well, that might be an issue..." ("base", "narrow", "base", "down", cheeks="blush")

    call hide_characters
    hide screen bld1
    with d3

    if hermione.is_any_worn("robe", "accessory"):
        $ hermione.strip("robe", "accessory")
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        pause 1.4

    call her_walk("desk", "base", reduce=0.8)
    pause .7

    if not hermione.is_worn("bottom") and hermione.is_worn("panties"):
        call her_chibi("stand", "desk", "base")
        her "I don't really feel like wearing them right now..." ("base", "narrow", "base", "R", cheeks="blush", xpos="mid", ypos="base")
        $ hermione.strip("panties")
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        pause 1.4
        her "" ("base", "narrow", "base", "mid", cheeks="blush")
        call ctc

        gen "Is that so?" ("base", xpos="far_left", ypos="head")
        her "Yes..." ("base", "narrow", "base", "mid", cheeks="blush")
    else:
        if hermione.is_any_worn("bottom", "panties"):
            if hermione.is_worn("bottom", "panties"):
                call her_chibi("lift_skirt","desk","base")
            else:
                call her_chibi("stand", "desk", "base")
            $ hermione.strip("bottom", "panties")
            with d3
            pause.8

            her "" ("base", "narrow", "base", "mid_soft", xpos="mid", ypos="base", trans=d3)
            call ctc

            # No Panties!
            gen "No panties again, [hermione_name]?" ("grin", xpos="far_left", ypos="head")
            her "Well... what's the point if they're just going to be in the way all the time..." ("base", "narrow", "worried", "down", cheeks="blush")
        else:
            call her_chibi("stand", "desk", "base")

            her "I'm not wearing any panties right now..." ("base", "narrow", "base", "mid", cheeks="blush", xpos="mid", ypos="base", trans=dissolve)
            her "Was I supposed to? I'm sure you asked me not to wear them..." ("open", "narrow", "worried", "down", cheeks="blush")
            gen "So I did... Good job [hermione_name]." ("base", xpos="far_left", ypos="head")
            gen "I'm glad that I can count on you doing what I ask of you." ("base", xpos="far_left", ypos="head")
            her "Oh... Thank you [genie_name]." ("base", "narrow", "worried", "mid", cheeks="blush")

    menu:
        "\"You little slut!\"":
            her "*Hmm*..."
            her "I suppose I am..." ("base", "narrow", "base", "mid_soft")
            her "Do I get extra points this time?"

            menu:
                "\"Absolutely!\"":
                    gen "Absolutely!" ("base", xpos="far_left", ypos="head")
                    gen "Ten additional points to Gryffindor!" ("base", xpos="far_left", ypos="head")
                    her "Thank you, [genie_name]!" ("base", "happyCl", "worried", "mid")

                    $ gryffindor+= 10

                    call ctc

                "\"Absolutely not!\"":



                    her "Why not!?" ("scream", "closed", "angry", "mid")
                    gen "Sluts aren't getting paid." ("base", xpos="far_left", ypos="head")
                    gen "That's what makes them sluts." ("base", xpos="far_left", ypos="head")
                    her "Well are you even going to pay me {number=current_payout} points?" ("annoyed", "base", "angry", "mid")
                    gen "Are you a slut or are you a prostitute?" ("base", xpos="far_left", ypos="head")
                    her "{size=-4}... A slut. {/size}"
                    gen "Good girl." ("base", xpos="far_left", ypos="head")

                    $ current_payout = 0
                    $ her_mood +=5

                    call ctc

        "\"Good! {number=current_payout} points!\"":
            pass


    her "I could put my panties back on for you, if you'd like that, [genie_name]?" ("open", "base", "base", "mid")

    menu:
        "\"Yes, put them back on!\"":
            her "Alright, [genie_name]." ("base", "narrow", "base", "mid_soft")
            hide hermione_main
            with d3
            ">Hermione puts on her panties."

            if not hermione.is_equipped("panties"):
                $ hermione.equip(her_panties_base1)
            else:
                $ hermione.wear("panties")

            her "" ("base", "narrow", "base", "mid_soft")
            call ctc

            her "I hope you like them..." ("soft", "base", "base", "R")

        "\"No, keep them off!\"":
            her "Of course, [genie_name]." ("soft", "narrow", "base", "mid")
            $ hermione.unequip("panties")
            call ctc

    jump end_hg_pf_admire_panties


label hg_pf_admire_panties_T4_E2:

    gen "[hermione_name], show me those cute panties of yours again." ("base", xpos="far_left", ypos="head")
    her "Oh..." ("open", "narrow", "worried", "down")
    her "Okay..." ("base", "narrow", "base", "down", cheeks="blush")

    call hide_characters
    hide screen bld1
    with d3

    if hermione.is_any_worn("robe", "accessory"):
        $ hermione.strip("robe", "accessory")
        $ renpy.sound.play("sounds/cloth_sound3.ogg")
        pause 1.4

    call her_walk("desk", "base", reduce=0.8)
    pause .7

    if hermione.is_worn("bottom"):
        $ hermione.strip("bottom")
        call her_chibi("lift_skirt","desk","base")
        with d3
        call ctc
    else:
        call her_chibi("stand", "desk", "base")

    her "" ("base", "narrow", "base", "mid_soft", xpos="mid", ypos="base", trans=d3)
    call ctc

    # No Panties.
    if not hermione.is_worn("panties"):
        gen "Where are your panties, [hermione_name]?" ("grin", xpos="far_left", ypos="head")
        her "You asked me not to wear any..." ("open", "squint", "base", "mid")
        gen "Oh right..." ("base", xpos="far_left", ypos="head")
        her "Most of the time I just leave them in the Gryffindor common room..." ("base", "squint", "base", "R")
        her "But I got them with me this time." ("base", "base", "base", "mid")
        call ctc

        her "If you'd like, [genie_name], I could put my panties back on for you." ("soft", "narrow", "base", "mid_soft")

        menu:
            "\"Yes, put them back on!\"":
                her "Alright, [genie_name]." ("base", "narrow", "base", "mid_soft")
                hide hermione_main
                with d3
                ">Hermione puts on her panties."

                if not hermione.is_equipped("panties"):
                    $ hermione.equip(her_panties_base1)
                else:
                    $ hermione.wear("panties")

                her "" ("base", "narrow", "base", "mid_soft")
                call ctc

                her "I hope you like them..." ("soft", "base", "base", "mid")

            "\"No, keep them off!\"":
                her "Of course, [genie_name]." ("soft", "narrow", "annoyed", "up")
                $ hermione.unequip("panties")
                call ctc

    else:
        her "Do you like them, [genie_name]?" ("base", "narrow", "base", "mid_soft")
        gen "Indeed I do, [hermione_name]..." ("base", xpos="far_left", ypos="head")
        call ctc

        her "I could take them off, if you'd like that, [genie_name]." ("open", "base", "base", "R")

        menu:
            "\"Yes, Take them off!\"":
                her "Alright, [genie_name]." ("soft", "narrow", "annoyed", "up")
                gen "And keep them off from now on!" ("base", xpos="far_left", ypos="head")
                her "Whatever you want, [genie_name]." ("base", "narrow", "base", "mid_soft")
                hide hermione_main
                with d3
                call nar(">Hermione takes off her panties.")

                $ hermione.unequip("panties")

                her "" ("base", "narrow", "base", "mid_soft")
                call ctc

                her "I hope you like it, [genie_name]..." ("angry", "wink", "base", "mid")

            "\"No, keep them on!\"":
                her "Sure, [genie_name]." ("base", "narrow", "base", "mid_soft")
                call ctc

    jump end_hg_pf_admire_panties
