label hermione_talk:
    menu:
        ### Astoria ###
        "-Ask her to help Tonks-" (icon="interface/icons/small/tonks.webp") if states.ast.ev.intro.e1_complete and not states.ast.ev.intro.e3_complete:
            if states.ast.ev.intro.e2_ask_hermione:
                her "I'm still looking for that student, [name_genie_hermione]!" ("open", "closed", "base", "mid")
                her "Trust in me, I will find that Slytherin scum!" ("angry", "base", "angry", "mid")
                jump hermione_talk

            $ states.her.busy = True
            $ states.ast.ev.intro.e2_ask_hermione = True
            $ ag_event_pause = 2
            jump astoria_intro_E2_hermione


        ### Cho ###
        "-Solve the matter with Cho-" (icon="interface/icons/small/cho.webp", style="disabled") if states.cho.ev.intro.e2_complete and not states.sna.ev.hangouts.cho_e1:
            # Before talking to Snape.
            gen "(I should ask Snape what to do about that Cho girl first. Just to be safe.)" ("base", xpos="far_left", ypos="head")
            gen "(Might as well have a drink with him...)" ("base", xpos="far_left", ypos="head")
            jump hermione_talk

        "-Solve the matter with Cho-" (icon="interface/icons/small/cho.webp") if states.sna.ev.hangouts.cho_e1 and not states.cho.ev.intro.e4_complete:
            # After talking to Snape.
            jump cho_intro_E3

        "-Ask her to commentate the game-" (icon="interface/icons/small/quidditch.webp") if states.cho.tier == 1 and states.cho.ev.quidditch.e3_complete and not states.cho.ev.quidditch.e4_complete:
            jump cho_quid_E4

        "-Ask her to commentate the game-\n{size=-5}again...{/size}" (icon="interface/icons/small/quidditch.webp") if states.cho.tier == 2 and states.cho.ev.quidditch.e6_complete and not states.cho.ev.quidditch.e7_complete:
            jump cho_quid_E7

        # General.
        "-Address me only as-":
            menu:
                "-Sir-":
                    $ name_genie_hermione = _("Sir")
                    jump genie_change
                "-Dumbledore-":
                    $ name_genie_hermione = _("Dumbledore")
                    jump genie_change
                "-Professor-":
                    $ name_genie_hermione = _("Professor")
                    jump genie_change
                "-Old man-":
                    $ name_genie_hermione = _("Old man")
                    jump genie_change
                "-Genie-":
                    if states.her.level >=5:
                        $ name_genie_hermione = _("Genie")
                        jump genie_change
                    else:
                        jump genie_change_fail
                "-My Lord-":
                    if states.her.level >=7:
                        $ name_genie_hermione = _("My Lord")
                        jump genie_change
                    else:
                        jump genie_change_fail
                "-Darling-":
                    if states.her.level >=10:
                        $ name_genie_hermione = _("Darling")
                        jump genie_change
                    else:
                        jump genie_change_fail
                "-Lord Voldemort-":
                    if states.her.level >=15:
                        $ name_genie_hermione = _("Lord Voldemort")
                        jump genie_change
                    else:
                        jump genie_change_fail
                "-Daddy-":
                    if states.her.level >=19:
                        $ name_genie_hermione = _("Daddy")
                        $ achievements.unlock("daddy")
                        jump genie_change
                    else:
                        jump genie_change_fail
                "-Master-":
                    if states.her.level >=20:
                        $ name_genie_hermione = _("Master")
                        jump genie_change
                    else:
                        jump genie_change_fail
                "-Custom Input-":
                    $ temp_name = renpy.input(_("(Please enter the name.)"), name_genie_hermione, ALLOWED_CHARACTERS, length=14)
                    $ temp_name = temp_name.strip()
                    if temp_name == "":
                        jump hermione_talk
                    if states.her.level >=20:
                        $ name_genie_hermione = temp_name
                        jump genie_change
                    else:
                        jump genie_change_fail
                "-Never mind-":
                    jump hermione_talk

        "-From now on, I will refer to you as-":
            menu:
                "-Miss Granger-":
                    $ temp_name = _("Miss Granger")
                    jump hermione_change
                "-Hermione-":
                    $ temp_name = _("Hermione")
                    jump hermione_change
                "-Girl-":
                    $ temp_name = _("Girl")
                    if states.her.level >=1:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Nerd-":
                    $ temp_name = _("Nerd")
                    if states.her.level >=3:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Hottie-":
                    $ temp_name = _("Hottie")
                    if states.her.level >=5:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Angel-":
                    $ temp_name = _("Angel")
                    if states.her.level >=7:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Minx-":
                    $ temp_name = _("Minx")
                    if states.her.level >=9:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Princess-":
                    $ temp_name = _("Princess")
                    if states.her.level >=11:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Pet-":
                    $ temp_name = _("Pet")
                    if states.her.level >=11:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Bitch-":
                    $ temp_name = _("Bitch")
                    if states.her.level >=15:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Slut-":
                    $ temp_name = _("Slut")
                    if states.her.level >=19:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Cumslut-":
                    $ temp_name = _("Cumslut")
                    if states.her.level >= 19:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Slytherin Whore-":
                    $ temp_name = _("Slytherin Whore")
                    if states.her.level >= 22:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Mudblood-":
                    $ temp_name = _("Mudblood")
                    if states.her.level >= 22 and states.her.status.sex:
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Custom Input-":
                    $ temp_name = renpy.input(_("(Please enter the name.)"), name_hermione_genie, ALLOWED_CHARACTERS, length=14)
                    $ temp_name = temp_name.strip()
                    if temp_name == "":
                        jump hermione_talk
                    if states.her.level >=21:
                        $ name_hermione_genie = temp_name
                        jump hermione_change
                    else:
                        jump hermione_change_fail
                "-Never mind-":
                    jump hermione_talk

        "-Give her the ball dress-" if states.her.ev.yule_ball.e4_complete and ball_outfit_ITEM.owned > 0 and not states.her.ev.yule_ball.gave_dress:
            jump ball_quest_E5

        "-Start the autumn ball-" if states.her.ev.yule_ball.gave_dress and not states.her.ev.yule_ball.started:
            jump ball_ending_start

        "-Never mind-":
            jump hermione_requests


