#TODO Add event checks for the existing writing variants once the other T4 Luna events are added

### Luna Suck It ###

label ll_pf_blowjob:

    if not _events_completed_any:
        gen "{size=-4}(*Hmm*... I wonder if I should ask Luna to suck me off...){/size}" ("base", xpos="far_left", ypos="head")
        menu:
            "\"(Yes, let's do it!)\"":
                pass

            "\"(Not right now.)\"":
                $ _event.cancel()
                jump luna_favor_menu

    # Start Event
    call hide_characters
    hide screen bld1
    show screen blkfade
    with d5
    pause 1

    $ lun_outfit_last.save() #Save Luna clothing
    $ luna.equip(lun_outfit_default) #Equip Luna Default clothing

    hide screen blkfade
    with d5

    return

label ll_pf_blowjob_end:

    # Setup
    stop music fadeout 2.0
    call hide_characters

    call gen_chibi("sit_behind_desk")

    # Reset Luna clothing.
    $ luna.equip(lun_outfit_last)

    if states.lun.tier == 4:
        if states.lun.level < 16:
            $ states.lun.level += 1

    jump end_luna_event

label ll_pf_blowjob_T4_E1_intro:

    call ll_pf_blowjob

    gen "I think it's about time we try a new technique to deal with those wankspurs." ("base", xpos="far_left", ypos="head")
    lun "This is the idea that you had, after I've told you about Professor Trelawney reading me my future?" ("open", "base", "base", "mid", xpos="base", ypos="base", trans=d3)
    gen "That's--" ("base", xpos="far_left", ypos="head")
    lun "\"I will soon find something new within me, that will propel me forward on the path towards my destiny!\"" ("grin", "closed", "base", "mid")
    lun "That's what she said!" ("grin", "base", "base", "mid")
    lun "Oh my goodness, I can hardly wait!" ("smile", "wide", "base", "mid")
    lun "These sessions have been so much fun." ("smile", "happyCl", "base", "mid")
    gen "Calm down, [name_luna_genie]..." ("base", xpos="far_left", ypos="head")
    gen "This research is very serious business." ("base", xpos="far_left", ypos="head")
    gen "So for this to succeed, I'll need you to focus and perform at your very best." ("base", xpos="far_left", ypos="head")
    lun "Can do, [name_genie_luna]!" ("smile", "base", "base", "mid")
    gen "Now... If you've calmed--" ("base", xpos="far_left", ypos="head")
    lun "So, I am to put something new inside of me?" ("smile", "wide", "base", "mid")
    gen "...{w} Well... New for you at least, but I'd say in terms of age, it's probably the oldest thing in here." ("base", xpos="far_left", ypos="head")
    lun "Wow!" ("open", "wide", "base", "mid")
    nar "Luna's eyes begins darting around your office."
    gen "*Err*...{w=0.4} What are you doing?" ("base", xpos="far_left", ypos="head")
    lun "Oh, I'm just looking around to see if I can spot what it might be." ("grin", "base", "base", "L")
    lun "You said it was very old, so it must be some kind of ancient, magical artefact, right?" ("grin", "base", "raised", "R")
    gen "That's not--{w=0.4} This isn't a setup for a game of hide and seek." ("angry", xpos="far_left", ypos="head")
    gen "If you could just shut your mouth for a moment, I'll tell you!" ("base", xpos="far_left", ypos="head")
    lun "..." ("normal", "base", "base", "mid")
    gen "*Sigh*..." ("base", xpos="far_left", ypos="head")
    gen "(I'm beginning to feel as if these tales I'm spinning are only self-serving at this point...)" ("base", xpos="far_left", ypos="head")
    gen "*Ahem*... So... My theory..." ("base", xpos="far_left", ypos="head")
    gen "It involves sucking those nasty things out." ("base", xpos="far_left", ypos="head")
    lun "..." ("normal", "wide", "base", "stare") #Wide eyed
    gen "I suppose it's a bit out there, I was afraid you might not be up for it." ("base", xpos="far_left", ypos="head")
    lun "..." ("angry", "wide", "base", "mid") #He did tell her to shut her mouth
    gen "..." ("base", xpos="far_left", ypos="head")
    gen "You--{w} You can talk now." ("base", xpos="far_left", ypos="head")
    lun "Sucking them out?!" ("mad", "wide", "base", "mid")
    lun "That's brilliant!" ("smile", "wide", "base", "mid")
    gen "...{w} It is?" ("angry", xpos="far_left", ypos="head")
    lun "Yes!" ("smile", "wide", "base", "mid")
    lun "What better way is there to get them all in one place than applying suction?" ("grin", "wide", "base", "mid")
    gen "That's what I thought!" ("grin", xpos="far_left", ypos="head")
    lun "But, [name_genie_luna]... How on earth are you supposed to suck them out of me?!" ("soft", "wide", "base", "mid")
    gen "..." ("base", xpos="far_left", ypos="head")
    lun "Oh, don't tell me!" ("smile", "base", "base", "stare")
    lun "You're going to put a wand inside of me and \"accio\" them out!" ("smile", "wide", "base", "mid")
    gen "(What the fuck.)" ("base", xpos="far_left", ypos="head")
    gen "While I appreciate your input, I think an easier approach is you, sucking them out of me..." ("base", xpos="far_left", ypos="head")
    lun "..." ("soft", "wide", "base", "stare")
    gen "Out of my cock." ("base", xpos="far_left", ypos="head")

    #TODO if you've not played label ll_pf_talk_T4_E1_repeat:
        #lun "..." ("base", "base", "base", "mid")
        #gen "*Sigh*... My Penis... [name_luna_genie]." ("base", xpos="far_left", ypos="head")

    lun "Using \"Accio\"?" ("soft", "wide", "base", "mid")
    gen "Using your mouth..." ("base", xpos="far_left", ypos="head")
    lun "Oh!" ("angry", "wide", "base", "stare")
    gen "I mean, if it's not too much to ask... I wouldn't want to--" ("base", xpos="far_left", ypos="head")
    lun "I'll do it!" ("smile", "base", "base", "mid")
    gen "Great!" ("base", xpos="far_left", ypos="head")
    gen "Then let's begin, shall we?" ("base", xpos="far_left", ypos="head")
    lun "Yay!" ("smile", "base", "base", "mid")

    #Luna quickly walks up towards the desk, fades to black

    call lun_walk("desk", "base", speed=1.75)
    show screen blkfade
    with d5

    if luna.is_any_worn("clothes"):
        $ _wearing_clothes = True
        $ luna.strip("clothes")
        nar "Luna hurriedly makes her way around your desk, strips down and then crawls underneath..."
    else:
        nar "Luna hurriedly makes her way around your desk and crawls underneath..."
    gen "*Err*... It's probably not the best idea to go under my--"

    show lun_blowjob_personal_pose1 as cg
    hide screen blkfade
    with d5

    gen "Desk..."

    show lun_blowjob_personal_pose1 eyebrows_shocked eyes_wide_left mouth_grin as cg with d3
    lun "My goodness...{w=0.4} I've never seen so much..."

    show lun_blowjob_personal_pose1 eyes_wide_right as cg with d3
    lun "There's more magic down here than under my Wiggentree!"
    gen "Wait...{w} Magic?"
    show lun_blowjob_personal_pose1 eyebrows_base eyes_base_stare mouth_base as cg with d3
    lun "Yes!"
    lun "Why I never would've imagined the wrackspurts drawing out this much magical essence..."
    show lun_blowjob_personal_pose1 eyebrows_raised mouth_grin as cg with d3
    lun "Can you not feel it, [name_genie_luna]?"
    show lun_blowjob_personal_pose1 eyebrows_shocked eyes_halflid_down as cg with d3
    lun "It's so heavy in the air... It's almost infused into the wood..."
    show lun_blowjob_personal_pose1 eyes_halflid_up_hearts as cg with d3
    lun "You can almost taste it..."

    show lun_blowjob_personal_pose1 eyes_closed mouth_base as cg with d3
    nar "Luna takes a deep breath of air under your soiled desk..."

    show lun_blowjob_personal_pose1 mouth_soft as cg with d3
    lun "Wow..."
    gen "Are you sure you're okay down there? I haven't cleaned it since...{w=0.5} well...{w=0.5} Ever..."
    show lun_blowjob_personal_pose1 mouth_base as cg with d3
    lun "I'm...{w=0.3} Great..."
    show lun_blowjob_personal_pose1 eyebrows_angry as cg with d3
    nar "Luna takes another deep breath..."
    gen "(She's got to be faking this... No one could be this oblivious...)"
    gen "(Still, better not look a gift horse in the mouth...)"

    show lun_blowjob_personal_pose1 eyes_halflid_stare as cg with d3
    nar "While the naive blonde sits under your desk, you decide it's finally time for her to get to work."

    menu:
        "-Pull your cock out-":

            show lun_blowjob_personal_pose1 no_trousers eyes_halflid_down mouth_soft as cg with d3

            nar "You swiftly pull out your hardening cock, and Luna grabs it without hesitation."

            show lun_blowjob_personal_pose1 eyebrows_base eyes_halflid_down mouth_neutral as cg with d3
            lun "{size=-5}Wow...{/size}"
            gen "Now, as I said... This technique requires you to suck those nasty little critters out of the affected area..."
            gen "And as you know... For me, that's right here."

            show lun_blowjob_personal_pose1 mouth_base as cg with d3
            lun "*Mmm*..."
            gen "Just try and make me feel as good as possible, and I'm sure those nasty little buggers will come..."

            show lun_blowjob_personal_pose1 eyebrows_raised mouth_open as cg with d3
            lun "Out?"
            gen "Yeah, out, that's it..."
            gen "Begin when you're ready, [name_luna_genie]."

            show lun_blowjob_personal_pose1 eyebrows_angry mouth_soft as cg with d3
            lun "Okay..."

            nar "Luna stares at your cock excitedly as she readies herself to take the head into her mouth."
            show lun_blowjob_personal_pose1 eyebrows_base mouth_open as cg with d3
            lun "Suck until they come..."

            #Luna puts dick in mouth
            show lun_blowjob_personal_pose2 mouth_kiss as cg with d3
            gen "*Ngh*!"

            show lun_blowjob_personal_pose2 eyes_halflid_stare as cg with d3
            lun "*Hmm*?"
            gen "I'm good, you just startled me--{w=0.4} I mean, them!"

            show lun_blowjob_personal_pose2 eyebrows_angry eyes_halflid_down as cg with d3
            gen "Now, I'll need you to--"

            show lun_blowjob_personal_pose3 as cg with d3

        "-Tell her to take it out-":

            gen "I'm a little tired..."
            gen "So, why don't you assist me by pulling out the \"affected area\"..."

            show lun_blowjob_personal_pose1 eyebrows_base eyes_halflid_down as cg with d3
            lun "Of course, [name_genie_luna]."

            show lun_blowjob_personal_pose1 no_trousers mouth_soft as cg with d3
            nar "Luna takes a deep breath and then withdraws your hardening cock."

            show lun_blowjob_personal_pose1 eyes_wide_down mouth_grin as cg with d3
            lun "(It looks so much bigger, when I'm this close...)"
            gen "You may proceed with the treatment, [name_luna_genie]..."

            play sound "sounds/sniff.ogg"
            show lun_blowjob_personal_pose1 eyebrows_worried eyes_closed as cg with d3
            lun "*Sniff* *Sniff*"

            gen "What are you--"

            show lun_blowjob_personal_pose2 as cg with d5
            lun "*Lick* *Lick*"
            gen "[name_luna_genie]?"

            show lun_blowjob_personal_pose2 mouth_kiss as cg with d3
            lun "*Kissing noises*"

            gen "[name_luna_genie]!"

            show lun_blowjob_personal_pose1 eyebrows_shocked eyes_wide_right mouth_soft as cg with d3
            lun "Sorry [name_genie_luna], I'm listening!"

            gen "As I said... You may proceed with the treatment..."

            show lun_blowjob_personal_pose1 eyebrows_shocked eyes_wide_stare as cg with d3
            lun "Oh... Right... Is there any particular way that I should suck on it, [name_genie_luna]?"
            gen "*Ahem*... Perhaps sucking isn't the right phrase to describe it..."
            gen "The goal is to lure them out, so just try and make the area feel good, first and foremost."

            show lun_blowjob_personal_pose1 eyebrows_base mouth_base as cg with d3
            lun "Okay then..."
            show lun_blowjob_personal_pose1 eyebrows_base eyes_halflid_down mouth_grin as cg with d3
            nar "Luna's eyes darts to your cock excitedly as she readies herself to take the head into her mouth."

            show lun_blowjob_personal_pose1 eyebrows_base eyes_wide_down mouth_open as cg with d3
            lun "I'll make sure to lure them out before you even know it!"
            gen "That's--"

            show lun_blowjob_personal_pose2 mouth_kiss as cg with d2

            show lun_blowjob_personal_pose3 as cg with d3

        "-Shove it in there!-":

            gen "Open wide!"

            show lun_blowjob_personal_pose3 no_trousers genie_arm_petting eyebrows_angry eyes_halflid_up as cg with d3
            nar "You quickly pull out your cock, and then pull Luna's head down your shaft."

            show lun_blowjob_personal_pose3 eyebrows_shocked eyes_wide_up as cg with d3
            lun "*Mff*!!!"
            gen "Sorry, I just couldn't wait any longer."

            show lun_blowjob_personal_pose3 eyebrows_base eyes_base_down as cg with d3
            lun "*Mhm*..."

            show lun_blowjob_personal_pose3 -genie_arm_petting as cg with d3
            gen "Glad you understand...{w=0.4} Now, why don't you start by--"


    show lun_blowjob_personal_pose4 as cg with d3

    play sound "sounds/gag_01.ogg"
    show lun_blowjob_personal_pose5 eyebrows_angry eyes_closed as cg with d3
    with vpunch

    nar "Luna pushes her head all the way down your shaft."
    gen "By the gods, girl!"
    show lun_blowjob_personal_pose5 eyebrows_raised eyes_base_up as cg with d3
    lun "*Gmph*?"

    #moves head back up
    show lun_blowjob_personal_pose4 penis_spit as cg with d3

    show lun_blowjob_personal_pose3 as cg with d3

    show lun_blowjob_personal_pose2 as cg with d3

    lun "*Ish shomhing whon*?"
    gen "N-no, of course not...{w=0.3} You're doing great..."

    show lun_blowjob_personal_pose2 eyebrows_shocked as cg with d3
    lun "*Hi ahm*?"

    gen "Yes..."
    show lun_blowjob_personal_pose2 eyebrows_base eyes_closed as cg with d3
    lun "*Schan khoo!*"

    show lun_blowjob_personal_pose2 mouth_kiss as cg with d2

    show lun_blowjob_personal_pose3 as cg with d3

    show lun_blowjob_personal_pose4 as cg with d3
    nar "After responding to your praise, Luna moves her tongue along the underside of your cock once again, and a sudden rush of pleasure runs through your body."
    gen "*Argh*..."

    show lun_blowjob_personal_pose4 eyes_base_up as cg with d3
    lun "*Hmm*?"
    gen "Would you please be careful, [name_luna_genie]!"

    #Takes cock out
    show lun_blowjob_personal_pose3 as cg with d3

    show lun_blowjob_personal_pose2 mouth_kiss as cg with d2

    show lun_blowjob_personal_pose1 eyes_halflid_up mouth_open_spit as cg with d3
    lun "*Pwah*..."

    show lun_blowjob_personal_pose1 eyebrows_worried mouth_annoyed as cg with d3
    lun "Was my performance not satisfactory, [name_genie_luna]?"
    gen "No, you were doing surprisingly well, but unless you know how to control your gag--"

    show lun_blowjob_personal_pose1 eyebrows_shocked eyes_wide_stare mouth_open as cg with d3
    lun "I knew it! I was hurting you!"

    show lun_blowjob_personal_pose1 eyebrows_angry eyes_base_down mouth_soft as cg with d3
    lun "Should I try inserting my wand and \"Accio\" them out instead?"
    gen "What?! That's sounding--{w=0.2} I mean, that sounds awful!"

    show lun_blowjob_personal_pose1 eyebrows_base eyes_base_stare as cg with d3
    lun "But, wasn't I doing it wrong?"
    gen "Of course not!"

    show lun_blowjob_personal_pose1 mouth_annoyed as cg with d3
    lun "Then how come you told me to be careful?"
    gen "I just figured..."

    show lun_blowjob_personal_pose1 eyebrows_raised as cg with d3
    lun "..."
    gen "You know what, just go for it...{w=0.4} I'm sure nothing bad will happen..."
    gen "It was probably those nasty wrinklespores that made me stop you in the first place anyway."

    show lun_blowjob_personal_pose1 eyebrows_angry eyes_halflid_down as cg with d3
    lun "Those tricksy little--"

    show lun_blowjob_personal_pose1 eyes_base_down mouth_open as cg with d3
    lun "Don't worry, [name_genie_luna], I'll get them out in no time!"

    play sound "sounds/spit.ogg"
    show lun_blowjob_personal_pose1 mouth_spitting as cg with d3
    lun "*Ptui*"

    show lun_blowjob_personal_pose1 handjob_moderate mouth_base as cg with d3
    nar "Without even hesitating, Luna spits on your cock and begins jerking you off."
    nar "Her fingers move across your shaft with ease, and you can feel yourself getting close to finishing already."

    show lun_blowjob_personal_pose1 eyes_base_stare mouth_soft as cg with d3
    lun "How's this, [name_genie_luna]? Is this how you usually do it?"
    gen "*Ah*...{w=0.4} Yes...{w=0.4} Very good, [name_luna_genie]."

    show lun_blowjob_personal_pose1 handjob_fast mouth_grin as cg with d3
    lun "Thank you, [name_genie_luna]!"
    gen "(*Ngh*...{w=0.4} How's she so good at this already?)"

    show lun_blowjob_personal_pose2 as cg with d3
    pause 0.2

    play background "sounds/slickloop.ogg" fadein 2
    show lun_blowjob_personal_loop as cg with d3

    gen "*Ghh*!!"
    gen "G--{w=0.2} Good work, [name_luna_genie]..."
    gen "I--{w=0.2} I think I can feel them coming...{w=0.4} Get ready!"

    gen "That's...{w=0.3} It...{w=0.3} Take all of my cum, you cumslut!"

    #Luna pulls out to speak, and takes a facial
    show lun_blowjob_personal_pose1 no_trousers penis_spit cum_precum eyebrows_shocked eyes_wide_stare mouth_open as cg with d3

    stop background fadeout 2
    lun "What did you call--"
    gen "*Argh*!"

    play sound "sounds/slick_01.ogg"
    show lun_blowjob_personal_pose1 cum_frame0 eyes_wide_down as cg with d2
    show lun_blowjob_personal_pose1 cum_frame1 eyes_wide_stare as cg with d2
    play sound "sounds/slick_01.ogg"
    show lun_blowjob_personal_pose1 cum_frame2 as cg with d2
    show lun_blowjob_personal_pose1 cum_frame3 as cg with d2
    show lun_blowjob_personal_pose1 cum_frame4 as cg with d2

    show lun_blowjob_personal_pose1 eyebrows_angry eyes_wide_down as cg with d2
    lun "Whoa!{w=0.4}{nw}"

    show lun_blowjob_personal_pose1 mouth_grin as cg
    lun "Whoa!{fast} You've covered me in wrackspurts, [name_genie_luna]!"
    gen "*Ah*...{w=0.4} I...{w=0.4} Sorry about--"
    show lun_blowjob_personal_pose1 eyes_closed as cg with d3
    lun "Oh, I'm so pleased I managed to get so many out at once!"

    show lun_blowjob_personal_pose1 eyes_wide_stare as cg with d3
    nar "Luna looks up at you happily as your cum slowly starts sliding down her face."

    gen "*Ahem*... Perhaps it'd be best if you got out from under the desk now."

    show lun_blowjob_personal_pose1 eyes_halflid_stare mouth_base as cg with d3
    lun "Of course, [name_genie_luna]."

    #Blackfade
    #Hide CG

    show screen blkfade with d3

    $ luna.set_cum(face="heavy")
    call lun_chibi("stand","desk","base", flip=False)

    nar "Luna crawls out and happily starts skipping to the front of your desk, then spinning around, she flicks some of the remains of your deed off her hair and onto the stone floor."

    #Fade to Office
    hide cg
    hide screen blkfade
    with d5

    play sound "sounds/giggle2.ogg"
    pause .8

    lun "I can't believe how fun this was!" ("smile", "happyCl", "base", "mid", xpos="mid", ypos="base", trans=d3)
    gen "Glad you enjoyed it." ("grin", xpos="far_left", ypos="head")
    lun "Just let me know when you require my assistance again." ("grin", "narrow", "base", "mid")
    gen "I most certainly will..." ("base", xpos="far_left", ypos="head")
    pause .8
    hide luna_main
    with d3

    call lun_chibi(flip=True)
    pause .5

    gen "[name_luna_genie]." ("base", xpos="far_left", ypos="head")
    gen "Aren't you forgetting something?" ("base", xpos="far_left", ypos="head")

    call lun_chibi(flip=False)

    lun "*Ehm*...{w=0.4} Probably...{w=0.4} I'm not the best when it comes to remembering things." ("angry", "base", "raised", "mid")
    gen "Don't you think you should clean yourself off a little, before heading to your dorm?" ("base", xpos="far_left", ypos="head")
    lun "Oh, don't worry [name_genie_luna], I'm not going to my dorm, I'm going to the library." ("base", "wink", "base", "mid")
    gen "That doesn't--" ("base", xpos="far_left", ypos="head")
    lun "Oh, wait! I {i}did{/i} forget something!" ("angry", "base", "base", "stare")
    gen "...{w=0.4} Right?" ("base", xpos="far_left", ypos="head")
    lun "You called me a cumslut." ("grin", "base", "base", "mid")
    gen "*Err*...{w=0.4} I did? You sure I didn't say...{w=0.4} *Err*...{w=0.4} thumb cut?!" ("angry", xpos="far_left", ypos="head")
    lun "No, I'm certain you said cumslut! You said it, just before you released a bucketload of wrackspurts all over my face!" ("grin", "base", "base", "mid")
    gen "Oh..." ("angry", xpos="far_left", ypos="head")
    lun "So, is that what I am?! What does it mean?!" ("smile", "base", "base", "mid")
    gen "*Err*...{w=0.4} I guess you--{w=0.2} Why, it just means that you enjoy making someone cum!" ("base", xpos="far_left", ypos="head")
    lun "Cum..." ("base", "narrow", "base", "down")
    lun "Is that another name for the magical essence that is released?" ("grin", "base", "raised", "mid")
    gen "Sure is...{w=0.4} I figured why not have a singular word for both the substance, and the action." ("base", xpos="far_left", ypos="head")
    lun "I like it!" ("smile", "base", "base", "mid")
    gen "And since you appeared to be enjoying it, I figured that cumslut would be an appropriate title for you." ("base", xpos="far_left", ypos="head")
    lun "Oooh...{w=0.4} I see!" ("grin", "base", "base", "stare")
    lun "You know me so well, [name_genie_luna]! I truly am a cumslut!" ("grin", "happyCl", "raised", "mid")
    gen "Indeed you are!" ("grin", xpos="far_left", ypos="head")
    lun "Well, I better let everyone know my new title!" ("base", "base", "base", "mid")
    gen "Oh, *Err*...{w=0.4} I don't think that's such a good idea."("base", xpos="far_left", ypos="head")
    lun "*Aww*... Why not?" ("annoyed", "wink", "base", "mid")
    gen "Because...{w=0.4} I'm your patient now! Yes, that's it!" ("grin", xpos="far_left", ypos="head")
    gen "Patient confidentiality and all that." ("grin", xpos="far_left", ypos="head")
    lun "I see! I think I've heard about that!" ("grin", "base", "base", "stare")
    lun "Well then, at least you can be pleased to know that I'm a cumslut now!" ("base", "base", "base", "mid")
    gen "Very pleased, indeed!" ("grin", xpos="far_left", ypos="head")
    lun "Well, I better get going...{w=0.4} Too-da-loo!" ("grin", "base", "base", "mid")

    call lun_walk(action="leave")

    gen "*Heh-heh*...{w=0.4} Very pleased..." ("grin", xpos="far_left", ypos="head")
    if _wearing_clothes:
        gen "(Wait... Wasn't she wearing something when she arrived?)" ("angry", xpos="far_left", ypos="head")
        gen "(And, she didn't even clean herself!)" ("angry", xpos="far_left", ypos="head")
    else:
        gen "(Wait, she didn't clean herself!)" ("angry", xpos="far_left", ypos="head")

    $ luna.set_cum(None)

    $ _wearing_clothes = False

    $ states.lun.ev.lun_cumslut_nickname_unlocked = True
    $ states.lun.status.blowjob = True
    $ states.lun.status.cumshot = True

    jump ll_pf_blowjob_end

