
#hermione asks genie about who will be in-charge of the ball
label ball_quest_E1:
    stop music fadeout 1.0

    call her_walk(action="enter", xpos="mid", ypos="base")

    call play_music("chipper_doodle")
    her "[genie_name]?" ("soft", "base", "base", "mid", xpos="right", ypos="base")
    gen "[hermione_name], how can I help you?" ("base", xpos="far_left", ypos="head")
    her "[genie_name], have you made your decision yet on who will be in charge of the \"ABOC\" this year?" ("open", "base", "base", "mid")
    gen "\"ABOC\"?" ("base", xpos="far_left", ypos="head")
    her "The \"Autumn Ball Organization Committee\", [genie_name]..." ("open", "closed", "base", "mid")
    gen "*Ehm*... Sure..." ("base", xpos="far_left", ypos="head")
    her "Please excuse me if I am being too direct with this, [genie_name]..." ("normal", "squint", "angry", "mid")
    her "But I think you should put {b}me{/b} in charge." ("open", "closed", "angry", "mid")
    her "I did it last year and it was the best organised \"autumn ball\" Hogwarts has had in years." ("open", "closed", "base", "mid")
    her "You said so yourself, [genie_name]. Do you remember?" ("normal", "base", "base", "mid")
    gen "Right, of course..." ("base", xpos="far_left", ypos="head")
    her "So, is this a yes?" ("base", "base", "base", "mid")
    her "Does this mean I will be in charge again this year?" ("base", "base", "base", "mid")

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "\"You shall be in charge, [hermione_name].\"":
            her "Thank you, [genie_name]." ("base", "base", "base", "mid")

        "\"No. Professor Snape shall be in charge!\"":
            her "Professor Snape, [genie_name]?" ("open", "squint", "angry", "mid")
            her "But, traditionally organizing and hosting the ball is the responsibility of the students..." ("normal", "base", "angry", "mid")
            her "Teachers are only present as the guests of honour..." ("open", "closed", "angry", "mid")
            gen "Of course...{w=0.4} I was just kidding." ("base", xpos="far_left", ypos="head")
            gen "You shall be in charge, [hermione_name]..." ("base", xpos="far_left", ypos="head")

    gen "There is one condition, though..." ("base", xpos="far_left", ypos="head")
    her "Yes, [genie_name]?" ("normal", "squint", "angry", "mid")

    $ d_flag_01 = False
    $ d_flag_02 = False
    $ d_flag_03 = False # Masturbation flag

    label .choices:

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "\"Take some of those clothes off\"" if hermione.is_any_worn("top", "bottom", "bra", "panties"):
            $ her_mood += 5
            $ d_flag_01 = True

        "\"Just stand right there for a moment\"" if not hermione.is_worn("top", "bottom", "bra", "panties"):
            if hermione.is_any_worn("clothes"):
                gen "And take off those things you're wearing." ("base", xpos="far_left", ypos="head")
                her "Alright..." ("open", "squint", "base", "R")
                $ renpy.sound.play("sounds/cloth_sound3.ogg")
                $ hermione.strip("all")
            else:
                her "Just stand right here?" ("base", "base", "base", "R")
                gen "Yes, just stand right there for me..." ("base", xpos="far_left", ypos="head")
            her "..." ("base", "base", "base", "mid")
            her "Is that all?" ("open", "squint", "base", "mid")
            jump ball_quest_E1.after_strip

        "\"You will have to sleep with me.\"" if not d_flag_02 and not hg_pf_sex.counter > 0:
            $ her_mood += 10
            $ d_flag_02 = True

            her "I will have to... sleep...?" ("angry", "wide", "base", "mid")
            her "..................." ("angry", "base", "angry", "mid", cheeks="blush")
            call play_music("chipper_doodle") # HERMIONE'S THEME.
            her "I am not stupid, [genie_name]... Quite the opposite in fact." ("angry", "closed", "angry", "mid", cheeks="blush")
            her "And I understand that the nature of the favours I have been selling you lately..." ("open", "base", "angry", "R", cheeks="blush")
            her "... Might have led you to believe that I would be willing to..." ("open", "squint", "angry", "mid", cheeks="blush")
            her "... To let you have your way with me eventually, [genie_name]..." ("disgust", "squint", "angry", "L_soft", cheeks="blush")
            gen "Whaaa--? I would never--" ("base", xpos="far_left", ypos="head")
            her "Please, let me finish, [genie_name]." ("scream", "base", "angry", "mid",emote="angry", cheeks="blush")
            gen "Right..." ("base", xpos="far_left", ypos="head")
            her "I know that you are a rather wise man yourself, [genie_name]." ("angry", "base", "angry", "mid", cheeks="blush")
            her "So, please... understand this..." ("disgust", "narrow", "base", "L_soft", cheeks="blush")
            her "I may be willing to sacrifice my pride and even my dignity for the sake of my house..." ("open", "closed", "angry", "mid", cheeks="blush")
            her "But sleeping with my headmaster?" ("open", "squint", "annoyed", "mid", cheeks="blush")
            her "That is where I draw the line, [genie_name]." ("angry", "base", "angry", "mid", cheeks="blush")
            gen "Fine... in that case..." ("base", xpos="far_left", ypos="head")

            jump ball_quest_E1.choices

        "\"Never mind. the Position is yours.\"":
            $ her_mood = 0

            her "Really?" ("smile", "base", "base", "mid")
            gen "Yes." ("base", xpos="far_left", ypos="head")

            jump ball_quest_E1.end

    if d_flag_02:
        her "Do I have to?" ("annoyed", "base", "annoyed", "R", cheeks="blush")
        gen "No [hermione_name]..." ("base", xpos="far_left", ypos="head")
        gen "You don't have to take any clothes off..." ("base", xpos="far_left", ypos="head")
        her "Finally you're being reasonable." ("open", "closed", "base", "mid")
        if hermione.is_worn("panties"):
            gen "I only need you to pull those panties aside for easy access." ("grin", xpos="far_left", ypos="head")
        else:
            gen "I only need you to bend over my desk for easy access." ("grin", xpos="far_left", ypos="head")
        her "[genie_name]! I thought I established this already... I'm not going to sleep with you!" ("angry", "narrow", "angry", "mid", cheeks="blush")
        gen "Then the answer is yes..." ("base", xpos="far_left", ypos="head")
        gen "If you want to be in charge of My balls--" ("base", xpos="far_left", ypos="head")
        her "The \"Autumn Ball\", [genie_name]..." ("upset", "squint", "annoyed", "mid", cheeks="blush")
        her "But this isn't a favour... this is THE Autumn Ball we're talking about..." ("open", "squint", "angry", "mid")
        gen "Then would you say the job of organizing it is... an honour?" ("base", xpos="far_left", ypos="head")
        her "It is!" ("open", "closed", "base", "mid")
        gen "And you believe that you should be the one to do it?" ("base", xpos="far_left", ypos="head")
        her "I do!" ("open", "base", "base", "mid")
        gen "Well then..." ("base", xpos="far_left", ypos="head")
        gen "Show me what you're prepared to do for the privilege!" ("base", xpos="far_left", ypos="head")
    else:
        her "What?!" ("open", "base", "base", "mid")
        gen "What?" ("base", xpos="far_left", ypos="head")
        her "[genie_name]!" ("angry", "base", "angry", "mid")
        gen "What?" ("base", xpos="far_left", ypos="head")
        her "You are abusing your power, [genie_name]. Again!" ("disgust", "narrow", "base", "mid_soft")
        gen "Seriously? After all those favours you sold me?" ("base", xpos="far_left", ypos="head")
        her "Those were for the sake of my house, [genie_name]." ("annoyed", "narrow", "annoyed", "mid")
        gen "Well this one is for the sake of the \"Autumn prom\"." ("base", xpos="far_left", ypos="head")
        her "It's the \"Autumn Ball\", [genie_name]..." ("upset", "closed", "base", "mid")
        gen "Oh, come on..." ("base", xpos="far_left", ypos="head")
        gen "Entrusting the thing to somebody else would be a crime, you know that." ("base", xpos="far_left", ypos="head")
        her ".........." ("annoyed", "narrow", "angry", "R")
        gen "Don't you care about your classmates at all?" ("base", xpos="far_left", ypos="head")
        her "What?" ("open", "base", "base", "mid")
        gen "Put your selfishness aside for once, would you?" ("base", xpos="far_left", ypos="head")
        her "My... selfishness?" ("annoyed", "base", "worried", "R")
        gen "Your classmates deserve the best organised ball possible!" ("base", xpos="far_left", ypos="head")
        gen "And only {size=+5}YOU{/size} can give them that!" ("base", xpos="far_left", ypos="head")
        her "... that is true actually." ("angry", "narrow", "base", "down")
        gen "People depend on you, girl!" ("base", xpos="far_left", ypos="head")
        her "You... maybe you're right, [genie_name]." ("open", "narrow", "worried", "down")
        her "I must do this... Everyone depends on me." ("upset", "closed", "base", "mid")

    her "Just give me a second please." ("annoyed", "narrow", "base", "R")
    hide hermione_main
    with d5

    gen "............" ("base", xpos="far_left", ypos="head")

    call play_music("playful_tension") # SEX THEME.

    hide screen bld1
    hide hermione_main
    with d5

    #Walks to the door
    call her_walk("door", "base")

    #Locks the door
    pause.5
    call chibi_emote("thought","hermione")
    pause.5

    call chibi_emote("hide", "hermione")
    $ renpy.play('sounds/09_lock.ogg')
    pause 1.5

    #Returns from the door
    gen "......?" ("base", xpos="far_left", ypos="head")

    call her_walk("mid", "base")
    pause.2

    her "Just in case..." ("annoyed", "narrow", "angry", "R", cheeks="blush")

    $ d_flag_01 = False
    $ d_flag_02 = False

    gen ".........................." ("base", xpos="far_left", ypos="head")
    her "Okay then... what would you have me do?" ("normal", "base", "worried", "mid")

    label .choices2:

    if d_flag_01 and d_flag_02:
        if hermione.is_any_worn("clothes"):
            gen "Now take off everything else you're wearing." ("base", xpos="far_left", ypos="head")
            $ hermione.strip("all")

        jump ball_quest_E1.after_strip

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "\"Take your top off.\"" if not d_flag_01:
            $ d_flag_01 = True

            call play_music("playful_tension") # SEX THEME.

            if not hermione.is_worn("top"):
                her "Take off my what? I'm not exactly clothed, you know!" ("angry", "base", "annoyed", "R")
                if not hermione.is_worn("bra"):
                    her "Can't you see that my breasts are already on display?" ("annoyed", "squint", "angry", "mid")
                    gen "Right..." ("base", xpos="far_left", ypos="head")

                    jump ball_quest_E1.choices2
                else:
                    gen "You are still wearing a bra, aren't you?" ("base", xpos="far_left", ypos="head")

                    jump ball_quest_E1.bra

            her "............" ("annoyed", "base", "worried", "R_soft", cheeks="blush")

            pause.3

            # TODO Animation doesn't work if this option is chosen second.
            # The standing chibi will reflect clothing state (once we have a topless chibi, that is)
            # call her_chibi("lift_top","mid","base")
            # with d3
            # pause 2.0
            $ renpy.sound.play("sounds/cloth_sound3.ogg")
            $ hermione.strip("robe", "accessory")
            $ hermione.strip("top")

            call ctc

            if hermione.is_worn("bra"):
                pause 2.0
                gen "And your bra..." ("base", xpos="far_left", ypos="head")

                label .bra:

                her "..." ("annoyed", "base", "angry", "R_soft", cheeks="blush")
                $ renpy.sound.play("sounds/cloth_sound3.ogg")
                $ hermione.strip("bra")
                pause.5

            her "" ("soft", "base", "base", "R_soft", cheeks="blush")
            call ctc

            gen "Very good [hermione_name]..." ("base", xpos="far_left", ypos="head")
            gen "Your ample tits are always a welcome sight..." ("base", xpos="far_left", ypos="head")
            her "...................." ("disgust", "narrow", "base", "down", cheeks="blush")
            her "" ("normal", "base", "worried", "R_soft", cheeks="blush")

            jump ball_quest_E1.choices2

        "\"Take your bottoms off.\"" if not d_flag_02:
            $ d_flag_02 = True

            call play_music("playful_tension") # SEX THEME.
            $ hermione.strip("robe", "accessory")
            if not hermione.is_worn("bottom"):
                her "I would if you'd let me wear any!" ("angry", "base", "angry", "mid")
                if not hermione.is_worn("panties"):
                    her "You have no idea how cold Hogwarts can be this time of year!" ("annoyed", "base", "worried", "R")
                    gen "......." ("base", xpos="far_left", ypos="head")

                    jump ball_quest_E1.choices2
                else:
                    gen "You don't need any, in fact, you don't need your panties either!" ("grin", xpos="far_left", ypos="head")
                    gen "Take them off..." ("base", xpos="far_left", ypos="head")

                    jump ball_quest_E1.panties

            pause.3

            # TODO Animation doesn't work if this option is chosen second. Just use the standing chibi (ie. remove the commented code)
            # call her_chibi("lift_skirt","mid","base")
            # with d3
            # pause 2.0

            $ renpy.sound.play("sounds/cloth_sound3.ogg")
            $ hermione.strip("bottom")

            call ctc

            if hermione.is_worn("panties"):
                pause 2.0
                gen "And your panties..." ("base", xpos="far_left", ypos="head")

                label .panties:

                her "..." ("normal", "base", "low", "R_soft", cheeks="blush")
                $ renpy.sound.play("sounds/cloth_sound3.ogg")
                $ hermione.strip("panties")
                pause.5

            her "" ("annoyed", "base", "base", "R_soft", cheeks="blush")
            call ctc

            her ".............................." ("annoyed", "base", "angry", "R_soft", cheeks="blush")

            gen "What are you doing, girl?!" ("angry", xpos="far_left", ypos="head") with hpunch
            gen "I am your headmaster! Do you have no shame?!" ("angry", xpos="far_left", ypos="head")
            her "What?! But--" ("angry", "base", "angry", "mid", cheeks="blush")
            gen "*He-he*... Relax, [hermione_name]. I'm just kidding." ("grin", xpos="far_left", ypos="head")
            her "[genie_name], that was just mean." ("scream", "happyCl", "angry", "mid", cheeks="blush")
            gen "*He-he*..." ("grin", xpos="far_left", ypos="head")
            her "....................................." ("annoyed", "base", "worried", "R_soft", cheeks="blush")
            gen "I do like your cute little pussy though..." ("base", xpos="far_left", ypos="head")
            her "..... Thank you, [genie_name]." ("disgust", "base", "angry", "R_soft", cheeks="blush")

            jump ball_quest_E1.choices2

        "\"Never mind. The position is yours.\"" if d_flag_01 or d_flag_02:
            her "Really?" ("smile", "base", "base", "mid")

            jump ball_quest_E1.end

    label .after_strip:

    call her_chibi("stand")
    with d5
    pause 1.0

    gen "Looking good [hermione_name]..." ("grin", xpos="far_left", ypos="head")
    her "Happy now?" ("annoyed", "base", "worried", "R", cheeks="blush")
    her "Will you let me have the \"privilege\" of being in charge of the \"ABOC\" this year?" ("normal", "base", "worried", "mid")

    menu:
        "\"Of course... the Position is yours.\"":
            her "Really?" ("smile", "base", "base", "mid")

            jump ball_quest_E1.end

        "\"Touch yourself for me first...\"":
            $ hg_masturbated.triggered()
            $ d_flag_03 = True
            $ her_mood += 5

            her "You want me to..." ("shock", "wide", "base", "stare")
            gen "Flick the bean..." ("base", xpos="far_left", ypos="head")
            gen "Fondle those puppies..." ("base", xpos="far_left", ypos="head")
            her "I..." ("angry", "wide", "worried", "mid", cheeks="blush")
            gen "Or did you not want to be in charge?" ("base", xpos="far_left", ypos="head")
            her "Of... of course I do!" ("angry", "base", "worried", "down", cheeks="blush")
            gen "Then get on with it..." ("base", xpos="far_left", ypos="head")
            her "..." ("annoyed", "happyCl", "worried", "down", cheeks="blush")
            her "Fine..." ("disgust", "squint", "worried", "down", cheeks="blush")

            show screen blkfade
            with d5
            $ renpy.play("sounds/slick_02.ogg")
            with hpunch
            with kissiris
            $ hermione.set_pose("masturbate")
            $ hermione.set_body(armleft="on_pussy")
            her "" ("open", "squint", "worried", "mid", xpos=270)
            hide screen blkfade
            with d5

            pause 0.5

            her "*Ah*..." ("open", "squint", "worried", "R", cheeks="blush")
            gen "Ni-i-i-ce!" ("grin", xpos="far_left", ypos="head")
            play bg_sounds "sounds/slickloop.ogg" fadein 2
            her "*mmmh*..." ("open", "happyCl", "worried", "R", cheeks="blush")
            pause 0.4
            her "" ("soft", "closed", "base", "R", cheeks="blush")
            pause 0.4
            call ctc
            her "*Sob*!" ("soft", "squint", "worried", "R_soft", cheeks="blush", tears="soft")
            gen "*huh*?" ("base", xpos="far_left", ypos="head")
            her "Oh, please,{w=0.4} don't mind me, [genie_name]." ("open", "base", "base", "R", cheeks="blush", tears="crying")
            her "Just enjoy the... {w=0.5}the view..." ("upset", "happy", "base", "R", cheeks="blush", tears="soft")
            gen "Are you... crying?" ("base", xpos="far_left", ypos="head")
            stop bg_sounds

            # Hand down
            $ hermione.set_body(armleft="down")

            her "*Sob*! No, [genie_name]... *sob*!..." ("angry", "happyCl", "worried", "mid", cheeks="blush", tears="crying_blink")
            her "I... I enjoy touching myself...{w=0.5} In front of my headmaster *SOB*!" ("angry", "squint", "worried", "R_soft", cheeks="blush", tears="crying")

            # Hands on pussy, tits
            $ hermione.set_body_zorder(armright=3)
            $ hermione.set_body(armleft="on_pussy", armright="on_tits")

            play bg_sounds "sounds/slickloop.ogg" fadein 2
            her "*Ah*..." ("open", "squint", "worried", "R", cheeks="blush")
            her "These...{w=0.4} *Ah*...{w=0.5} are happy tears, [genie_name]." ("open", "narrow", "low", "R", cheeks="blush", tears="messy")
            her "I...{w=0.5} *Ah*...{w=0.5}... I'm sorry...{w=0.5} I can't help it! *Sob*!" ("angry", "happyCl", "worried", "mid_soft", cheeks="blush", tears="messy")
            gen "Are you sure that you are okay with this?" ("base", xpos="far_left", ypos="head")
            her "Yes...{w=0.4} *Ah*...{w=0.5} yes, sir, please.... *Sob*!" ("soft", "squint", "worried", "mid", cheeks="blush", tears="messy")
            her "Please keep looking as I...{w=0.3} pleasure myself *Sob*!" ("open", "narrow", "base", "mid_soft", cheeks="blush", tears="messy")
            her "" ("open", "narrow", "angry", "stare_soft", cheeks="blush", tears="messy")
            pause.2

            gen "(What the...?)" ("angry", xpos="far_left", ypos="head")
            with hpunch
            her "[genie_name], I am begging you!" ("soft", "narrow", "angry", "mid", cheeks="blush", tears="messy")
            gen "Kind of sounds like an order--" ("base", xpos="far_left", ypos="head")
            play bg_sounds "sounds/slickloopfast.ogg"
            her "I need it!" ("open", "narrow", "worried", "up_soft", cheeks="blush", tears="messy")
            her "... I need to shamelessly present my naked body before you like this!" ("soft", "narrow", "base", "up_soft", cheeks="blush", tears="messy")
            with hpunch
            gen ".............?" ("base", xpos="far_left", ypos="head")
            her "I need to feel this embarrassment and humiliation! *SOB*!" ("silly", "narrow", "angry", "dead", cheeks="blush", tears="messy")
            play bg_sounds "sounds/slickloopveryfast.ogg"
            her "The fate of the \"Autumn ball\" depends on this..." ("silly", "base", "worried", "mid_soft", cheeks="blush", tears="messy")
            her "So... [genie_name], please..."
            her "Keep looking at my naked breasts, and my pussy..." ("silly", "narrow", "worried", "mid", cheeks="blush", tears="messy")
            her "Look at me as I get wet for you..."
            her "*mmmh*..." ("open", "happyCl", "worried", "R", cheeks="blush", tears="messy") #disgusted #blushing
            call ctc


            with hpunch
            her "*Ah*...{w=0.5} Yes! Make my skin burn with shame, [genie_name]... *Sob*!" ("open", "narrow", "base", "up", cheeks="blush", tears="messy")
            gen "*Ehm*... right... Okay..." ("base", xpos="far_left", ypos="head")
            gen "Listen, I think this will do..." ("base", xpos="far_left", ypos="head")

            play bg_sounds "sounds/slickloop.ogg" fadein 2
            her "*Ah*...{w=0.5} Are you sure, [genie_name]?" ("open", "narrow", "base", "mid", cheeks="blush", tears="messy")
            her "Are you sure that you've humiliated me enough, [genie_name]?" ("base", "narrow", "worried", "mid_soft", cheeks="blush", tears="messy")
            gen "...................." ("base", xpos="far_left", ypos="head")
            gen "(Is she getting off on this or is she being sarcastic? I don't get it...)" ("base", xpos="far_left", ypos="head")
            her "*mmmh*............" ("open", "happyCl", "worried", "R", cheeks="blush", tears="messy")
            call ctc

            gen "That's enough..." ("base", xpos="far_left", ypos="head")
            her "" ("annoyed", "base", "base", "mid", cheeks="blush", tears="messy")
            gen "Just put your clothes back on, [hermione_name]. You're making me feel uncomfortable." ("base", xpos="far_left", ypos="head")
            stop bg_sounds fadeout 4
            her "..."

            # Reset pose
            $ hermione.set_body_zorder(armright=0)
            $ hermione.set_body(armleft="down", armright="down")
            $ hermione.set_pose(None)
            $ hermione.strip("all")

            her "As you wish, [genie_name]..." ("annoyed", "narrow", "angry", "R", cheeks="blush", tears="messy")

            stop music fadeout 3.0

    label .end:

    show screen blkfade
    with d5
    call her_chibi("stand","mid","base")
    her "" ("base", "happyCl", "base", "mid", xpos="right", ypos="base")
    $ hermione.wear("all")
    pause 2.0
    hide screen blkfade
    with d5

    call play_music("chipper_doodle")

    her "So... does this mean I'm officially in charge of this year's \"Autumn Ball Organization Committee\" now?" ("base", "happyCl", "base", "mid", xpos="right", ypos="base")
    gen "That you are." ("base", xpos="far_left", ypos="head")
    her "Thank you [genie_name]! You will not regret this, I promise!"
    if d_flag_03:
        call blktone
        gen "(That was weird... she sure changed her mood quick.)" ("base", xpos="far_left", ypos="head")
        gen "(Maybe she gets off on being humiliated...)" ("base", xpos="far_left", ypos="head")
        gen "(Guess I'll have to find out.)" ("base", xpos="far_left", ypos="head")
        call hide_blktone
    else:
        call blktone
        gen "{size=-4}(Why would I?){/size}" ("base", xpos="far_left", ypos="head")
        gen "{size=-4}(I couldn't care less about the whole thing...){/size}" ("base", xpos="far_left", ypos="head")
        call hide_blktone
    her "Well, I'd better go now. I have so many arrangements to make!" ("grin", "base", "base", "R")
    gen "By all means, [hermione_name]. Have a nice day." ("base", xpos="far_left", ypos="head")

    call her_walk(action="leave")
    pause.5

    call bld
    gen "........................................" ("base", xpos="far_left", ypos="head")
    gen "A ball, *huh*?" ("base", xpos="far_left", ypos="head")
    gen "I wonder if I will have to show up for that..." ("base", xpos="far_left", ypos="head")

    $ ball_quest.E1_complete = True

    $ hermione_busy = True
    $ ss_event_pause += 2 # Next event happens in 2 days.

    jump end_hermione_event