label genie_change:
    # NickName responses
    if name_genie_hermione == "Sir":
        if states.her.level < 19:
            random:
                her "Certainly, [name_genie_hermione]." ("base", "base", "base", "mid")
                her "Yes, [name_genie_hermione]." ("base", "base", "base", "mid")
                her "Of course, [name_genie_hermione]." ("base", "base", "base", "mid")
        else:
            her "Do I really have to be so formal, [name_genie_hermione]?" ("annoyed", "happy", "base", "mid")
            her "...{w=0.4} Alright then." ("open", "happy", "base", "mid")
    elif name_genie_hermione == "Dumbledore":
        if states.her.level < 3:
            her "You'd like me to call you...{w=0.4} [name_genie_hermione]?" ("soft", "base", "base", "mid")
            gen "That's my name...{w=0.4} Right?" ("base", xpos="far_left", ypos="head")
            her "Yes, but...{w=0.4} You're a teacher." ("angry", "base", "base", "mid")
            gen "So?" ("base", xpos="far_left", ypos="head")
            her "Well...{w=0.4} I just figured...{w=0.4} Alright then..." ("soft", "squint", "base", "R")
        else:
            her "Of course, [name_genie_hermione]." ("base", "base", "base", "mid")
    elif name_genie_hermione == "Professor":
        her "Certainly, [name_genie_hermione]." ("base", "base", "base", "mid")
    elif name_genie_hermione == "Old man":
        her "Old man?" ("soft", "base", "base", "mid")
        gen "That's right." ("base", xpos="far_left", ypos="head")
        her "Okay then, if you say so..." ("base", "base", "base", "mid")
    elif name_genie_hermione == "Genie":
        her "Why, [name_genie_hermione]?" ("soft", "base", "base", "mid")
        gen "Because that's my--" ("base", xpos="far_left", ypos="head")
        gen "*Err*..." ("angry", xpos="far_left", ypos="head")
        gen "Because the main role of a headmaster is to grant the wishes of their students!" ("grin", xpos="far_left", ypos="head")
        her "..." ("soft", "happy", "base", "mid")
        gen "Don't you reckon it'd be a fitting nickname?" ("base", xpos="far_left", ypos="head")
        her "Isn't the primary responsibility of the headmaster to prepare students for life after school and to ensure their overall well-being?" ("open", "base", "base", "mid")
        gen "Well, you could say that I've ensured your well-being by granting your wish to earn points for your house..." ("base", xpos="far_left", ypos="head")
        her "I guess...{w=0.4} Although--" ("disgust", "base", "base", "mid")
        gen "Although I suppose compared to a genie, I could always change my mind..." ("base", xpos="far_left", ypos="head")
        her "Well, since you'd never do that, then I suppose calling you [name_genie_hermione] would be fitting!" ("angry", "closed", "worried", "mid")
        gen "Yes! That's what I thought!" ("base", xpos="far_left", ypos="head")
    elif name_genie_hermione == "My Lord":
        if states.her.level < 13:
            her "*Hmm*... Well, I suppose you're technically a high-ranking member of an institution..." ("soft", "base", "base", "R")
            gen "A befitting title, is it not?" ("base", xpos="far_left", ypos="head")
            her "But, is it not a bit...{w=0.4} Old fashioned?" ("open", "base", "base", "mid")
            gen "Just because it's old...{w=0.4} I mean...{w=0.4} Well, I like it, okay?" ("base", xpos="far_left", ypos="head")
            her "I see... If you say so, [name_genie_hermione]." ("base", "base", "base", "mid")
        elif states.her.level < 22:
            her "If you say so, [name_genie_hermione]." ("base", "base", "base", "mid")
        else:
            her "Of course, [name_genie_hermione]..." ("base", "base", "base", "mid")
    elif name_genie_hermione == "Darling":
        if states.her.level < 13:
            her "[name_genie_hermione]?!" ("angry", "base", "base", "stare")
            gen "That's right... Unless, you think I'm not important to you?" ("base", xpos="far_left", ypos="head")
            her "I... Well, I suppose..." ("disgust", "base", "base", "stare")
        elif states.her.level < 19:
            her "[name_genie_hermione]..." ("soft", "narrow", "base", "down")
            her "Alright then..." ("base", "narrow", "base", "down")
        else:
            her "Yes, [name_genie_hermione]..." ("base", "base", "base", "mid")
    elif name_genie_hermione == "Lord Voldemort":
        her "You want me to call you--" ("angry", "base", "base", "stare")
        her "I was under the impression that witches and wizards usually avoided mentioning that name." ("angry", "base", "base", "mid")
        gen "Is that so?" ("base", xpos="far_left", ypos="head")
        her "From what I've read--" ("open", "closed", "base", "mid")
        gen "You shall not use the lord's name in vain?" ("base", xpos="far_left", ypos="head")
        her "*Huh*?" ("disgust", "base", "base", "mid")
        gen "I'm sure using it's fine, as long as you're not being disrespectful..." ("base", xpos="far_left", ypos="head")
        her "I... Alright then..." ("disgust", "happy", "base", "mid")
    elif name_genie_hermione == "Daddy":
        if states.her.level < 22:
            her "*Ehm*... Of course, [name_genie_hermione]." ("disgust", "happy", "base", "down")
        else:
            her "Yes, [name_genie_hermione]." ("base", "base", "base", "mid")
    elif name_genie_hermione == "Master":
        if states.her.level < 22:
            her "[name_genie_hermione]..." ("soft", "narrow", "base", "down")
            her "Alright then..." ("base", "narrow", "base", "down")
        else:
            her "Yes, [name_genie_hermione]..." ("base", "base", "base", "mid")
    else:
        her "Okay, from now on, I'll call you [name_genie_hermione]." ("base", "base", "base", "mid")
    jump hermione_talk