label ll_pf_blowjob_T4_E2_intro:

    call ll_pf_blowjob

    gen "I've got another theory that I'd like us to try today, [name_luna_genie]." ("base", xpos="far_left", ypos="head")
    lun "Oh... Are we already finished with testing the sucking technique?" ("annoyed", "narrow", "base", "downL", xpos="base", ypos="base", trans=d3)
    gen "Heavens no!" ("base", xpos="far_left", ypos="head")
    gen "I'll need you to do it at least two more times as to not break the format." ("base", xpos="far_left", ypos="head")
    lun "The format?" ("soft", "narrow", "raised", "mid")
    gen "Since we've already made plenty of progress in terms of extracting. It is now time to explore the more important matter of disposing." ("base", xpos="far_left", ypos="head")
    lun "Ooooh...{w=0.4} Good idea, [name_genie_luna]!" ("grin", "base", "base", "stare")
    lun @ cheeks blush "Although...{w=0.4} Well, are you certain I am the most suitable person to help with this?" ("soft", "narrow", "base", "mid")
    gen "Most certainly, [name_luna_genie]." ("base", xpos="far_left", ypos="head")
    lun @ cheeks blush "I see..." ("base", "narrow", "base", "downL")
    lun "Well, in that case, why don't we try using \"scourgify\" on them?" ("grin", "base", "base", "mid")
    gen "Scurvy-what?" ("base", xpos="far_left", ypos="head")
    lun "The scouring charm!" ("base", "narrow", "base", "mid")
    lun "Professor Snape used it to wash the mouth of one of my classmates, when they let out a swear during class." ("open", "base", "base", "mid")
    lun "So, I figured if you use the charm on the wrackspurts as soon as they come out, it should clean them up in no time!" ("smile", "base", "base", "mid")
    gen "Well, I do think--" ("base", xpos="far_left", ypos="head")
    lun "And if that doesn't work, we could try the drought charm!" ("grin", "base", "base", "mid")
    lun "They'd get all dried out, and the only thing that'd remain is a flaky crust on my face!" ("grin", "closed", "base", "mid")
    gen "...{w} Or you could just swallow them." ("base", xpos="far_left", ypos="head")
    lun "Swallow--" ("soft", "wide", "base", "stare")
    lun "You believe that wrackspurts are unable to survive in someone's stomach, [name_genie_luna]?" ("soft", "wide", "base", "mid")
    gen "Sure...{w=0.4} Let's go with that." ("base", xpos="far_left", ypos="head")
    lun "Wow, your brilliance astounds me yet again, [name_genie_luna]." ("smile", "wide", "base", "mid")
    gen "So, are you up for it? Some women don't like to--" ("base", xpos="far_left", ypos="head")
    lun "Why of course, [name_genie_luna]!" ("smile", "happyCl", "base", "mid")
    lun "No trouble at all!" ("base", "base", "base", "mid")
    lun "May I crawl under your desk again?" ("grin", "base", "base", "mid")
    gen "You don't have to, I could just turn the chair around." ("base", xpos="far_left", ypos="head")
    lun "Oh no, I want to..." ("grin", "base", "base", "downL")
    lun "I've always been rather fond of small spaces..." ("base", "base", "base", "mid")
    lun "When I was a little girl, I used to hide under the roots of a huge {i}Wiggentree{/i} near our home..." ("base", "closed", "base", "mid")
    lun "I've never experienced a greater sense of security than when I sought shelter beneath the comforting embrace of that tree's roots." ("base", "narrow", "base", "downL")
    gen "..." ("base", xpos="far_left", ypos="head")
    gen "Then feel free to crawl under the desk if you must..." ("base", xpos="far_left", ypos="head")
    lun "Thank you, [name_genie_luna]." ("base", "base", "base", "mid")

    #Luna quickly walks up towards the desk, fades to black
    call lun_walk("desk", "base", speed=1.75)
    show screen blkfade
    with d5

    if luna.is_any_worn("clothes"):
        $ _wearing_clothes = True
        $ luna.strip("clothes")
        nar "Luna quickly makes her way around your desk, strips, and then crawls underneath."
    else:
        nar "Luna quickly makes her way around your desk, and crawls underneath."

    show lun_blowjob_personal_pose1 as cg
    hide screen blkfade
    with d5

    show lun_blowjob_personal_pose1 eyebrows_worried eyes_closed as cg with d3
    lun "*Ah*...{w=0.4} There's that familiar scent..."
    gen "..."

    show lun_blowjob_personal_pose1 eyebrows_base eyes_base_stare mouth_grin as cg with d3
    lun "I think I could get used to doing this..."
    gen "I don't doubt it."

    show lun_blowjob_personal_pose1 eyes_halflid_stare mouth_grin as cg with d3
    lun "It's like brushing your teeth, you know."
    gen "What?"
    gen "You better not get your teeth anywhere near it."

    play sound "sounds/giggle.ogg"
    pause 1

    #Luna smiles
    show lun_blowjob_personal_pose1 eyebrows_angry eyes_base_stare mouth_base as cg with d3
    lun "Not like that, silly..."

    show lun_blowjob_personal_pose1 eyes_halflid_down as cg with d3
    lun "What I meant, is that I wouldn't mind this becoming more of a habit, like brushing your teeth."
    gen "Right..."

    show lun_blowjob_personal_pose1 mouth_open as cg with d3
    lun "Although I must say..."

    #Luna pulls genies trousers down so his cock pops out

    show lun_blowjob_personal_pose1 no_trousers eyebrows_shocked eyes_halflid_down_hearts mouth_open_spit as cg with d3
    lun "I've found this activity to be far more enjoyable than brushing your teeth..."
    gen "If you say--"

    #Luna pushes her head down genie's shaft
    show lun_blowjob_personal_pose2 mouth_kiss as cg with d2
    show lun_blowjob_personal_pose3 as cg with d3
    show lun_blowjob_personal_pose4 as cg with d3

    play sound "sounds/gag_01.ogg"
    show lun_blowjob_personal_pose5 eyebrows_angry eyes_closed as cg with d3
    with vpunch

    gen "*Ngh*!"
    gen "Eager today, are we?"

    show lun_blowjob_personal_pose5 eyes_halflid_up as cg with d3
    lun "*Mhm*..."

    #moves head back up
    show lun_blowjob_personal_pose4 penis_spit as cg with d3

    show lun_blowjob_personal_pose3 as cg with d3

    show lun_blowjob_personal_pose2 as cg with d3

    lun "*Pwah*"
    gen "*Ah*....{w=0.4} Excellent work, [name_luna_genie]..."
    show lun_blowjob_personal_pose2 eyes_closed as cg with d3
    lun "*Glae U Ike Eet*"

    show lun_blowjob_personal_pose2 eyes_halflid_down_hearts as cg with d3
    show lun_blowjob_personal_pose2 mouth_kiss as cg with d2
    play background "sounds/slickloop.ogg" fadein 2
    show lun_blowjob_personal_loop as cg with d3
    nar "Without hesitating, Luna starts bobbing her head happily down your shaft, the thought of swallowing your cum being the only thing occupying her mind."
    nar "Looking down at the girl, you can't help but appreciate her commitment."
    gen "Now, I'm going to need you to--{w=0.4} Relax your throat...{w=0.4} We wouldn't want any of them to escape..."
    gen "You think you could do that?"
    lun "*Mhm*..."
    nar "You feel Luna's throat muscles relax slightly as she prepares herself to take your load down her throat."
    gen "*Ah*... Yes, that's it, [name_luna_genie]... Just like that."
    nar "Luna continues bobbing her head up and down your shaft happily, and you can feel your cock reaching all the way down towards the back of her throat..."
    gen "(Bloody hell... How is this girl... so good at this?)"
    lun "(*Hmm*...)"
    lun "(Looks like he's really enjoying it when I push my head down...)"

    #Luna moves down and keeps her head there
    stop background
    play sound "sounds/gag_03.ogg"
    show lun_blowjob_personal_pose5 penis_spit eyebrows_angry eyes_closed as cg with d3
    with vpunch
    gen "What are you--"

    show lun_blowjob_personal_pose5 eyes_halflid_up_hearts as cg with d3
    nar "With her head firmly down your shaft, Luna begins moving her tongue, the lack of oxygen barely even phasing her."
    gen "Girl... Don't forget you need to--"

    #Luna moves again
    play background "sounds/slickloop.ogg" fadein 2
    show lun_blowjob_personal_loop_ahegao as cg with d3
    nar "Luna starts bobbing her head again, although this time, you can sense the tip of her tongue playfully licking the underside of your shaft."
    nar "Taken aback by her sheer enthusiasm, you can't help but let out a groan of pleasure."

    gen "*Aaah*..."

    nar "Feeling yourself getting closer to the edge, you start to tense up your pelvis muscles."
    nar "Luna, eagerly anticipating your load, keeps sucking your cock fervently."

    gen "By the great desert--{w=0.3} Get ready, girl!"

    stop background
    show lun_blowjob_personal_pose5 penis_spit eyebrows_base eyes_halflid_down_hearts as cg with d3
    with vpunch
    lun "{heart}*Mmmf*{heart}"

    show lun_blowjob_personal_pose5 penis_spit eyebrows_angry eyes_halflid_up_hearts as cg with d3
    nar "You suddenly feel Luna's throat tense around your cock, and with a rush of pleasure coursing through your body, wave after wave of semen starts shooting down her throat."
    gen "*Nnngh*...{w=0.5} AAHH!!!!"

    #Bobbing stops and Genie cums down her throat
    play sound "sounds/slick_01.ogg"
    show lun_blowjob_personal_pose5 penis_spit eyebrows_base eyes_closed as cg with d3
    play sound "sounds/gulp.ogg"
    pause 1
    play sound "sounds/slick_01.ogg"
    show lun_blowjob_personal_pose5 throatpie_frame0 as cg with d3
    pause 1
    play sound "sounds/gag_05.ogg"
    show lun_blowjob_personal_pose5 throatpie_frame1 eyebrows_angry as cg with d3
    pause 1

    #Luna pulls out
    show lun_blowjob_personal_pose4 throatpie_frame0 as cg with d3
    show lun_blowjob_personal_pose3 as cg with d3
    show lun_blowjob_personal_pose2 mouth_kiss as cg with d3
    show lun_blowjob_personal_pose1 no_trousers eyebrows_worried eyes_halflid_up mouth_open_tongue as cg with d3

    lun "*Ah*...{w=0.4} I...{w=0.4} *Pant*...{w=0.5}{nw}"
    show lun_blowjob_personal_pose1 eyes_halflid_stare mouth_open_spit as cg
    lun "*Ah*... I... *Pant*...{fast} I couldn't--{w=0.2} I didn't manage to swallow them all, [name_genie_luna]..."
    gen "*Ah*...{w=0.4} Don't--{w=0.2} don't worry, [name_luna_genie]..."
    gen "Your performance... Was highly... Satisfactory..."

    show lun_blowjob_personal_pose1 eyes_halflid_down mouth_neutral as cg with d3
    lun "I...{w=0.4} Alright then..."

    show screen blkfade with d3

    show lun_blowjob_personal_pose5 eyebrows_angry eyes_halflid_down_hearts -throatpie_frame0 as cg with d3
    lun "..."
    gen "..."
    gen "[name_luna_genie]?"
    gen "You can come out from under the desk now..."
    lun "..."
    gen "[name_luna_genie]?"

    play sound "sounds/gltch.ogg"
    with kissiris
    pause 0.5
    hide screen blkfade with d3

    gen "[name_luna_genie]!"

    #moves head back up
    show lun_blowjob_personal_pose4 as cg with d3

    show lun_blowjob_personal_pose3 as cg with d3

    show lun_blowjob_personal_pose2 mouth_kiss as cg with d3
    lun "*Slrp-pop*!{w=0.4}{nw}"
    show lun_blowjob_personal_pose2 eyes_halflid_up_hearts as cg
    lun "*Slrp-pop*!{fast}"
    show lun_blowjob_personal_pose1 eyes_halflid_down mouth_base as cg with d3
    lun "There we are...{w=0.4}{nw}"
    show lun_blowjob_personal_pose1 eyes_halflid_down mouth_grin as cg
    lun "There we are...{fast} Much better..."

    show screen blkfade with d3

    call lun_chibi("stand","desk","base", flip=False)

    nar "With a contented smile, now spreading across her face, Luna crawls out and walks to the front of your desk."

    #Fade to Office
    hide cg
    hide screen blkfade
    with d5

    lun "Those nasty wrackspurts were giving you a lot of trouble, weren't they [name_genie_luna]?" ("open", "narrow", "worried", "mid", xpos="mid", ypos="base", trans=d3)
    lun "Swallowing them all sure proved itself quite a bit more difficult than I had anticipated..." ("soft", "narrow", "base", "mid")
    gen "Well, I certainly appreciate the extra effort you put into it." ("grin", xpos="far_left", ypos="head")
    lun "So... Do you believe I managed to dispose of them all, [name_genie_luna]?" ("soft", "narrow", "base", "downR")
    gen "What?" ("base", xpos="far_left", ypos="head")
    lun "Since I went back for seconds to clean them all up... Does that mean they're gone for good?" ("open", "base", "base", "mid")
    gen "I'm sure there's more to come..." ("base", xpos="far_left", ypos="head")
    lun "Oh... Well, that's good." ("base", "closed", "base", "mid")
    lun @ cheeks blush "I mean--" ("angry", "base", "base", "mid")
    gen "Now, if you don't mind..." ("base", xpos="far_left", ypos="head")
    gen "This encounter with those...{w=0.4} Things... Has left me rather exhausted..." ("base", xpos="far_left", ypos="head")
    lun "Oh... Okay..." ("soft", "base", "base", "downL")

    if _wearing_clothes:
        hide luna_main
        with d3
        $ luna.wear("all")
        with d3
        pause .5

    if game.daytime:
        lun "I best be off to divination class..." ("base", "base", "base", "mid")
    else:
        lun "I better head off to bed then." ("base", "base", "base", "mid")

    lun "Oh, before I go... There's something I wanted to ask you... If that's alright?" ("base", "base", "raised", "mid")
    gen "Sure thing." ("base", xpos="far_left", ypos="head")
    lun "I was thinking about that prediction Professor Trelawney performed on me." ("open", "base", "base", "R")
    gen "Right?" ("base", xpos="far_left", ypos="head")
    lun "It's just... How could something be a true prediction, if hearing it is required for it to become true?" ("open", "base", "base", "mid")
    gen "What?" ("base", xpos="far_left", ypos="head")
    lun "I mean... I shared the details of the prediction with you, didn't I? Then you subsequently derived an idea from its contents." ("open", "base", "base", "mid")
    lun "Doesn't that make the prediction more of a self-fulfilling prophecy, and not an actual prophecy?" ("open", "base", "raised", "mid")
    gen "..." ("base", xpos="far_left", ypos="head")
    gen "(The way this girl's mind figures things out, is genuinely unpredictable.)" ("base", xpos="far_left", ypos="head")
    gen "So, what you're saying is that fortune telling is just psychological manipulation, where the subject is lead down a path where they themselves allow it to become a reality?" ("base", xpos="far_left", ypos="head")
    lun "*Huh*?" ("angry", "base", "base", "mid")
    gen "Or that predictions are based on past knowledge, and even if you had not told me, it is something that I would've naturally come up with either way?" ("base", xpos="far_left", ypos="head")
    lun "*Ehm*..." ("disgust", "narrow", "base", "mid")
    gen "You've not been telling her about our research, have you?" ("base", xpos="far_left", ypos="head")
    lun "Oh--{w=0.4} Of course not!" ("angry", "base", "base", "mid")
    lun "The only way she'd know is if she was somehow able to read my mind!" ("angry", "base", "base", "mid")
    gen "I see... So, highly improbable." ("base", xpos="far_left", ypos="head")
    gen "Either way, while I'm always up for figuring out how this universe works, I believe there are more important things to prioritise." ("base", xpos="far_left", ypos="head")
    lun "This universe?" ("soft", "narrow", "base", "stare")
    gen "These priorities include this dick getting sucked on a regular basis." ("base", xpos="far_left", ypos="head")
    lun "Oh, why of course, [name_genie_luna]!" ("grin", "base", "base", "mid")
    lun "Just call for me any time you need me, and I'll be under your desk, sucking, before you know it!" ("smile", "base", "base", "mid")
    gen "So, you'll happily be my call girl?" ("base", xpos="far_left", ypos="head")
    lun "Of course, [name_genie_luna]!" ("base", "base", "base", "mid")
    gen "Well, you said it, not me." ("base", xpos="far_left", ypos="head")
    lun "..." ("base", "base", "base", "mid")
    gen "Well, go on then... How am I supposed to call you, unless you leave?" ("base", xpos="far_left", ypos="head")
    lun "Oh, right!" ("angry", "base", "base", "mid")
    if game.daytime:
        lun "Have a nice day!" ("smile", "base", "base", "mid")
    else:
        lun "Have a nice evening!" ("base", "base", "base", "mid")

    lun "And thanks for cumming in my mouth!" ("smile", "base", "base", "mid")
    gen "Oh...{w=0.4} *Err*...{w=0.4} You're welcome?" ("base", xpos="far_left", ypos="head")

    call lun_walk(action="leave")

    gen "...{w} (I feel like I've just unlocked a new fetish somehow...)" ("base", xpos="far_left", ypos="head")

    $ _wearing_clothes = False
    $ states.lun.status.gokkun = True

    jump ll_pf_blowjob_end