#Snape confronts genie about his ABOC decision

label ball_quest_E2:
    stop music fadeout 1.0

    call sna_walk(action="enter", xpos="mid", ypos="base")
    pause.2

    call play_music("snape")
    sna "Are you bloody insane?!" ("snape_01", xpos="base", ypos="base")
    gen "You know, sometimes I think I may be..." ("base", xpos="far_left", ypos="head")

    sna "You appointed {b}that{/b} girl as the head of the \"Autumn Ball Organization Committee\"?!!" ("snape_01")
    gen "I'm guessing that's bad?" ("base", xpos="far_left", ypos="head")
    sna "Bad?{w} {size=+5}BAD?!{/size}" ("snape_10")
    sna "{size=+5}That's a catastrophe!{/size}" ("snape_15")
    sna "last year's ball was completely horrible!" ("snape_16")
    gen "Was it? I heard differently..." ("base", xpos="far_left", ypos="head")
    sna "Oh really? And who told you that?" ("snape_10")
    gen "not a very reliable source apparently..." ("base", xpos="far_left", ypos="head")
    sna "Dammit... Dammit all to hell..." ("snape_08")
    sna "I had big plans for the thing..." ("snape_07")
    gen "Really? Like what?" ("base", xpos="far_left", ypos="head")
    sna "Oh, that doesn't matter now..." ("snape_06")
    #sna "The girl is a complete control freak..."
    sna "Now the girl will use the prefects or the ghosts to keep an eye on me throughout entire thing..."
    gen "Right, that reminds me..." ("base", xpos="far_left", ypos="head")
    gen "Am I supposed to show up as well?" ("base", xpos="far_left", ypos="head")
    sna "Show up?" ("snape_03")
    sna "You are expected to host the bloody thing!"
    sna "But don't you worry! I'll figure something out!" ("snape_09")
    sna "*Hmm*... I'll Probably have to host the ball instead..." ("snape_06")
    gen "............" ("base", xpos="far_left", ypos="head")
    sna "Well, the Autumn ball is about to happen and Hermione Granger is in charge..." ("snape_09")
    sna "There is no changing it now..."
    sna "Sorry for the outburst..." ("snape_05")
    sna "That girl brings out the worst in me..." ("snape_16")
    gen "Don't sweat it..." ("base", xpos="far_left", ypos="head")
    sna "You know what...?" ("snape_06")
    sna "I don't feel like working today..."
    sna "Do we still have any of Dumbledore's wine left?" ("snape_05")
    gen "I believe so..." ("base", xpos="far_left", ypos="head")
    sna "Great! Pour me some..." ("snape_02")
    gen "Seriously? You're just gonna bail on your class like that?" ("base", xpos="far_left", ypos="head")
    sna "Yeah, big news -- I hate my job." ("snape_03")
    sna "And since you are my boss..."
    sna "I don't know why I even bother teaching those so-called students..." ("snape_06")
    gen "To maintain the charade?" ("base", xpos="far_left", ypos="head")
    gen "for the Same reason why I never leave this room...?" ("base", xpos="far_left", ypos="head")
    sna "Right..." ("snape_05")
    sna "But you know what else could endanger our little enterprise?"
    sna "Me losing it during class and strangling a couple of Gryffindor maggots with my bare hands..." ("snape_07")
    gen "*Hmm*... I see your point..." ("base", xpos="far_left", ypos="head")
    sna "Seriously, man... I need a drink..." ("snape_06")

    hide snape_main
    call blkfade

    call gen_chibi("hide")
    show screen with_snape(ani=False)
    $ chair_OBJ.hidden = True

    $ fire_in_fireplace = True
    $ fireplace_OBJ.foreground = "fireplace_fire"
    call sna_chibi("hide")
    hide screen bld1
    call hide_blkfade

    call bld
    call nar(">Professor Snape spends the day in your chamber, drinking the stress away.")

    if sna_friendship < 100:
        call nar(">Your relationship with him has improved.")
        $ sna_friendship +=1

    $ ss_event_pause += 2
    $ hg_event_pause += 1

    $ ball_quest.E2_complete = True
    $ chair_OBJ.hidden = False
    $ fireplace_OBJ.foreground = None

    jump end_snape_hangout_no_points

