WTS/game/scripts/characters/susan/summon.rpy

label summon_susan:

    $ active_girl = "susan"
    $ last_character = "susan"

    $ susan_busy = True

    call update_susan

    $ renpy.checkpoint(hard=True)

    call play_music("susan")
    call play_sound("door")

    call sus_chibi("stand","mid","base")
    with d3

    sus "You wanted to see me, [sus_genie_name]?" ("base", "base", "base", "mid", xpos="base", ypos="base")

    label susan_requests:

    sus "" (xpos="base", ypos="base")

    menu:

        # Talk
        "-Talk-" (icon="interface/icons/small/talk.webp"):
            if sus_mood > 0:
                sus "I'm sorry, [sus_genie_name], but I don't want to talk right now." ("soft", "happy", "base", "downR")
                jump susan_requests

            call susan_chitchat
            jump susan_talk

        "-Sexual favours-" (icon="interface/icons/small/condom.webp", style="disabled") if False:
            $ TBA_message()
            jump susan_requests

        # Wardrobe
        "-Wardrobe-" (icon="interface/icons/small/wardrobe.webp") if susan_wardrobe_unlocked:
            hide susan_main with d1
            call wardrobe
            jump susan_requests

        "-Hidden-" (style="disabled") if not susan_wardrobe_unlocked:
            call nar(">You haven't unlocked this feature yet.")
            jump susan_requests

        "-Give Item-" (icon="interface/icons/small/gift.webp"):
            $ TBA_message()
            jump susan_requests

            # hide susan_main with d1
            # call gift_menu
            # jump susan_requests


        # Dismiss
        "-Dismiss her-":
            if game.daytime:
                sus "I will go back to classes then, [sus_genie_name]." ("base", "base", "shocked", "mid")
            else:
                sus "*Ehm*... good night then, [sus_genie_name]." ("base", "base", "base", "mid")

            call play_sound("door")

            jump end_susan_event