label ll_pf_blowjob_T4_E3_intro:

    call ll_pf_blowjob

    gen "[name_luna_genie], care to help me with--" ("base", xpos="far_left", ypos="head")
    lun "Of course, [name_genie_luna]! Today is Sunday, after all!" ("smile", "narrow", "base", "mid", xpos="base", ypos="base", trans=d3)

    call lun_walk("desk", "base", speed=1.75)

    gen "I didn't even tell you what--" ("base", xpos="far_left", ypos="head")
    gen "Wait...{w=0.4} It's Sunday?" ("base", xpos="far_left", ypos="head")
    gen "(I thought weekends didn't exist in this universe...)" ("base", xpos="far_left", ypos="head")
    lun "Yes! It's Mister Sun's happy day!" ("grin", "narrow", "base", "mid", xpos="mid", ypos="base", trans=d3)
    menu:
        "-Enough with the nonsense-":
            gen "And here I thought my calendar said {i}Suckday{/i} on it." ("base", xpos="far_left", ypos="head")
            lun "*Huh*?" ("angry", "base", "base", "mid")
            gen "That's why I called you here, to suck those spurts out for me." ("base", xpos="far_left", ypos="head")

            #giggles
            play sound "sounds/giggle.ogg"
            pause 1

            lun "Oh... You're so silly sometimes, [name_genie_luna]." ("grin", "happyCl", "base", "mid")
            gen "I'm a hundred percent serious." ("base", xpos="far_left", ypos="head")
            lun "Oh! Sorry, I don't always know when someone is joking..." ("angry", "narrow", "base", "mid")
            gen "So, since it's \"Suckday\" today...{w=0.4} You think you could help me?" ("base", xpos="far_left", ypos="head")
            lun "Of course!" ("angry", "base", "base", "mid")
        "-Humour her-":
            if game.daytime:
                if game.weather == "clear": #Sunny
                    gen "Right..." ("base", xpos="far_left", ypos="head")
                    lun "Can't you see the radiant joy on Mister Sun's face?" ("grin", "base", "base", "L")
                    gen "Looks like the same burning ball of fire to me." ("base", xpos="far_left", ypos="head")
                    lun "[name_genie_luna], don't look directly at him!" ("mad", "wide", "base", "mid")
                    gen "Whops." ("base", xpos="far_left", ypos="head")
                    gen "(Mortals and their weak retinas...)" ("base", xpos="far_left", ypos="head")
                    gen "(Hold on... Did she actually give me some useful advice--)" ("angry", xpos="far_left", ypos="head")
                    lun "The sun is rather bashful and doesn't like it when you stare directly at him." ("angry", "base", "base", "mid")
                    gen "(Never mind...)" ("base", xpos="far_left", ypos="head")
                else: #cloudy/rain/snow
                    gen "Are you sure about that?" ("base", xpos="far_left", ypos="head")
                    lun "Of course! Can't you see the radiant joy on Mister Sun's face?" ("smile", "base", "base", "L")
                    gen "*Err*... It's not really visible right now..." ("base", xpos="far_left", ypos="head")
                    lun "Oh..." ("soft", "narrow", "base", "L")
                    lun "Maybe he's just being shy..." ("open", "base", "base", "L")
                    gen "The sun... Is being, shy?" ("base", xpos="far_left", ypos="head")
                    lun "Obviously... Why else would Daddy tell not to look directly at him?" ("soft", "base", "base", "mid")
                    gen "...{w=0.4} I suppose that's a reasonable conclusion to make." ("base", xpos="far_left", ypos="head")
                    lun "That said... Even if he's being shy, that doesn't mean we shouldn't acknowledge him on his special day." ("base", "base", "base", "mid")
                    gen "(Hold on... Is she one of those sun worshippers?)" ("base", xpos="far_left", ypos="head")
                    gen "(Don't tell me she's been trying to groom me for some peculiar sacrificial role...)" ("base", xpos="far_left", ypos="head")
                    lun "Don't you think so too, [name_genie_luna]?" ("grin", "base", "base", "mid")
                    gen "(Is that why she's been trying so hard to suck me dry?)" ("base", xpos="far_left", ypos="head")
                    lun "[name_genie_luna]?" ("soft", "base", "base", "mid")
                    gen "Please, don't suck me dry!" ("base", xpos="far_left", ypos="head")
                    lun "*Huh*?" ("angry", "base", "base", "mid")
                    gen "*Err*... Never mind..." ("base", xpos="far_left", ypos="head")
            else:
                gen "Right..." ("base", xpos="far_left", ypos="head")
                gen "Why is it his happy day, again?" ("base", xpos="far_left", ypos="head")
                lun "Because he gets to remind us about our limited time on this earth." ("grin", "base", "base", "mid")
                gen "I see... Sounds like a very happy occasion indeed..." ("base", xpos="far_left", ypos="head")
                gen "So, what is it this time, an impending alien abduction or something?" ("base", xpos="far_left", ypos="head")

                #giggles
                play sound "sounds/giggle.ogg"
                pause 1

                lun "Good one, [name_genie_luna]!" ("smile", "narrow", "base", "mid")
                gen "(So, she doesn't believe in aliens... The irony...)" ("base", xpos="far_left", ypos="head")
                lun "..." ("grin", "base", "base", "mid") #smiles
                gen "..." ("base", xpos="far_left", ypos="head")


            gen "So... What's so special about Sundays, exactly?" ("base", xpos="far_left", ypos="head")
            lun "I'm glad you asked!" ("grin", "base", "base", "mid")
            lun "Sundays are the day of the week when we acknowledge the importance of the sun." ("grin", "narrow", "base", "mid")
            gen "Right..." ("base", xpos="far_left", ypos="head")
            lun "The sun's movement reminds us all to spend our time on this earth to the fullest, after all." ("grin", "base", "base", "mid")
            gen "*Hmm*... Well, I can't say that I can relate to that very much." ("base", xpos="far_left", ypos="head")
            lun "It also marks the end of the weekend and makes you look forward to getting back to work or school the next day." ("base", "base", "base", "mid")
            gen "Ah, yes. Now that certainly is  relatable..." ("base", xpos="far_left", ypos="head")
            lun "The sun itself should also be appreciated, as it has given us life itself." ("smile", "base", "base", "mid")
            lun "I mean, I wouldn't be standing here if it wasn't for the sun." ("grin", "narrow", "base", "mid")
            gen "Then let's not waste the day any further!" ("base", xpos="far_left", ypos="head")
            gen "If I'm to live life to the fullest, then I'll require your help again, [name_luna_genie]." ("base", xpos="far_left", ypos="head")
            lun "Again, [name_genie_luna]?" ("soft", "base", "base", "mid")
            gen "The spurts have been quite lively today... Must be because it's Sunday and all that." ("base", xpos="far_left", ypos="head")
            lun "Oh, I see!" ("smile", "base", "base", "mid")
            gen "So, do you think you and your mouth could help me again?" ("base", xpos="far_left", ypos="head")
            lun "Certainly [name_genie_luna], I'd be happy to!" ("grin", "base", "base", "mid")
            gen "Praise the sun!" ("grin", xpos="far_left", ypos="head")

    lun "My mouth is here for you, whenever you need it, [name_genie_luna]." ("smile", "base", "base", "mid")
    gen "That's--" ("grin", xpos="far_left", ypos="head")
    lun "Any time!" ("smile", "wide", "base", "mid")
    gen "Greatly appreciated--" ("grin", xpos="far_left", ypos="head")
    lun "Even if I'm asleep!" ("smile", "wide", "base", "mid")
    gen "..." ("angry", xpos="far_left", ypos="head")
    lun "So, just wake me up whenever you need it!" ("grin", "wink", "base", "mid")
    lun "I even made sure to brush my tongue for you!" ("smile", "base", "base", "mid")
    gen "Well, that's--" ("base", xpos="far_left", ypos="head")
    lun "Look!{w=0.4}{nw}" ("scream", "base", "base", "mid")
    lun "Look!{fast} Aaaaaah..." ("open_wide_tongue", "base", "base", "mid")
    gen "Right...{w=0.4} Well, I don't think--" ("base", xpos="far_left", ypos="head")
    lun "If you don't believe it, you could always brush it yourself!" ("grin", "base", "base", "mid")
    lun "Would you like that, [name_genie_luna]?" ("smile", "base", "base", "mid")
    gen "That's--{w=0.2} You didn't watch a certain video since your last visit, did you?" ("base", xpos="far_left", ypos="head")
    lun "A what?" ("soft", "base", "base", "mid")
    gen "Never mind..." ("base", xpos="far_left", ypos="head")
    gen "So... Ready to suck some dick?" ("base", xpos="far_left", ypos="head")
    lun "Of course, [name_genie_luna]! I love sucking dick!" ("smile", "base", "base", "mid")
    gen "...{w=0.4} You do?" ("base", xpos="far_left", ypos="head")
    lun "Oh, it's an absolute blast!" ("grin", "base", "base", "mid")
    gen "..." ("base", xpos="far_left", ypos="head")
    lun "I mean...{w=0.4} Focusing on ridding you of wrackspurts is my top priority, not having fun, of course!" ("angry", "base", "base", "mid")
    gen "*He-heh*" ("grin", xpos="far_left", ypos="head")
    gen "Well, I certainly don't see anything wrong with you having a bit of fun, as long as you get the job done..." ("base", xpos="far_left", ypos="head")
    lun "Great!" ("grin", "base", "base", "mid")

    show screen blkfade
    with d5

    if luna.is_any_worn("clothes"):
        $ _wearing_clothes = True
        $ luna.strip("clothes")

    gen "Under the desk again, [name_luna_genie]?"
    lun "I like it down here..."
    gen "Very well..."

    show lun_blowjob_personal_pose1 no_trousers eyebrows_angry eyes_halflid_down_hearts mouth_base as cg
    hide screen blkfade
    with d5

    lun "*Mmm*...{w=0.4} Hello there Mister penis..."
    gen "(Somehow I'm feeling like a third wheel, even though it's only the two of us...)"

    show lun_blowjob_personal_pose1 mouth_open_spit as cg with d3
    pause 0.4
    gen "Steady girl...{w=0.4} There's no need to rush..."

    show lun_blowjob_personal_pose1 eyes_halflid_stare_hearts mouth_soft as cg with d3
    lun "But..."
    gen "Fine...{w=0.4} Go on then..."

    show lun_blowjob_personal_pose1 eyes_halflid_down_hearts mouth_grin as cg with d3
    lun "Yay!"

    show screen blkfade
    with d5

    play background "sounds/slickloop.ogg" fadein 2
    show lun_blowjob_personal_loop_ahegao as cg with d3

    nar "Over the next hour, Luna remains kneeling beneath your desk, relentlessly assaulting your cock as if her life depended on it."

    hide screen blkfade
    with d5

    gen "I--{w=0.2} I think this is it!"
    lun "*Mmm*..."
    gen "Get ready to--"

    play sound "sounds/gag_01.ogg"
    stop background fadeout 2
    show lun_blowjob_personal_pose5 penis_spit eyebrows_base eyes_closed as cg with d3
    nar "Before you can finish your sentence, Luna thrusts her head forward, forcing your cock down her throat."

    show lun_blowjob_personal_pose5 genie_arm_idle as cg with d3
    nar "You grab the edge of your desk to steady yourself as your balls begin to contract, releasing one of the largest loads of your life."
    gen "By the--"

    #Bobbing stops and Genie cums down her throat

    play sound "sounds/slick_01.ogg"
    show lun_blowjob_personal_pose5 eyes_halflid_down_hearts as cg with d3
    play sound "sounds/gulp.ogg"
    pause 1
    play sound "sounds/slick_01.ogg"
    show lun_blowjob_personal_pose5 eyes_halflid_stare_hearts as cg with d3
    play sound "sounds/gulp.ogg"
    pause 1
    play sound "sounds/slick_01.ogg"
    show lun_blowjob_personal_pose5 eyebrows_base eyes_halflid_up_hearts as cg with d3
    play sound "sounds/gulp.ogg"
    pause 1

    show lun_blowjob_personal_pose4 as cg with d3
    show lun_blowjob_personal_pose3 as cg with d3

    show lun_blowjob_personal_pose2 mouth_kiss as cg with d3
    lun "*Slrp-pop*!{w=0.4}{nw}"
    show lun_blowjob_personal_pose2 eyes_halflid_up_hearts as cg
    lun "*Slrp-pop*!{fast}"
    show lun_blowjob_personal_pose1 no_trousers eyes_halflid_stare_hearts mouth_open_cum as cg with d3
    lun "Aaaah...{w=0.4}{nw}"

    play sound "sounds/gulp.ogg"
    show lun_blowjob_personal_pose1 eyes_closed mouth_neutral as cg
    lun "Aaaah...{fast} *Gulp*...{w=0.4}{nw}"

    show lun_blowjob_personal_pose1 eyes_wide_stare_hearts mouth_base as cg
    lun "Aaaah... *Gulp*...{fast} All gone..."

    show lun_blowjob_personal_pose1 eyes_halflid_stare_hearts mouth_grin as cg with d3
    lun "Thank you so much, [name_genie_luna]..."

    show lun_blowjob_personal_pose1 -genie_arm_idle as cg with d3
    gen "*Huh*? For what?"

    show lun_blowjob_personal_pose1 mouth_base as cg with d3
    lun "You were the only person who took me seriously about the wrackspurts problem..."

    show lun_blowjob_personal_pose1 mouth_soft as cg with d3
    lun "And you've been so nice, and patient, and have taught me so many things..."

    show lun_blowjob_personal_pose1 eyes_halflid_down_hearts as cg with d3
    lun "And this cum..."

    show lun_blowjob_personal_pose1 mouth_grin as cg with d3
    lun "It's so good! It's as if it's made of pure magic!"

    show lun_blowjob_personal_pose1 handjob_moderate as cg with d3
    lun "I can't get enough of it!"

    show lun_blowjob_personal_pose1 eyebrows_worried eyes_closed as cg with d3
    lun "Thank you, thank you, thank you!"

    show lun_blowjob_personal_pose1 handjob_fast eyebrows_base eyes_base_stare_hearts as cg with d3
    lun "You're the best genie ever!" #heart eyes

    #Luna kiss dick
    show lun_blowjob_personal_pose2 eyebrows_angry eyes_closed mouth_kiss as cg with d3
    lun "*Kissing noises*"
    nar "With that, Luna starts kissing and licking the tip of your cock, shamelessly slobbering over every inch of it..."

    gen "*Ngh*... I'm glad you're enjoying yourself."
    gen "And indeed, I {i}am{/i} the best genie ever..."

    play sound "sounds/scratch.ogg"

    gen "Wait...{w=0.5} Did you just say {b}GENIE{/b}?!"

    show lun_blowjob_personal_pose2 eyes_halflid_up_hearts mouth_kiss as cg with d2
    lun "*Slrp*?"

    show lun_blowjob_personal_pose1 eyebrows_raised eyes_halflid_stare mouth_base as cg with d3
    lun "I mean you are a genie, aren't you?"
    gen "Well, yes..."
    gen "But how did you know? Don't tell me the cloaking thingy had an expiration date..."

    show lun_blowjob_personal_pose1 eyebrows_shocked eyes_base_stare mouth_grin as cg with d3
    lun "Oh, don't worry [name_genie_luna]... I can only see your true form when I'm wearing my spectrespecs!"
    gen "Those glasses? So, you're saying you've known this whole time?"

    show lun_blowjob_personal_pose1 eyebrows_angry eyes_halflid_down mouth_base as cg with d3
    lun "Well, I wasn't a hundred percent sure you were a genie until I tasted this..."

    show lun_blowjob_personal_pose1 eyebrows_base as cg with d3
    lun "I doubt any other creature could produce something this tasty..."

    show lun_blowjob_personal_pose1 mouth_grin as cg with d3
    lun "Not even a unicorn..."
    gen "So...{w=0.4} You don't mind that I'm a genie?"

    show lun_blowjob_personal_pose1 eyes_halflid_stare mouth_soft as cg with d3
    lun "Nope! Not unless it bothers you..."
    gen "As long as you keep sucking like that, you can think I'm the Prince of Persia..."
    gen "Just don't expect any wishes."

    show lun_blowjob_personal_pose1 mouth_annoyed as cg with d3
    lun "Oh...{w=0.4} Why not?"
    gen "Well... First off, you have to rub--"

    show lun_blowjob_personal_pose1 eyebrows_shocked eyes_wide_stare mouth_grin as cg with d3
    lun "I can do that!"

    show lun_blowjob_personal_pose1 handjob_moderate eyebrows_angry eyes_halflid_down as cg with d3

    gen "That's not--{w=0.2} Well, I suppose if it's cum that you want..."
    nar "You quickly realise that Luna isn't paying you much attention, as her gaze has once again locked onto your cock."
    gen "Steady on, girl...{w=0.4} Don't you think you've had enough for one day?"

    show lun_blowjob_personal_pose1 mouth_open_spit as cg with d3
    lun "{size=-4}Come on out already...{/size}"
    gen "[name_luna_genie]!"

    show lun_blowjob_personal_pose1 -handjob_moderate eyes_halflid_stare mouth_soft as cg with d3
    lun "*Huh*?"
    gen "That shall do for today."

    show lun_blowjob_personal_pose1 eyebrows_worried mouth_annoyed as cg with d3
    lun "*Aww*...{w=0.4} Already?{w=0.4} Surely there must be some wrackspurts left in you..."
    gen "Perhaps it's time we moved onto another method..."

    show lun_blowjob_personal_pose1 eyebrows_shocked eyes_wide_stare mouth_neutral as cg with d3
    lun "You've come up with another method already?"
    gen "I believe so..."
    gen "Am I making the right assumption that the spurs haven't stopped bothering you whilst you've been helping me, [name_luna_genie]?"

    show lun_blowjob_personal_pose1 eyes_halflid_right cheeks_blush mouth_soft as cg with d3
    lun "Oh...{w=0.4} I mean...{w=0.4} I suppose not...{w} But I'll manage, as long as it helps with your research!"
    gen "*Hmm*...{w=0.4} I appreciate the sentiment, but that isn't good enough, I'm afraid..."

    show lun_blowjob_personal_pose1 -cheeks_blush eyes_halflid_stare mouth_soft as cg with d3
    lun "[name_genie_luna]?"
    gen "A world where the comfort of one is only achievable thanks to the suffering of another is not an acceptable solution."

    show lun_blowjob_personal_pose1 eyes_halflid_down as cg with d3
    lun "I see..."
    gen "The only real solution is one where the participants are able to physically stimulate each other at the same time."

    show lun_blowjob_personal_pose1 eyes_wide_stare mouth_open as cg with d3
    lun "At the same time!?"
    gen "That's right, [name_luna_genie]...{w=0.4} If we can achieve physical stimulation and release between both participants simultaneously, then--"

    show lun_blowjob_personal_pose1 handjob_moderate eyebrows_worried eyes_halflid_stare mouth_soft as cg with d3
    lun "Can we try it now? Pleaaaase!"
    gen "*Ugh*...{w=0.4} I appreciate the enthusiasm [name_luna_genie], but I think I need a bit of a nap first..."

    show lun_blowjob_personal_pose1 -handjob_moderate eyes_base_stare mouth_grin as cg with d3
    lun "Oh... Okay then, Mister Genie!"
    gen "Just \"Genie\" is fine."
    gen "Although, try to avoid calling me that in front of anyone else...{w=0.4} It will be our little secret."

    show lun_blowjob_personal_pose1 eyebrows_base eyes_halflid_stare as cg with d3
    lun "Okie dokie, [name_genie_luna], Enjoy your nap!"

    show screen blkfade
    with d5

    if _wearing_clothes:
        hide luna_main
        $ luna.wear("all")

    hide cg
    hide screen blkfade
    with d5

    #Luna leaves
    call lun_walk(action="leave")

    $ _wearing_clothes = False
    $ states.lun.ev.gen_genie_nickname_unlocked = True

    call ll_pf_blowjob_end