label genie_change_fail:
    her "I'm not calling you that!" ("scream", "closed", "angry", "mid")
    jump hermione_talk

label hermione_change:
    if temp_name == "Miss Granger":
        if states.her.level <=0:
            random:
                her "Sure, [name_genie_hermione]." ("base", "base", "base", "mid")
                her "Of course, [name_genie_hermione]." ("base", "base", "base", "mid")
        else:
            her "You don't have to be so formal, [name_genie_hermione], you know?" ("base", "closed", "base", "mid")
            her "" ("base", "base", "base", "mid")
    elif temp_name == "Hermione":
        her "Of course, [name_genie_hermione]." ("base", "base", "base", "mid")
    elif temp_name == "Girl":
        if states.her.level < 3:
            her "This \"girl\" thing again?" ("annoyed", "happy", "base", "mid")
            her "*Sigh*..." ("soft", "happy", "base", "R")
        elif states.her.level < 13:
            her "Fine...{w=0.4}  I don't mind." ("soft", "base", "base", "R")
        else:
            her "Of course..." ("soft", "base", "base", "R")
    elif temp_name == "Nerd":
        if states.her.level < 5:
            her "*Sigh*...{w=0.4} I just enjoy books, that's all." ("annoyed", "narrow", "worried", "down")
            gen "I'm sure you'll find other things to enjoy soon enough..." ("base", xpos="far_left", ypos="head")
            her "Like what exactly?" ("normal", "narrow", "base", "mid_soft")
            gen "Nothing to worry about, things will work out..." ("base", xpos="far_left", ypos="head")
            gen "Nerd..." ("grin", xpos="far_left", ypos="head")
            her "*Tsk* ..." ("soft", "narrow", "base", "R_soft")
            her "" ("normal", "narrow", "base", "R_soft")
        elif states.her.level < 19:
            her "I can be a bit nerdy sometimes I suppose..." ("angry", "happyCl", "base", "mid", emote="sweat")
            her "" ("base", "base", "base", "mid")
        else:
            her "I don't read as much as I used to anymore." ("grin", "narrow", "base", "R_soft", emote="sweat")
            her "" ("base", "narrow", "base", "mid_soft")
    elif temp_name == "Hottie":
        if states.her.level < 7:
            her @ cheeks blush "[name_genie_hermione]?!" ("angry", "wide", "angry", "mid")
            gen "What? That's true, you're hot." ("base", xpos="far_left", ypos="head")
            her @ cheeks blush "That's inappropriate." ("annoyed", "base", "worried", "R")
            her "But I'll let it slide, I guess."
        elif states.her.level < 19:
            her "Thank you, [name_genie_hermione]." ("soft", "wink", "base", "mid")
            her "" ("normal", "base", "base", "mid")
        else:
            her @ cheeks blush "... Glad you think so." ("smile", "wink", "base", "mid")
            her @ cheeks blush "" ("base","happy", "base", "mid")
    elif temp_name == "Good Girl": #Custom nickname (21+)
        if states.her.level <=23:
            her "I'm not sure if I'd qualify, but fine." ("annoyed", "wink", "base", "mid")
            her "" ("normal", "base", "base", "mid")
        else:
            her @ cheeks blush "I'm not sure that's true..." ("soft", "narrow", "base", "mid")
            her @ cheeks blush "But I could act like a good girl if you really want me to..." ("smile", "wink", "base", "mid")
            her @ cheeks blush "" ("base","happy", "base", "mid")
    elif temp_name == "Angel":
        if states.her.level < 9:
            her "What's going on with these silly nicknames of yours all of a sudden?" ("normal", "squint", "angry", "mid")
            gen "What do you mean by silly?" ("base", xpos="far_left", ypos="head")
            her @ cheeks blush "*Ugh*... forget I said anything..." ("open", "narrow", "base", "down")
            her @ cheeks blush "" ("normal", "base", "base", "R")
        elif states.her.level < 19:
            her @ cheeks blush "I like it..." ("soft", "narrow", "base", "R_soft")
            her @ cheeks blush "" ("base", "narrow", "base", "R_soft")
        else:
            her @ cheeks blush "After everything you've put me through, I certainly must be..." ("base", "narrow", "base", "R_soft")
            her @ cheeks blush "I'm surprised I didn't grow wings yet." ("base", "narrow", "worried", "mid_soft")
    elif temp_name == "Little Girl": #Custom nickname (21+)
        her @ cheeks blush "Little...{w=0.4} Girl..." ("soft", "narrow", "worried", "mid_soft")
        her @ cheeks blush "Yes, [name_genie_hermione]..." ("base", "narrow", "worried", "mid_soft")
    elif temp_name == "Bad Girl": #Custom nickname (21+)
        her @ cheeks blush "I suppose I may be a little bit naughty at times." ("base", "happy", "base", "R")
        her @ cheeks blush "" ("base", "base", "base", "mid")
    elif temp_name == "Minx":
        if states.her.level < 15:
            her "I guess I am a bit." ("soft", "narrow", "worried", "down")
            her "" ("normal", "narrow", "worried", "mid_soft")
        elif states.her.level < 19:
            her @ cheeks blush "I may be a little bit naughty at times." ("base", "happy", "base", "R")
        else:
            her @ cheeks blush "I may be a little bit naughty at times." ("base", "happy", "base", "R")
            her @ cheeks blush "" ("base", "base", "base", "mid")
    elif temp_name == "Princess":
        if states.her.level < 15:
            her @ cheeks blush "That would make you my prince, wouldn't it?" ("open", "base", "base", "R")
            her @ cheeks blush "" ("base", "base", "base", "mid")
        else:
            her "Yes...{w=0.4} My prince." ("smile","happy", "base", "mid")
            gen "..." ("base", xpos="far_left", ypos="head")
            her "I--{w=0.2} I mean, [name_genie_hermione]." ("smile", "happyCl", "base", "mid", emote="sweat")
            her "" ("base", "base", "base", "mid")
    elif temp_name == "Pet":
        if states.her.level < 15:
            her "You want to call me....{w=0.5} a pet?" ("normal", "squint", "angry", "mid")
            gen "Yes." ("base", xpos="far_left", ypos="head")
            her ".... {w=0.5}.... {w=0.5}.... {w=0.5}...." ("normal", "happy", "base", "mid")
            her "" ("normal", "squint", "base", "mid")
            gen ".... {w=0.5}.... {w=0.5}...." ("base", xpos="far_left", ypos="head")
            her "May I at least know why?" ("open", "squint", "base", "mid")
            gen "No." ("base", xpos="far_left", ypos="head")
            her "...." ("annoyed", "base", "worried", "mid")
        else:
            her "*Meow*" ("smile","happyCl", "base", "mid")
            her "" ("smile","happy", "base", "mid")
            gen "Don't do that..." ("base", xpos="far_left", ypos="head")
            her "Such a party pooper." ("annoyed","happyCl", "base", "mid")
            her "" ("base", "base", "base", "mid")
    elif temp_name == "Bitch":
        if states.her.level < 19:
            her "Isn't this a bit inappropriate [name_genie_hermione]?" ("mad", "narrow", "worried", "down")
            gen "And doing favours for house points isn't?" ("base", xpos="far_left", ypos="head")
            her @ cheeks blush "Fine..." ("base", "narrow", "base", "down")
        elif states.her.level < 21:
            her @ cheeks blush "..." ("normal", "narrow", "worried", "down")
            gen "Any objections?" ("base", xpos="far_left", ypos="head")
            her @ cheeks blush "..." ("soft", "base", "worried", "R")
            gen "Okay then..." ("grin", xpos="far_left", ypos="head")
        else:
            her @ cheeks blush "Alright." ("base", "happyCl", "base", "mid")
            her @ cheeks blush "" ("base","happy", "base", "mid")
    elif temp_name == "Slut":
        if states.her.level < 21:
            her @ cheeks blush "I suppose if you have to call me that, sure..." ("base", "narrow", "base", "down")
        else:
            her @ cheeks blush "I don't mind..." ("smile", "happyCl", "base", "mid")
    elif temp_name == "Cumslut":
        if states.her.level < 22:
            her "I suppose if you have to call me that, sure..." ("base", "narrow", "base", "down")
        else:
            her "..." ("soft", "narrow", "base", "up")
            her @ cheeks blush "(When did I start enjoying it so much...)" ("open", "narrow", "base", "up")
            her @ cheeks blush "(That taste, even the texture...)" ("open", "narrow", "annoyed", "up")
            her @ cheeks blush "(So warm, sticky, and--)" ("silly", "narrow", "base", "up")
            gen "Are you okay there, [temp_name]?" ("base", xpos="far_left", ypos="head")
            her "Wha--" ("mad", "wide", "base", "stare")
            her @ cheeks blush "Of course I am!" ("smile", "base", "base", "R")
    elif temp_name == "Slytherin Whore":
        her "Do you really have to call me that, [name_genie_hermione]?" ("disgust", "base", "worried", "mid")
        her @ cheeks blush "Referring to me as a bitch or a slut for your own amusement is one thing..." ("mad", "narrow", "worried", "down")
        her "I know you're aware of how much I loathe Slytherin..." ("open", "narrow", "worried", "mid_soft")
        her "And I'm definitely not a whore..." ("soft", "closed", "base", "mid")
        her "I refuse!"
        menu:
            "-Say it's fine-":
                gen "Fine, I won't call you that..." ("base", xpos="far_left", ypos="head")
                her "You won't?" ("open", "base", "base", "mid")
                her "" ("soft", "base", "base", "mid")
                gen "Of course..." ("base", xpos="far_left", ypos="head")
                her "I am glad we're on the same page on this one, [name_genie_hermione]." ("open", "closed", "base", "mid")
                her "" ("base", "closed", "base", "mid")
                gen "In fact, from this point forward you don't have to call me [name_genie_hermione], or exchange any favours..." ("base", xpos="far_left", ypos="head")
                her "" ("soft", "base", "base", "mid", emote="confused")
                gen "Let's just void this whole... deal of yours, shall we?" ("base", xpos="far_left", ypos="head")
                her "B-but, [name_genie_hermione]?!" ("mad", "wide", "base", "mid", emote="shocked")
                her "" ("mad", "wide", "base", "mid")
                gen "I must apologise {b}Miss Granger{/b}, I thought we had come to some kind of agreeable arrangement by now..." ("base", xpos="far_left", ypos="head")
                her "But I--" ("mad", "wide", "worried", "stare")
                gen "I should have known better to believe that this sort of thing would work out..." ("base", xpos="far_left", ypos="head")
                her "Maybe I could--" ("clench","happyCl", "worried", "stare")
                gen "I thought we both had what we wanted..." ("base", xpos="far_left", ypos="head")
                her "Listen--" ("soft", "narrow", "worried", "down")
                her "" ("normal", "closed", "angry", "mid")
                gen "Might as well hand in my resignation with the ministry and--" ("base", xpos="far_left", ypos="head")
                with hpunch
                her @ cheeks blush "{size=+10}I AM A SLYTHERIN WHORE!!!{/size}" ("scream", "closed", "angry", "mid")
                her "" ("normal", "closed", "base", "mid")
                gen "..." ("base", xpos="far_left", ypos="head")
                her "Now please, [name_genie_hermione]... Let's just forget this conversation ever happened." ("disgust", "base", "worried", "mid")
                gen "Are you sure that's what you want, [temp_name]?" ("base", xpos="far_left", ypos="head")
                her "... Yes." ("disgust", "narrow", "worried", "down", emote="sweat")
                gen "(This girl really is beyond redemption...)" ("base", xpos="far_left", ypos="head")
                her "" ("base", "narrow", "worried", "down")
            "-Threaten her-":
                gen "Either accept my offer or Gryffindor lose five hundred points..." ("angry", xpos="far_left", ypos="head")
                with hpunch
                her "{size=+4}Five hundred?!{/size}" ("shock", "wide", "base", "stare")
                her "[name_genie_hermione]... This is blackmailing!" ("scream", "closed", "angry", "mid")
                her "" ("mad", "closed", "angry", "mid")
                gen "It is?" ("base", xpos="far_left", ypos="head")
                her @ cheeks blush "What else would it be?" ("mad", "base", "angry", "mid")
                gen "Negotiations..." ("grin", xpos="far_left", ypos="head")
                her @ cheeks blush "You..." ("clench", "closed", "angry", "mid")
                gen "That's not an answer..." ("base", xpos="far_left", ypos="head")
                her @ cheeks blush "{size=-10}Okay...{/size}" ("soft", "narrow", "angry", "R")
                gen "What was that? I didn't hear you." ("base", xpos="far_left", ypos="head")
                her @ cheeks blush "I said yes, you can call me a Slytherin whore... or whatever." ("normal", "narrow", "annoyed", "mid")
                her @ cheeks blush "Happy now?!" ("open", "closed", "angry", "mid")
                gen "Very." ("grin", xpos="far_left", ypos="head")
                her @ cheeks blush "{size=-6}You are the worst.{/size}" ("normal", "narrow", "base", "R_soft")
                $ states.her.mood += 15
    elif temp_name == "Mudblood":
        her "A...{w=0.5} {size=+6}{b}{cps=20}mud{w=0.5}blood{/cps}{/b}?!{/size}" ("shock", "wide", "base", "stare")
        her "Did I hear you right, [name_genie_hermione]?!" ("normal", "wide", "base", "mid")
        menu:
            "-Confirm-":
                pass
            "-!!!{b}ABORT ABORT ABORT{/b}!!!-{#LINT_IGNORE}":
                gen "What? Of course not!" ("angry", xpos="far_left", ypos="head")
                gen "I said..." ("base", xpos="far_left", ypos="head")
                gen "(I have to think fast)" ("angry", xpos="far_left", ypos="head")
                menu:
                    "-Mass flood-":
                        gen "I said mass flood!" ("angry", xpos="far_left", ypos="head")
                        her "Mass flood?" ("soft", "base", "base", "mid")
                        gen "Are you deaf or something?" ("base", xpos="far_left", ypos="head")
                        if states.env.weather == "rain":
                            her "I was pretty sure you said--" ("open", "base", "base", "mid")
                            her "" ("normal", "base", "base", "R")
                            gen "Look outside the window, it's raining is it not?" ("base", xpos="far_left", ypos="head")
                            her "I{w=0.5}...{w=0.5} Yes, you are right [name_genie_hermione]." ("normal", "closed", "base", "mid")
                            gen "Of course I am." ("base", xpos="far_left", ypos="head")
                            her "So what did you want to talk about?" ("base", "base", "base", "mid")
                        else:
                            her "[name_genie_hermione], but it's not raining..." ("normal", "closed", "base", "mid")
                            her @ cheeks blush "" ("disgust", "narrow", "base", "down")
                            gen "Last time I had my dick in you, it felt like a mass flood." ("grin", xpos="far_left", ypos="head")
                            her @ cheeks blush "[name_genie_hermione]..." ("disgust", "closed", "base", "mid")
                            gen "What? It's true, I swear!" ("grin", xpos="far_left", ypos="head")
                            her @ cheeks blush "..." ("soft", "narrow", "worried", "down")
                    "-Mad stud-":
                        gen "I said mad stud!" ("angry", xpos="far_left", ypos="head")
                        her "Mad stud?" ("soft", "base", "base", "mid")
                        gen "My dick, your ass, bud." ("grin", xpos="far_left", ypos="head")
                        her @ cheeks blush "Really..." ("disgust", "narrow", "base", "mid_soft")
                        her @ cheeks blush "You can be so childish sometimes, [name_genie_hermione]..." ("annoyed", "narrow", "base", "R_soft")
                jump hermione_talk
        her "Why would you even suggest calling me such a thing..." ("scream", "squint", "angry", "mid")
        her @ tears soft "It's like the most offensive thing you could call someone like..." ("shock", "squint", "angry", "mid")
        her @ tears soft_blink "Like..." ("open", "happyCl", "worried", "mid")
        her @ tears mascara_crying "Someone like..." ("open", "narrow", "worried", "down")
        her @ tears mascara_soft "Me..." ("disgust", "narrow", "worried", "down")
        her @ tears mascara "" ("disgust", "happyCl", "worried", "mid")
        menu:
            "-Try to calm her down-":
                her @ tears mascara "" ("disgust", "narrow", "worried", "mid_soft")
                gen "Now, now, there's no need to cry." ("base", xpos="far_left", ypos="head")
                gen "Do you know why I call you these things, Miss Granger?" ("base", xpos="far_left", ypos="head")
                her @ tears mascara "... No?" ("disgust", "narrow", "worried", "mid_soft")
                gen "It's so that you'll come to know that words are just words, and they only hurt if you let them." ("base", xpos="far_left", ypos="head")
                her @ tears mascara "..." ("normal", "narrow", "worried", "mid_soft")
                gen "Once you truly understand that nothing will hold you back." ("base", xpos="far_left", ypos="head")
                gen "And you'll be at your utmost potential." ("grin", xpos="far_left", ypos="head")
                her @ tears mascara "You really think so?" ("open", "narrow", "worried", "mid_soft")
                her @ tears mascara "" ("normal", "narrow", "worried", "mid_soft")
                gen "Yes, in fact I do." ("base", xpos="far_left", ypos="head")
                her @ tears mascara "Thank you, [name_genie_hermione]." ("normal", "closed", "base", "mid")
                her @ tears mascara "I can do it, I know I can." ("base", "narrow", "worried", "mid_soft")
            "-Tell her she deserves it-":
                gen "You deserve to be called a slut, a whore and a mudblood... Just look at you." ("angry", xpos="far_left", ypos="head")
                her @ tears mascara_soft_blink "..." ("scream", "happyCl", "worried", "mid")
                her @ tears mascara_soft "" ("disgust", "happyCl", "worried", "mid")
                gen "You walk into my office and sell your body for the sole reason that it will make Gryffindor happy to win the house cup." ("angry", xpos="far_left", ypos="head")
                her @ tears mascara_soft_blink "..." ("open", "happyCl", "worried", "mid")
                her @ tears mascara_soft "" ("disgust", "happyCl", "worried", "mid")
                gen "Bending over onto my desk and let yourself be taken like a some common harlot..." ("angry", xpos="far_left", ypos="head")
                her @ tears mascara_soft "I..." ("disgust", "narrow", "worried", "mid_soft")
                gen "Letting your headmaster thrust himself upon you, and taking my load like your life depended on it..." ("angry", xpos="far_left", ypos="head")
                her @ tears mascara_soft "..." ("normal", "happyCl", "worried", "mid")
                her @ tears mascara "" ("normal", "narrow", "worried", "mid_soft")
                gen "I bet you don't even care about the points anymore..." ("base", xpos="far_left", ypos="head")
                her @ tears mascara "I..." ("normal", "narrow", "worried", "down")
                her @ tears mascara "" ("normal", "narrow", "annoyed", "up")
                gen "You are nothing more than a whore..." ("base", xpos="far_left", ypos="head")
                her @ tears mascara "" ("annoyed", "narrow", "annoyed", "up")
                gen "{size=+4}{b}MY{/b}{/size} whore!" ("grin", xpos="far_left", ypos="head")
                her @ tears mascara "" ("disgust", "narrow", "base", "up")
                gen "And I {b}will{/b} call you however I want!" ("base", xpos="far_left", ypos="head")
                her @ tears mascara "...." ("angry", "narrow", "base", "up")
    else: #Custom/fallback
        her "That's a bit odd...{w=0.4} But sure, you can call me that." ("soft", "squint", "base", "mid")

    $ name_hermione_genie = temp_name
    jump hermione_talk