label ball_quest_E3:
    stop music fadeout 1.0

    call her_walk(action="enter", xpos="mid", ypos="base")

    call play_music("chipper_doodle")
    her "My parents sent me the wrong dress!" ("angry", "base", "base", "mid", tears="soft", xpos="right", ypos="base")
    gen "Are You kidding me!?" ("base", xpos="far_left", ypos="head")
    her "They sent me the dress I wore to the ball last year..." ("angry", "base", "base", "mid", tears="soft")
    gen "Those inconsiderate bastards!" ("base", xpos="far_left", ypos="head")
    her "Are you making fun of me [genie_name]?" ("mad", "base", "worried", "mid", tears="soft")
    gen "Can you blame me?" ("base", xpos="far_left", ypos="head")
    her "I will become the laughingstock of Hogwarts! *Sob*!" ("clench", "base", "worried", "mid", cheeks="blush", tears="soft")
    her "My reputation is as good as ruined! *Sob*!" ("angry", "narrow", "base", "dead", cheeks="blush", tears="crying")
    gen "Seriously? After all the favours you sold me you care about a thing like this?" ("base", xpos="far_left", ypos="head")
    her "Wearing the same dress to the \"Autumn Ball\" for two years in a row would be more humiliating than any favour I sold you so far, [genie_name]." ("shock", "narrow", "base", "down", cheeks="blush", tears="crying")
    with hpunch
    gen "You've gotta be kidding me..." ("angry", xpos="far_left", ypos="head")
    her "Oh, you wouldn't understand..." ("angry", "squint", "base", "mid", cheeks="blush", tears="messy")
    her "You're just like my father!" ("scream", "base", "angry", "mid", cheeks="blush", tears="messy")
    gen "I beg your pardon?" ("base", xpos="far_left", ypos="head")
    her "I mean... *Ehm*..." ("open", "wide", "worried", "stare", cheeks="blush", tears="messy")
    her "Forgive me [genie_name]..."
    her "I don't know why I am telling you all of this..." ("shock", "narrow", "base", "down", cheeks="blush", tears="crying")
    gen "................" ("base", xpos="far_left", ypos="head")
    her "......................*sob*!" ("angry", "narrow", "base", "dead", cheeks="blush", tears="crying")
    her "I think I'd better go now...*sob*" ("angry", "squint", "base", "mid", cheeks="blush", tears="messy")
    gen "Well, don't let me keep you a moment longer, [hermione_name]..." ("base", xpos="far_left", ypos="head")

    call her_walk("door", "base")
    pause.3

    her "(My life is ruined...)" ("angry", "squint", "base", "mid", cheeks="blush", tears="messy", ypos="head", flip=False)
    pause.1

    call her_chibi("leave")

    call bld
    gen "*Hmm*... I don't remember ever seeing the girl this desperate..." ("base", xpos="far_left", ypos="head")
    gen "And that says a lot, all things considered..." ("base", xpos="far_left", ypos="head")
    gen "I suppose Whoring herself out for house points is a significantly smaller problem than not having a proper prom dress..." ("base", xpos="far_left", ypos="head")
    gen ".............." ("base", xpos="far_left", ypos="head")
    gen "Schoolgirls..." ("base", xpos="far_left", ypos="head")

    $ hermione_busy = True
    $ hg_event_pause += 1

    $ ball_quest.E3_complete = True

    jump end_hermione_event