label ll_pf_blowjob_T4_E4_repeat:

    #Genie asks for another blowjob before they move on to the next step

    call ll_pf_blowjob

    gen "Before we proceed to test out my new theory, what do you say about that spacious head of yours taking a trip downstairs?" ("base", xpos="far_left", ypos="head")
    lun "Downstairs?" ("soft", "base", "raised", "mid", xpos="base", ypos="base", trans=d3)
    gen "Downstairs, and down my shaft!" ("grin", xpos="far_left", ypos="head")
    lun "Your shaft? Are you talking about your wizard tower?" ("upset", "base", "raised", "mid")
    gen "Tower, mast, shaft, whatever you want to call it." ("grin", xpos="far_left", ypos="head")
    lun "But, I just got here, are you sure you don't need me for anything?" ("angry", "base", "base", "mid")
    gen "What do you--{w=0.2} I'm asking you to suck my dick again, [name_luna_genie]!" ("base", xpos="far_left", ypos="head")
    lun "Oh! Of course, [name_genie_luna]! Why didn't you say so?" ("grin", "base", "base", "stare")
    gen "..." ("base", xpos="far_left", ypos="head")
    lun "Either way... There's no need to to ask!" ("base", "base", "base", "mid")
    lun "As I said before..." ("grin", "base", "base", "mid")
    lun "My mouth is here for you, whenever you need it!" ("smile", "base", "base", "mid")
    gen "Oh right... You did say that." ("base", xpos="far_left", ypos="head")
    gen "I've gotten so used to requiring more convincing than that, so I forgot who I was talking to." ("base", xpos="far_left", ypos="head")
    lun "I'm {i}the{/i} cumslut aren't I? I'm always pleased to be of assistance!" ("smile", "closed", "base", "mid") # Genie told Luna it just means "a person who enjoys helping people cum".
    gen "You certainly are {i}a{/i} cumslut... Now, assume the pleasing position!" ("base", xpos="far_left", ypos="head")
    lun "Yes, [name_genie_luna]!" ("smile", "base", "base", "L")

    #Luna quickly walks up towards the desk, fades to black
    call lun_walk("desk", "base", speed=1.75)
    show screen blkfade
    with d5

    if luna.is_any_worn("clothes"):
        $ _wearing_clothes = True
        $ luna.strip("clothes")

    show lun_blowjob_personal_pose1 eyes_closed mouth_soft as cg

    hide screen blkfade
    with d5

    lun "*Sniff* *Sniff*"
    gen "Enjoying yourself down there?"

    show lun_blowjob_personal_pose1 eyebrows_angry eyes_halflid_stare mouth_base as cg with d3
    lun "Oh, yes... Very much..."

    show lun_blowjob_personal_pose1 eyes_halflid_right as cg with d3
    lun "I think this might even have become my new safe space."
    gen "Really? What makes you say that?"

    show lun_blowjob_personal_pose1 eyes_halflid_stare mouth_open as cg with d3
    lun "Well, I used to have another safe space that I'd go to whenever I needed to think."

    show lun_blowjob_personal_pose1 eyes_base_stare mouth_base as cg with d3
    lun "It was this magical broom closet on the seventh floor... You know, the one opposite the tapestry of Barnabas the Barmy." #Room of requirement
    gen "A magical broom closet? What makes something a \"magical\" broom closet?"

    show lun_blowjob_personal_pose1 eyebrows_worried eyes_base_stare mouth_soft as cg with d3
    lun "Because... Last time I went there, the closet was gone!"

    show lun_blowjob_personal_pose1 eyebrows_angry mouth_open as cg with d3
    lun "And in its place, was nothing but a brick wall!"

    show lun_blowjob_personal_pose1 mouth_soft as cg with d3
    lun "Have you ever experienced such an anomaly before, [name_genie_luna]?"

    gen "Only when I've hinted towards trying the other hole."

    show lun_blowjob_personal_pose1 eyes_halflid_stare as cg with d3
    lun "A magical hole? "
    gen "Some would say it is..."

    show lun_blowjob_personal_pose1 mouth_base as cg with d3
    lun "Fascinating..."

    show lun_blowjob_personal_pose1 eyebrows_raised as cg with d3
    lun "Any idea how this magical hole functions?"
    gen "I try not to think about it."

    show lun_blowjob_personal_pose1 eyebrows_angry eyes_closed mouth_open as cg with d3
    lun "My thought about the magic closet not materializing is that it will only appear when there's a desire for it to exist."

    show lun_blowjob_personal_pose1 eyes_halflid_stare mouth_soft as cg with d3
    gen "..."

    show lun_blowjob_personal_pose1 eyebrows_raised as cg with d3
    lun "*Ehm*... Or am I hooting up the wrong bush with that assumption, [name_genie_luna]?"
    gen "I think it'd be best if you focused less on {i}bushes{/i} and {i}closets{/i} and more towards the task at hand."

    show lun_blowjob_personal_pose1 mouth_open as cg with d3
    lun "Task at hand, [name_genie_luna]?"

    nar "You briefly move your gaze down towards your throbbing member."

    show lun_blowjob_personal_pose1 eyebrows_base eyes_halflid_down as cg with d3
    lun "Oh! Of course, [name_genie_luna]!"
    lun "I'll get to it right away!"

    #Luna pulls genie's trousers down
    show lun_blowjob_personal_pose1 no_trousers eyebrows_angry mouth_base as cg with d3
    pause 0.5
    lun "*Mmm*..."

    show lun_blowjob_personal_pose1 eyes_halflid_down mouth_open as cg with d3
    lun "You know.... I was worried that I would never get suck this delectable thing again."
    gen "Delectable?"

    #Luna kisses cock
    show lun_blowjob_personal_pose1 mouth_open_spit as cg with d3
    show lun_blowjob_personal_pose2 eyes_closed mouth_kiss as cg with d3
    lun "*Kissing noises*"

    gen "You sure have caught a liking to doing this..."

    show lun_blowjob_personal_pose2 mouth_lick as cg with d3
    lun "*Lick*"
    gen "*Ngh*!"

    show lun_blowjob_personal_pose2 eyes_halflid_stare as cg with d3
    lun "*Hmmff*?"

    show lun_blowjob_personal_pose2 eyebrows_worried as cg with d3
    lun "*U Oay*?"

    gen "I'm fine! You go right ahead."

    show lun_blowjob_personal_pose2 eyebrows_angry as cg with d3
    lun "*Esh pffeshor*!"

    show lun_blowjob_personal_pose2 eyes_halflid_down as cg with d3

    #Luna pushes her head down genie's shaft
    show lun_blowjob_personal_pose2 mouth_kiss as cg with d2
    show lun_blowjob_personal_pose3 eyes_halflid_stare as cg with d3
    show lun_blowjob_personal_pose4 as cg with d3
    show lun_blowjob_personal_pose5 eyebrows_angry eyes_halflid_up as cg with d3

    lun "*Mmmmmm*...."
    gen "*Ngh*!"
    gen "Whoa! Do that again!"

    show lun_blowjob_personal_pose5 eyes_base_stare as cg with d3
    lun "*Mff*?"
    gen "Whatever you just did, do it again!"

    show lun_blowjob_personal_pose5 eyebrows_base eyes_halflid_stare as cg with d3
    lun "*Mmmmmm*?"
    gen "*Ah*, yes! That felt good!"
    gen "Now, up and down the wizard tower you go!"

    show lun_blowjob_personal_pose5 eyes_halflid_down as cg with d3
    nar "Luna, looking slightly more puzzled than her usual self, shrugs and then starts moving her head up and down your cock."

    play background "sounds/slickloop.ogg" fadein 2
    show lun_blowjob_personal_loop as cg with d3
    gen "*Ah*...{w=0.4} Yes...{w=0.4} Now that's how you do it!"

    nar "Revelling in your praise, you watch as Luna happily bobs her head up and down your cock, only slowing down intermittently to run her tongue underneath your shaft."

    gen "*Ah*...{w=0.4} I think you might've touched the ground floor that time."
    gen "You sure are a cumslut..."

    nar "As the last word escapes your lips, you could swear that Luna's throat tensed up briefly, but before the thought could take hold, her onslaught on your cock continues."

    gen "(She's--{w=0.2} too good! If she keeps going like this, my reputation will be in shambles!)"
    gen "*Ngh*... Slow down a bit, won't you?"

    play background "sounds/slickloopfast.ogg" fadein 2
    show lun_blowjob_personal_loop_ahegao as cg with d3
    nar "Luna, hearing your pleas, looks at you worryingly for a moment, then increases her pace."
    gen "What are you--"
    gen "Slow down, girl!"
    lun "*Mmmmmm*..."
    gen "*Ngh*--"

    #Cum section
    menu:
        "-Say something weird to make her pull out-":
            menu:
                "\"Look! There's an elephant in the room!\"":
                    #Luna Pulls out
                    stop background
                    show lun_blowjob_personal_pose2 mouth_kiss as cg with d1
                    show lun_blowjob_personal_pose1 no_trousers penis_spit cum_precum eyebrows_shocked eyes_wide_left mouth_open_spit as cg with d3
                    lun "*Slrp-pop*! Where?!"

                    gen "*AAAAH*!"

                    play sound "sounds/slick_01.ogg"
                    show lun_blowjob_personal_pose1 cum_frame0 eyes_wide_down as cg with d2
                    show lun_blowjob_personal_pose1 cum_frame1 eyes_wide_stare as cg with d2
                    play sound "sounds/slick_01.ogg"
                    show lun_blowjob_personal_pose1 cum_frame2 as cg with d2
                    show lun_blowjob_personal_pose1 cum_frame3 as cg with d2
                    show lun_blowjob_personal_pose1 cum_frame4 as cg with d2

                    show lun_blowjob_personal_pose1 eyebrows_angry eyes_wide_down mouth_open_spit as cg with d2
                    lun "[name_genie_luna]!"

                    gen "*Ah*... That was--"

                    show lun_blowjob_personal_pose1 eyes_halflid_stare as cg with d3
                    lun "Quickly, [name_genie_luna]! Move your leg!"
                    gen "*Huh*?"

                    show screen blkfade
                    with d5

                    nar "Luna pushes your leg to the side, and then darts to the front of your desk."
                    $ luna.set_cum(face="heavy")

                    hide cg
                    hide screen blkfade
                    with d5

                    call lun_chibi(flip=True)
                    lun "I can't believe there's a--{w=0.2}{nw}"
                    call lun_chibi(flip=False)
                    lun "I can't believe there's a--{fast} Wait...{w=0.4} Where did the elephant go?" ("angry", "base", "base", "L", xpos="mid", ypos="base", trans=d3)
                    gen "Err..." ("base", xpos="far_left", ypos="head")
                    lun "There's no elephant in the room, is there?" ("annoyed", "narrow", "base", "mid")
                    gen "Other than your unfathomable naivety?" ("base", xpos="far_left", ypos="head")
                    lun "...?" ("annoyed", "base", "base", "mid")
                    gen "No, there's no actual elephant..." ("base", xpos="far_left", ypos="head")
                    lun "I see..." ("annoyed", "narrow", "base", "down") #dissapointed
                    gen "I mean, there was one! It just leapt out the window!" ("grin", xpos="far_left", ypos="head")
                    lun "Really?" ("angry", "wide", "base", "mid")
                    gen "Of course!" ("grin", xpos="far_left", ypos="head")
                    lun "How extraordinary!" ("grin", "base", "base", "mid")
                    gen "(If it was only this easy to make Hermione excited.)" ("base", xpos="far_left", ypos="head")
                    lun "Hold on... How would an elephant even fit--" ("upset", "base", "base", "L")
                    gen "Weren't you meant to swallow the spurs by the way?" ("base", xpos="far_left", ypos="head")
                    lun "Wha--{w=0.2} Oh no!" ("angry", "wide", "base", "stare")
                    gen "(*Phew*... Bullet dodged.)" ("base", xpos="far_left", ypos="head")

                    lun "" ("open_tongue", "base", "annoyed", "down") #Tongue out
                    nar "You watch as Luna desperately tries to extend her tongue towards your cum."

                    gen "What are you doing?" ("base", xpos="far_left", ypos="head")
                    lun "*Ngh*!" ("open_tongue", "narrow", "annoyed", "down")
                    gen "..." ("base", xpos="far_left", ypos="head")
                    gen "[name_luna_genie]... I believe it's a bit late for that..." ("base", xpos="far_left", ypos="head")
                    lun "... Really?" ("angry", "narrow", "base", "mid") #Sad
                    gen "Really..." ("base", xpos="far_left", ypos="head")
                    lun "Oh..." ("open", "narrow", "worried", "down") #Sad
                    lun "This means that the wrackspurts will return even faster, doesn't it?" ("angry", "narrow", "base", "down")
                    gen "Most certainly..." ("base", xpos="far_left", ypos="head")
                    lun "I see..." ("soft", "narrow", "worried", "down")
                    gen "What's with the long face?" ("base", xpos="far_left", ypos="head")

                "\"Cum covered bimbo says what?\"":
                    #Luna Pulls out
                    stop background
                    show lun_blowjob_personal_pose2 mouth_kiss as cg with d1
                    show lun_blowjob_personal_pose1 no_trousers penis_spit cum_precum eyebrows_angry eyes_halflid_stare mouth_open_spit as cg with d3
                    lun "*Slrp-pop*! What?!"

                    gen "*AAAAH*!"

                    #Genie cums
                    play sound "sounds/slick_01.ogg"
                    show lun_blowjob_personal_pose1 cum_frame0 eyes_wide_down as cg with d2
                    show lun_blowjob_personal_pose1 cum_frame1 eyes_wide_stare as cg with d2
                    play sound "sounds/slick_01.ogg"
                    show lun_blowjob_personal_pose1 cum_frame2 as cg with d2
                    show lun_blowjob_personal_pose1 cum_frame3 as cg with d2
                    show lun_blowjob_personal_pose1 cum_frame4 as cg with d2

                    show lun_blowjob_personal_pose1 eyebrows_angry eyes_wide_down as cg with d2
                    lun "[name_genie_luna]!"

                    show lun_blowjob_personal_pose1 eyes_halflid_stare as cg with d3
                    lun "You tricked me!"

                    show lun_blowjob_personal_pose1 eyes_base_stare mouth_soft as cg with d3
                    lun "Or... Did the wrackspurts make you say that?"
                    gen "What--{w=0.2} Oh yes! Those rascals got to me again!"

                    show lun_blowjob_personal_pose1 eyes_base_right as cg with d3
                    lun "*Hmph*"
                    gen "What's up?"

                    show lun_blowjob_personal_pose1 eyes_halflid_down as cg with d3
                    lun "It's just... *Hmph*... Nevermind..."

                    show screen blkfade
                    with d5

                    nar "Luna gets out from underneath your desk, and trudges over to stand in front of it."
                    $ luna.set_cum(face="heavy")

                    hide cg
                    hide screen blkfade
                    with d5

                    gen "Are you alright, [name_luna_genie]?" ("base", xpos="far_left", ypos="head")
                    lun "I failed to swallow the wrackspurts... So, now they'll surely end up returning even sooner." ("angry", "narrow", "base", "down", xpos="mid", ypos="base", trans=d3)
                "\"I'm cured! You can stop now!\"":
                    #Luna Pulls out
                    stop background
                    show lun_blowjob_personal_pose2 mouth_kiss as cg with d1
                    show lun_blowjob_personal_pose1 no_trousers penis_spit cum_precum eyebrows_worried eyes_wide_up mouth_open_spit as cg with d3
                    lun "*Slrp-pop*! What?!"
                    gen "Nevermind!"

                    gen "*AAAAH*!"

                    #Genie cums
                    play sound "sounds/slick_01.ogg"
                    show lun_blowjob_personal_pose1 cum_frame0 eyes_wide_down as cg with d2
                    show lun_blowjob_personal_pose1 cum_frame1 eyes_wide_stare as cg with d2
                    play sound "sounds/slick_01.ogg"
                    show lun_blowjob_personal_pose1 cum_frame2 as cg with d2
                    show lun_blowjob_personal_pose1 cum_frame3 as cg with d2
                    show lun_blowjob_personal_pose1 cum_frame4 as cg with d2

                    show lun_blowjob_personal_pose1 eyebrows_angry eyes_wide_down as cg with d2
                    lun "[name_genie_luna]!"

                    show lun_blowjob_personal_pose1 eyebrows_angry eyes_wide_stare as cg with d3
                    lun "You came on me again!"
                    gen "Sure did."

                    show lun_blowjob_personal_pose1 eyes_halflid_down mouth_soft as cg with d3
                    lun "But, I was meant to swallow it--{w=0.2} I mean, the wrackspurts!"
                    gen "Yes... An unfortunate outcome indeed..."

                    show lun_blowjob_personal_pose1 eyes_halflid_stare as cg with d2
                    lun "Then why would you say something like that, just as you were about to--"

                    show lun_blowjob_personal_pose1 eyebrows_shocked eyes_wide_up mouth_open as cg with d3
                    lun "Hold on a moment..."

                    show screen blkfade
                    with d5

                    nar "Luna quickly gets out from underneath your desk, and rushes over to the front of it."
                    $ luna.set_cum(face="heavy")

                    hide cg
                    hide screen blkfade
                    with d5

                    call lun_chibi(flip=False)

                    lun "[name_genie_luna]... Please don't tell me that your desk is made out of whisperwood!" ("angry", "wide", "base", "L", xpos="mid", ypos="base", trans=d3)
                    gen "Out of what?" ("base", xpos="far_left", ypos="head")
                    lun "Whisperwood!" ("angry", "wide", "base", "mid")
                    lun "Spending an excessive amount of time near a whisperwood tree may lead you to involuntarily utter the most inappropriate remarks at the most inopportune times imaginable!" ("mad", "narrow", "base", "mid")
                    gen "Sounds like you're describing the characteristics of a genie..." ("base", xpos="far_left", ypos="head")
                    lun "Really?" ("soft", "base", "base", "mid")
                    gen "Yes... Although, that wasn't why I said it." ("base", xpos="far_left", ypos="head")
                    lun "Then why did you..." ("soft", "base", "base", "mid")
                    gen "Just as the buggers were on the verge of bursting forth, they abruptly darted in the opposite direction!" ("base", xpos="far_left", ypos="head")
                    lun "So...{w=0.4} You're not cured?" ("angry", "base", "raised", "mid")
                    gen "On the contrary... They're getting smarter." ("base", xpos="far_left", ypos="head")
                    lun "..." ("upset", "narrow", "base", "down") #Sad
                    gen "Are you alright [name_luna_genie]? I didn't hit you in the eye, did I?" ("base", xpos="far_left", ypos="head")
                    lun "I'm fine, [name_genie_luna]...{w=0.4} I just thought I might've had them that time." ("angry", "narrow", "base", "down")
                    gen "I'm sure you'll get them next time." ("base", xpos="far_left", ypos="head")
                    gen "In any case..." ("base", xpos="far_left", ypos="head")

            gen "Didn't you say that you find pleasure in assisting me?" ("base", xpos="far_left", ypos="head")
            lun "Oh, right! I do! I'm {i}the{/i} cumslut!" ("angry", "base", "base", "stare") #Happy
            lun "See you next time, then!" ("grin", "base", "base", "mid")
            gen "*Heh-Heh*... See you next--" ("base", xpos="far_left", ypos="head")
            gen "Hold on!" ("base", xpos="far_left", ypos="head")
            lun "Yes?" ("soft", "base", "raised", "mid")
            gen "Make sure you clean yourself before you leave..." ("base", xpos="far_left", ypos="head")
            lun "Oh, but I'm fine [name_genie_luna], I assure you!" ("grin", "base", "base", "mid")
            gen "I'm sure you are...{w=0.4} I would just prefer it if that pretty face of yours weren't covered up." ("base", xpos="far_left", ypos="head")
            lun @ cheeks blush "Oh..." ("angry", "narrow", "base", "down") #blushing

            hide luna_main
            with d3
            $ luna.set_cum(None)

            nar "Luna quickly begins scooping your cum off her face, then flicking it onto the floor."

            lun @ cheeks blush "There we go!" ("soft", "narrow", "base", "down")
            lun @ cheeks blush "Did-- Did I manage to get them all?" ("open", "narrow", "base", "downR")
            gen "*Hmm*... Yes, I believe you did...{w=0.4} Nice work!" ("base", xpos="far_left", ypos="head")

            $ luna.set_cum(pussy="wet")
            lun @ cheeks blush "*Mmm*... Thank you, [name_genie_luna]!" ("base", "closed", "base", "down")

            if _wearing_clothes:
                hide luna_main
                with d3
                $ luna.wear("all")
                with d3
                pause .5

            if game.daytime:
                lun @ cheeks blush "*Ah*...{w=0.4} *Ehm*...{w=0.4} Have a nice day!" ("angry", "narrow", "base", "R")
                gen "Have a--" ("base", xpos="far_left", ypos="head")
            else:
                lun "*Ah*...{w=0.4} *Ehm*...{w=0.4} Good night then!" ("angry", "narrow", "base", "R")
                gen "Good--" ("base", xpos="far_left", ypos="head")

            #Luna leaves
            call lun_walk(action="leave", speed=1.75)
            gen "..." ("base", xpos="far_left", ypos="head")

            $ luna.set_cum(None)

        "-Tell her to get ready, and cum down her throat-":
            gen "Take it, you--{w=0.2} cum hungry--{w=0.2} Slut!"

            nar "Luna, readying herself for your load, pushes her head down to the hilt, and you feel her throat contract around your cock."

            gen "*AARGH*!! You whore!!!"

            #Bobbing stops, and Genie cums down her throat
            stop background

            play sound "sounds/slick_01.ogg"
            show lun_blowjob_personal_pose5 penis_spit eyes_halflid_down_hearts as cg with d3
            play sound "sounds/gulp.ogg"
            pause 1
            play sound "sounds/slick_01.ogg"
            show lun_blowjob_personal_pose5 eyes_halflid_stare_hearts as cg with d3
            play sound "sounds/gulp.ogg"
            pause 1
            play sound "sounds/slick_01.ogg"
            show lun_blowjob_personal_pose5 eyebrows_base eyes_halflid_up_hearts as cg with d3
            play sound "sounds/gulp.ogg"
            pause 1

            show lun_blowjob_personal_pose4 as cg with d3
            show lun_blowjob_personal_pose3 as cg with d3

            show lun_blowjob_personal_pose2 mouth_kiss as cg with d3
            lun "*Slrp-pop*!{w=0.4}{nw}"
            show lun_blowjob_personal_pose2 eyes_closed as cg
            lun "*Slrp-pop*!{fast}"
            show lun_blowjob_personal_pose1 no_trousers eyebrows_angry mouth_open_cum as cg with d3
            lun "*Ah*...{w=0.4} Ah*...{w=0.4} Ah*..."
            play sound "sounds/gulp.ogg"
            show lun_blowjob_personal_pose1 mouth_neutral as cg with d3

            show screen blkfade
            with d5

            nar "As Luna crawls out from under your desk, you slump back into your chair, exhausted by the cheer intensity of the session."

            hide cg
            hide screen blkfade
            with d5

            #Fade to office, Luna in front of desk
            call lun_chibi(flip=False)

            lun @ cheeks blush "So... Did I do good?" ("soft", "narrow", "base", "downR", xpos="mid", ypos="base", trans=d3)
            gen "..." ("base", xpos="far_left", ypos="head")
            lun "[name_genie_luna]?" ("open", "base", "base", "mid")

            $ renpy.sound.play("sounds/snore1.ogg")
            gen "*Snore*..." ("base", xpos="far_left", ypos="head")

            lun "You called me a whore, what did you--" ("open", "base", "base", "mid")

            $ renpy.sound.play("sounds/snore1.ogg")
            gen "*Snore*!" ("angry", xpos="far_left", ypos="head")

            lun "I'll...{w=0.4} I'll let you sleep...{w=0.4} Sweet dreams, [name_genie_luna]." ("base", "base", "base", "mid")

            if _wearing_clothes:
                hide luna_main
                with d3
                $ luna.wear("all")
                with d3
                pause .5

            #Luna leaves
            call lun_walk(action="leave")

            gen "..." ("base", xpos="far_left", ypos="head")
            gen "(When all else fails, pretend to sleep.)" ("grin", xpos="far_left", ypos="head")

    $ _wearing_clothes = False

    jump ll_pf_blowjob_end

#Tier 5 BJ notes:
#Genie jokes and says that perhaps he should call her the "head master now." Luna doesn't get it.
