label phoenix:

    if game.day == 1:
        if not bird_examined:
            $ bird_examined = True
            $ phoenix_OBJ.idle = "phoenix_idle"
            call gen_chibi("stand","mid","base",flip=False)
            with d5
            gen "*Hmm*..." ("base", xpos="far_left", ypos="head")
            gen "Even this weird-looking bird radiates magic..." ("base", xpos="far_left", ypos="head")
            call gen_chibi("sit_behind_desk")
            with d5
        else:
            gen "It's just a bird. Nothing more to say." ("base", xpos="far_left", ypos="head")

        if bird_examined and desk_examined and cupboard_examined and door_examined and fireplace_examined:
            jump genie_intro_E2
        else:
            jump main_room_menu

    if not phoenix_is_fed:
        $ phoenix_is_fed = True
        $ phoenix_fed_counter += 1

        call gen_chibi("grab_high", phoenix_OBJ.xpos, phoenix_OBJ.ypos+365, flip=False) # Note: Flip is inconsistent
        with d3
        pause .5

        $ phoenix_OBJ.foreground = "phoenix_food"
        with d3

        $ random_number = renpy.random.randint(1, 3)
        if random_number == 1:
            gen "There you go..." ("base", xpos="far_left", ypos="head")
        elif random_number == 2:
            gen "Eat up, buddy." ("base", xpos="far_left", ypos="head")
        else:
            pause .8

        call gen_chibi("sit_behind_desk")
        jump main_room_menu

    if not phoenix_is_petted:
        $ phoenix_is_petted = True
        $ phoenix_petted_counter += 1
        call gen_chibi("petting", phoenix_OBJ.xpos, phoenix_OBJ.ypos+270, flip=False) # Note: Flip is inconsistent
        with d3
        pause .5

        $ random_number = renpy.random.randint(1, 5)
        if random_number == 1:
            gen "Who's a good bird?" ("base", xpos="far_left", ypos="head")
        elif random_number == 2:
            "*Pat *Pat *Pat..."
        elif random_number == 3:
            "Glad you aren't as noisy as Iago..."
        else:
            pause 2.4

        call gen_chibi("sit_behind_desk")
        jump main_room_menu

    gen "I have already fed and petted it today." ("base", xpos="far_left", ypos="head")
    gen "Wouldn't want to overdo it." ("base", xpos="far_left", ypos="head")

    jump main_room_menu