label hermione_change_fail:
    if temp_name == "Girl":
        her "I would prefer if we kept using our formal names and titles, [name_genie_hermione]." ("open", "closed", "base", "mid")
        her "" ("normal", "base", "base", "mid")
    elif temp_name == "Nerd":
        her "I would prefer if you didn't, [name_genie_hermione]." ("open", "closed", "angry", "mid")
        her "{size=-4}And I'm not a nerd...{/size}" ("annoyed", "base", "worried", "mid")
        if states.her.level >= 1:
            her "(I think...)" ("annoyed", "base", "worried", "R")
    elif temp_name == "Hottie":
        her "I don't think that would be appropriate, [name_genie_hermione]..." ("open", "closed", "base", "mid")
        gen "You'd feel a lot better if you tried to be less critical of yourself..." ("base", xpos="far_left", ypos="head")
        her "*Huh*?" ("open", "base", "base", "mid")
    elif temp_name == "Angel":
        her "I certainly am!" ("open", "closed", "base", "mid")
        her "But I won't let you call me that..." ("open", "base", "base", "mid")
    elif temp_name == "Minx":
        her "That is neither appropriate, nor true!" ("annoyed", "closed", "base", "mid")
    elif temp_name == "Good Girl":
        her "I'm not letting you call me that, [name_genie_hermione]!" ("open", "closed", "angry", "mid")
        if states.her.level >= 3:
            her "(Although it's kinda cute he said that...)" ("base", "base", "base", "R")
    #elif temp_name == "Little Girl":
        #her "What's going on with these silly nicknames of yours all of a sudden?" ("normal", "squint", "angry", "mid")
        #gen "What do you mean by silly?" ("base", xpos="far_left", ypos="head")
        #her "It makes it sound as if I'm your..." ("soft", "base", "worried", "R")
        #her "I won't let you call me that, [name_genie_hermione]!" ("open", "closed", "angry", "mid")
        #if states.her.level >= 16:
            #her "(Surely my chest is big enough...)" ("disgust", "narrow", "worried", "down")
            #her "*Sigh*" ("annoyed", "closed", "base", "mid")
            #her "" ("normal", "base", "base", "R")
    #elif temp_name == "Bad Girl":
        #her "I guess I am a bit." ("soft", "narrow", "worried", "down")
        #her "I did fail that test after all..." ("disgust", "narrow", "base", "down")
        #her "Wait... You meant it in a--{w=0.2} I am not a [temp_name]!" ("open", "base", "angry", "mid")
        #if states.her.level >= 7:
            #her "(Or am I...?)" ("disgust", "base", "base", "R")
            #her "" ("normal", "base", "base", "R")
    elif temp_name == "Princess":
        her "This is inappropriate, [name_genie_hermione]!" ("open", "base", "angry", "mid")
        if states.her.level >= 9:
            her "(It sounds nice though...)" ("base", "base", "base", "R")
    elif temp_name == "Pet":
        her "Are you joking, [name_genie_hermione]?" ("open", "base", "worried", "mid")
        if states.her.level >= 11:
            her "(Why would he even suggest that?)" ("annoyed", "base", "base", "R")
    elif temp_name == "Bitch":
        her "I am not a dog!" ("open", "closed", "angry", "mid")
        gen "That's not..." ("base", xpos="far_left", ypos="head")
        gen "Alrighty then..." ("base", xpos="far_left", ypos="head")
    elif temp_name == "Slut":
        her "[name_genie_hermione]?!" ("shock", "wide", "worried", "stare")
        her "You can't just call someone that!" ("mad", "wide", "base", "stare")
        gen "It'll just be between us..." ("base", xpos="far_left", ypos="head")
        her "..." ("disgust", "squint", "base", "mid")
        gen "Nothing to add?" ("base", xpos="far_left", ypos="head")
        her "" ("clench", "closed", "base", "mid", emote="angry")
        gen "So, you'll let me call you that or not?" ("base", xpos="far_left", ypos="head")
        her "{size=+5}No!{/size}" ("clench", "closed", "angry", "mid", emote="angry")
        gen "..." ("base", xpos="far_left", ypos="head")
    elif temp_name == "Cumslut":
            her "{size=+5}A what?!{/size}" ("open", "wide", "worried", "stare")
            gen "Something wrong?" ("base", xpos="far_left", ypos="head")
            her @ cheeks blush "Do you even have to ask?" ("soft", "narrow", "angry", "down")
            her @ cheeks blush "Calling someone--{w=0.4} That is so degrading!" ("angry", "narrow", "angry", "down")
            her "I won't allow it!" ("angry", "closed", "angry", "down")
    elif temp_name == "Slytherin Whore":
        her "What did you just call me?!" ("open", "wide", "worried", "stare")
        gen "*Err*... Nothing..." ("base", xpos="far_left", ypos="head")
        her "*Hmph*..." ("annoyed", "narrow", "angry", "mid")
    elif temp_name == "Mudblood":
        her "A...{w=0.5} A...{w=0.5}{nw}" ("shock", "wide", "base", "stare")
        her "A... A... M--Mm..." ("normal", "wide", "base", "stare")
        gen "(This will end up badly...)" ("base", xpos="far_left", ypos="head")
        gen "Mad stud! That's what I said!" ("base", xpos="far_left", ypos="head")
        her "*Huh?*" ("normal", "wide", "base", "mid")
        gen "Let's resume the favour trading... You mad stud, you..." ("base", xpos="far_left", ypos="head")
    else:
        her "I won't let you call me that!" ("shock", "closed", "angry", "mid")
        her "" ("normal", "base", "angry", "mid")
    jump hermione_talk