label susan_talk:
    menu:
        #"--":
        "-Address me only as-":
            menu:
                "-Sir-":
                    $ sus_genie_name = "Sir"
                    sus "Very well, [sus_genie_name]." ("base", "base", "base", "mid")
                    jump susan_talk
                "-Dumbledore-":
                    $ sus_genie_name = "Dumbledore"
                    sus "Okay, [sus_genie_name]." ("soft", "base", "base", "mid")
                    jump susan_talk
                "-Professor-":
                    $ sus_genie_name = "Professor"
                    sus "Of course, [sus_genie_name]." ("base", "base", "base", "mid")
                    jump susan_talk
                "-Old man-":
                    $ sus_genie_name = "Old man"
                    sus "That wouldn't be very polite, Professor." ("soft", "happy", "low", "mid")
                    gen "Don't worry, [susan_name]. I always tell my students to call me silly names." ("base", xpos="far_left", ypos="head")
                    gen "It helps bonding with them!" ("grin", xpos="far_left", ypos="head")
                    sus "If you say so... *Ehm*, [sus_genie_name]." ("normal", "happy", "low", "downL")
                    gen "(And soon I'm going to bond with your tits!)" ("angry", xpos="far_left", ypos="head")
                    jump susan_talk
                "-Genie-":
                    $ sus_genie_name = "Genie"
                    sus "I... *Ehm*--" ("soft", "happy", "base", "mid")
                    sus "Is that something people call you?" ("open", "base", "raised", "mid")
                    gen "Yes-yes--, everybody!" ("base", xpos="far_left", ypos="head")
                    gen "It's perfectly normal!" ("base", xpos="far_left", ypos="head")
                    sus "(...)" ("soft", "base", "base", "mid")
                    sus "O--{w=0.2} Okay then... [sus_genie_name]." ("grin", "happy", "base", "mid")
                    jump susan_talk
                "-Lord Voldemort-":
                    $ sus_genie_name = "Lord Voldemort"
                    sus "Why would you want me to call you that?" ("angry", "happy", "low", "mid")
                    sus "We aren't supposed to mention his name!" ("angry", "happy", "worried", "mid")
                    gen "It's only a name, girl..." ("base", xpos="far_left", ypos="head")
                    sus "It's the name of, you-know-who!" ("disgust", "happy", "worried", "right")
                    sus "That name really creeps me out, Professor!" ("angry", "base", "worried", "mid")
                    gen "I don't want my students to be scared of a name, Susan! It's practice." ("base", xpos="far_left", ypos="head")
                    gen "Come on... say it." ("base", xpos="far_left", ypos="head")
                    sus "...{w=0.4} Okay." ("soft", "narrow", "sad", "down")
                    sus "V--{w=0.2} Voldemort..." ("angry", "happyCl", "sad", "mid")
                    jump susan_talk
                "-Daddy-":
                    $ sus_genie_name = "Daddy"
                    sus "Sir, no!" ("angry", "base", "base", "mid", cheeks="blush")
                    sus "I can't possibly call you that!" ("open", "happy", "sad", "mid", cheeks="blush")
                    gen "But I want you to." ("base", xpos="far_left", ypos="head")
                    gen "There's no harm in calling me Daddy." ("grin", xpos="far_left", ypos="head")
                    sus "But that's!--" ("angry", "narrow", "sad", "mid", cheeks="blush")
                    sus "(This is wrong, Susan!)" ("angry", "closed", "sad", "mid", cheeks="blush")
                    gen "Miss Bones?" ("base", xpos="far_left", ypos="head")
                    sus "O--{w=0.2} Okay then... Professor-- *Ehm*... D-Daddy." ("annoyed", "happy", "worried", "stare", cheeks="blush")
                    jump susan_talk
                "-Master-":
                    $ sus_genie_name = "Master"
                    sus "M--{w=0.2} Master?" ("soft", "base", "base", "stare")
                    sus "I don't think I should call my teachers that." ("soft", "narrow", "base", "downR")
                    gen "No-no--, that's what you should call your teachers nowadays!" ("base", xpos="far_left", ypos="head")
                    gen "But only call me that!" ("base", xpos="far_left", ypos="head")
                    sus "*Ehm*... Very well, [sus_genie_name]." ("soft", "happy", "base", "down")
                    jump susan_talk
                "-Custom Input-":
                    $ temp_name = renpy.input("(Please enter the name.)", sus_genie_name, ALLOWED_CHARACTERS, length=14)
                    $ temp_name = temp_name.strip()
                    if temp_name == "":
                        jump susan_talk
                    else:
                        $ sus_genie_name = temp_name
                        sus "*Ehm*... Okay. I will call you [sus_genie_name]." ("base", "base", "base", "mid")
                    jump susan_talk
                "-Never mind-":
                    jump susan_requests


        "-From now on I will refer to you as-":
            menu:
                "-Miss Bones-":
                    $ susan_name = "Miss Bones"
                    sus "Of course, [sus_genie_name]." ("base", "base", "base", "mid")
                    jump susan_talk
                "-Susan-":
                    $ susan_name = "Susan"
                    sus "Of course, [sus_genie_name]." ("base", "base", "base", "mid")
                    jump susan_talk
                "-Girl-":
                    $ susan_name = "Girl"
                    sus "I'm okay with that, [sus_genie_name]." ("base", "base", "base", "mid")
                    jump susan_talk
                "-Cow-":
                    $ susan_name = "Cow"
                    sus "Why would you want to call me that, [sus_genie_name]?" ("angry", "happy", "low", "mid")
                    sus "The other girls already call me that and I hate it..." ("angry", "narrow", "low", "down")
                    gen "You poor thing!" ("base", xpos="far_left", ypos="head")
                    gen "You see, if someone like me would call you that, maybe it wouldn't affect you as much." ("base", xpos="far_left", ypos="head")
                    sus "I--... You might be right." ("open", "narrow", "base", "down")
                    sus "You can call me a Cow, [sus_genie_name]." ("soft", "narrow", "base", "downR", cheeks="blush")
                    jump susan_talk
                "-Betsy-":
                    $ susan_name = "Betsy"
                    sus "But, sir... Isn't that... You know..." ("open", "happy", "sad", "mid")
                    gen "You know... What?" ("base", xpos="far_left", ypos="head")
                    sus "Isn't that a name you'd give to a-- A cow?" ("open", "happy", "sad", "downR", cheeks="blush")
                    gen "Oh, is it?" ("base", xpos="far_left", ypos="head")
                    sus "*Ehm*... Yes, I think so at least..." ("open", "happy", "worried", "mid", cheeks="blush")
                    sus "Some of the other girls shouted it at me before..." ("annoyed", "happy", "worried", "down", cheeks="blush")
                    gen "That's a shame... I thought you'd like it..." ("base", xpos="far_left", ypos="head")
                    sus "Oh, Well... I suppose as long as it's not ill meaning..." ("open", "happy", "worried", "downR", cheeks="blush")
                    gen "Of course not!" ("base", xpos="far_left", ypos="head")
                    sus "Alright then, you can call me that if you like..." ("soft", "base", "base", "mid", cheeks="blush")
                    jump susan_talk
                "-Slut-":
                    $ susan_name = "Slut"
                    sus "[sus_genie_name]!" ("soft", "wide", "base", "mid", cheeks="blush")
                    sus "You can't be serious!" ("angry", "happy", "base", "mid", cheeks="blush")
                    gen "Why not. Nobody has to know..." ("base", xpos="far_left", ypos="head")
                    sus "How could you even think of me like that!" ("open", "happy", "sad", "downR", cheeks="blush")
                    sus "I'm not a... slut." ("soft", "narrow", "sad", "downR", cheeks="blush")
                    gen "Of course not. This is just to strengthen your self-esteem." ("base", xpos="far_left", ypos="head")
                    gen "Trust me, I know what I'm doing." ("base", xpos="far_left", ypos="head")
                    gen "Being called a slut always boosts a girls confidence!" ("base", xpos="far_left", ypos="head")
                    sus "R-- Really?" ("soft", "happy", "sad", "mid", cheeks="blush")
                    gen "Yes. Now... shall we try it?" ("base", xpos="far_left", ypos="head")
                    sus "... alright, [sus_genie_name]..." ("base", "happy", "sad", "mid", cheeks="blush")
                    jump susan_talk
                "-Custom Input-":
                    $ temp_name = renpy.input("(Please enter the name.)", susan_name, ALLOWED_CHARACTERS, length=14)
                    $ temp_name = temp_name.strip()
                    if temp_name == "":
                        jump susan_talk
                    else:
                        $ susan_name = temp_name
                        sus "I don't like it, but--" ("base", "base", "base", "mid")
                        sus "Promise you'll only call me that when we are alone." ("base", "base", "base", "mid")
                        gen "Promised!" ("grin", xpos="far_left", ypos="head")
                    jump susan_talk
                "-Never mind-":
                    jump susan_talk


        "-Never mind-":
            jump susan_requests