label gameover(fake=False, autohide=True):

    # Fade to black
    $ renpy.pause(0.5, hard=True)

    hide screen cartoon_zoom
    show screen gameover
    hide screen blkfade
    with d9

    $ renpy.pause(0.5, hard=True)
    play sound "sounds/jail_door.ogg"
    $ renpy.pause(1.2, hard=True)
    with hpunch
    $ renpy.pause(1.3, hard=True)
    play sound "sounds/killswitch_on.ogg"

    if autohide:
        $ renpy.pause(4.0, hard=True)

    if fake:
        show screen blkfade
        with d9

        $ renpy.pause(0.9, hard=True)

        play music "music/Only 115 (Electro Loop)_125 BPM.ogg" fadein 0.5 fadeout 1 if_changed

        hide screen gameover
        show screen credits(fake_credits_text, duration=5, pauses=1)
        with blinds

        hide screen blkfade
        hide screen credits
        with None

    if autohide:
        hide screen gameover
    return

define fake_credits_text = credits.convert(_(f"""{{image=game_logo}}{{vspace=10}}
## The Dream Team Behind This Mess

### Mastermind in Charge
### Chief Code Wrangler
### Lead Artist and Designer... or something
### UI/UX Designer and {{flip}}{{=credits_animator}}Animator{{/}}{{/flip}}, we think?
- LoafyLemon (also known as "The One Who Can't Actually Code")

### Director of Random Ideas
### Storytelling Maestro
### Lead Tester, Because Why Not?
### Sound Guy... or Girl?
### Scriptwriter... except when they forget to script
- Johnny28 (aka "Johnny Confused")

## Special Thanks to People We Didn't Forget

### Programmers Who Also Like To Code
- STG Anon (AKA The Shadow Programmer)
- MadMerlin (Also Known As The Mythical Merlyn)
- Asease1 (The One Who Can Make Anything... Sometimes)
- TropeCode (Because Tropes Are What We're Made Of)
- Gouvernathor (Governor of Code? More Like Governor of Chaos)

### Writers Who Write Words
- MadMerlin (Also Known As The Mythical Merlyn, Again)
- Livvypoo (Writer... Also Part-Time Cat Whisperer)
- Mo (Not Actually A Mysterious Figure, Just Really Lazy At Writing Names)

### Proofreaders Who Ensure We're Not Embarrassed
- Livvypoo (Also Known As The Half-Cat, Half-Writer)
- MedicBear (Doctor of Proofreading, Master of Bear Hugs)
- MaiL (Mailman By Day, Proofreader By Night)
- Lineup (Because Sometimes You Just Need A Good Line-Up)
- Cosmic (They Don't Call Me Cosmic For Nothing)

### Character Designers Who Draw Doodles
- Soggy (The One Who Can Draw Anything In 5 Minutes)
- DostojevskijSTG (Also Known As The Russian Artisan, Except Not Really)
- Noodle (Because Their Brain Looks Like Spaghetti When They Think Hard)
- MadMerlin (Again, The Mythical Merlyn)
- Artguy (Because He's An Artist And We're Too Lazy To Think Of A Name)

### Clothing Designers Who Dress Up Characters
- Soggy (The One Who Can Draw Anything In 5 Minutes, Again)
- perniciousducks (Because They Know How To Make Any Costume Look Cool)
- DostojevskijSTG (Still Not The Russian Artisan, Just A Really Good Drawer)
- Noodle (Spaghetti Artist Turned Fashion Designer)
- MadMerlin (For The Thousandth Time, The Mythical Merlyn)
- BopJp (Because They're Just As Confused As Johnny28)

### Scene Designers Who Make Places Look Nice
- BopJp (Also Known As The Confusion Incarnate)
- KitsuneArts (Because Kitsunes Are Awesome At Making Scenes)

### Game Testers Who Find Bugs Before You Do
- MadMerlin (One More Time, The Mythical Merlyn)
- Livvypoo (Half-Cat, Half-Hero Of Bug Hunting)
- Cosmic (They Don't Call Me Cosmic For Nothing)
- MaiL (Night Shift Hero Of Testing)
- Lineup (Because We Needed Another Line-Up)
- MedicBear (Hero of Endless Debugging Sessions)
- perniciousducks (Because They're Also Pretty Good At Finding Bugs)
"""))

screen cartoon_zoom():
    layer "interface"
    tag gameover
    zorder 32 # Above saybox

    button style "empty" action NullAction()

    add "images/misc/circle_cartoon.webp":
        at transform:
            xanchor 0.1
            yanchor 0.9
            xpos 108
            ypos 540
            yoffset 1300
            xzoom 24.0
            yzoom 24.0
            easein_quart 5.0 xzoom 1.0 yzoom 1.0 yoffset 0

    add Solid("#000000"):
        at transform:
            alpha 0.0
            pause 5.0
            linear 1.0 alpha 1.0

screen gameover():
    layer "interface"
    tag gameover
    zorder 20

    button style "empty" action NullAction()

    add Solid("#000000")
    add "images/misc/gameover.webp":
        at transform:
            alpha 0.0
            pause 1.0
            linear 2.0 alpha 1.0
    add Solid("#000000"):
        at transform:
            alpha 0.5
            pause 4.8
            alpha 0.0
    add "images/misc/light.webp":
        at transform:
            alpha 0.0
            pause 4.8
            alpha 1.0

    add "images/misc/folks.webp":
        at transform:
            alpha 0.0
            pause 4.8
            alpha 1.0