label ball_quest_E4:
    stop music fadeout 1.0

    call her_walk(action="enter", xpos="mid", ypos="base")

    call play_music("chipper_doodle")
    call bld
    gen "[hermione_name]?" ("base", xpos="far_left", ypos="head")
    her "Sorry to disturb you [genie_name]..." ("open", "base", "worried", "mid", xpos="right", ypos="base")
    her "I came to apologise for my..." ("open", "base", "worried", "R")
    her "... My hysterical behaviour yesterday."
    gen "Sure thing, don't worry about it." ("base", xpos="far_left", ypos="head")
    her "Thank you, [genie_name]." ("open", "base", "base", "mid")
    her "Still, I cannot help but feel awful for causing a scene..." ("open", "closed", "angry", "mid")
    gen "So the issue has been resolved then?" ("base", xpos="far_left", ypos="head")
    her "Not really..." ("open", "base", "worried", "mid")
    her "Not at all actually..." ("annoyed", "narrow", "angry", "R")
    gen "*Hmm*...?" ("base", xpos="far_left", ypos="head")
    her "But it is not really a big deal..." ("annoyed", "narrow", "worried", "down")
    her "I'm just overreacting..."

    call play_music("despair")
    her "I won't be able to attend the ball this year... so what?" ("annoyed", "narrow", "worried", "down")
    her "I spent countless hours organising the event..." ("normal", "happyCl", "worried", "mid")
    her "I worked so hard... and..." ("open", "base", "worried", "mid", tears="soft")
    her "And now I will not even be able to...{w=0.3} to...{w=0.4} *Sob*!" ("shock", "base", "base", "R", cheeks="blush", tears="soft")
    her "To... *SOB*!" ("shock", "narrow", "base", "down", cheeks="blush", tears="crying")
    her "Excuse me [genie_name]!" ("angry", "squint", "base", "mid", cheeks="blush", tears="messy")
    hide hermione_main
    hide screen bld1
    with d3
    call gen_chibi("sit_behind_desk")
    with d1

    call her_walk(action="run", xpos="door", speed=2, reduce=True)
    call her_chibi("leave")

    call bld
    gen "......................................." ("base", xpos="far_left", ypos="head")
    gen "*Hmm*..." ("base", xpos="far_left", ypos="head")

    if clothing_store_intro_done:
        gen "Maybe I should pay Madam Mafkin a visit and ask for a dress..." ("base", xpos="far_left", ypos="head")
    else:
        gen "Maybe I should look around the castle and see if I can procure a dress for her." ("base", xpos="far_left", ypos="head")

    $ hermione_busy = True
    $ hg_event_pause += 1

    $ ball_quest.E4_complete = True
    $ her_outfit_ball.price = 1000 # Unlocks it in the store

    jump end_hermione_event

label ball_quest_E5:
    hide hermione_main
    with d5

    stop music fadeout 1.0
    gen "Here... This is for you..." ("base", xpos="far_left", ypos="head")

    call give_reward(">You give the ball dress to Hermione...","interface/icons/box_red_1.webp")

    her "*Hmm*...? What is this?" ("base", "base", "base", "mid")
    her "{size=+7}A DRESS?!{/size}" ("angry", "wide", "base", "stare")
    with hpunch
    gen "I thought that you--" ("base", xpos="far_left", ypos="head")

    call play_music("chipper_doodle") # HERMIONE'S THEME.
    her "[genie_name]!" ("angry", "base", "base", "mid", tears="soft")
    gen "What? What happened? Don't tell me it's the wrong colour or something!" ("angry", xpos="far_left", ypos="head")
    her "It's perfect, [genie_name]...*sob*!" ("angry", "base", "base", "mid", tears="soft")
    her "It's perfect... *sob*!... I love it."
    gen "You sure don't look like it..." ("base", xpos="far_left", ypos="head")
    her "I am sorry, [genie_name]... *Sob*!"
    her "I... I am just..." ("clench", "base", "worried", "mid", cheeks="blush", tears="soft")
    her "I am so happy..." ("shock", "narrow", "base", "down", cheeks="blush", tears="crying")
    her "Thank you, [genie_name]. Thank you so much."
    her "I cannot believe that you would do something like that for me..." ("angry", "squint", "base", "mid", cheeks="blush", tears="messy")
    gen "Well, I did. Now stop crying." ("base", xpos="far_left", ypos="head")
    her "I can't, [genie_name]. I am so happy and so grateful..." ("scream", "happyCl", "worried", "mid", cheeks="blush", tears="messy")
    her "Do you want me to suck your cock, [genie_name]?" ("open", "wide", "worried", "stare", cheeks="blush", tears="messy")
    gen "What?" ("base", xpos="far_left", ypos="head")
    her "Because I will do it!" ("open", "wide", "worried", "stare", cheeks="blush", tears="messy")
    her "And I will swallow and everything!"
    her "And you wouldn't have to pay me a single house point!" ("shock", "narrow", "base", "down", cheeks="blush", tears="crying")
    gen "*Uhm*... Maybe some other time..." ("base", xpos="far_left", ypos="head")
    gen "This is not the type of crying I find arousing..." ("base", xpos="far_left", ypos="head")
    her "I'm sorry, [genie_name]. I'm such a mess..." ("angry", "squint", "base", "mid", cheeks="blush", tears="messy")
    her "But this is so unexpected..." ("shock", "narrow", "base", "down", cheeks="blush", tears="crying")
    her "You made me so happy, [genie_name]... *sob*!"
    her "Thank you [genie_name]! *SOB*! Thank you! *SOB*!" ("angry", "squint", "base", "mid", cheeks="blush", tears="messy")
    gen "Well... *Err*... There, there..." ("base", xpos="far_left", ypos="head")
    gen "Better stop crying before you stain that new dress of yours with those tears..." ("base", xpos="far_left", ypos="head")
    her "My new dress! *SOB*!" ("scream", "happyCl", "worried", "mid", cheeks="blush", tears="messy")
    gen "Alright, you know what? Just get out of my office." ("base", xpos="far_left", ypos="head")
    gen "Just take your dress and leave." ("base", xpos="far_left", ypos="head")
    her "Of course... I am sorry, [genie_name]!" ("angry", "squint", "base", "mid", cheeks="blush", tears="messy")
    hide hermione_main
    hide screen bld1
    with d3
    pause.1

    call her_chibi("stand","mid","base")
    pause.3
    call her_chibi("stand","mid","base",flip=True)
    pause.2

    call her_walk(action="leave")

    call bld
    gen "......................" ("base", xpos="far_left", ypos="head")
    gen "Women..." ("base", xpos="far_left", ypos="head")

    $ hg_event_pause += 2

    $ ball_quest.gave_dress = True
    $ ball_outfit_ITEM.used = True

    jump end_hermione_event
