#Door Events (Astoria wears random clothing.)

label astoria_summon_setup:

    # Reset doll state
    $ astoria.wear("all")
    $ astoria.set_cum(None)
    $ astoria.animation = None

    if astoria_outfits_schedule:
        $ astoria.equip_random_outfit()

    call play_sound("door")
    call ast_chibi("stand","mid","base")
    with d3

    #Astoria greeting.
    call play_music("astoria")

    if ast_mood > 0:
        if 5 > ast_mood >= 1:
            ast "[ast_genie_name]?" ("annoyed", "base", "base", "mid", xpos="base", ypos="base", trans=d3)
        elif 10 > ast_mood >= 5:
            ast "What now?" ("annoyed", "base", "worried", "mid", xpos="base", ypos="base", trans=d3)
        elif 20 > ast_mood >= 10:
            ast "What is it, [ast_genie_name]?" ("annoyed", "base", "angry", "R", xpos="base", ypos="base", trans=d3)
        elif 30 > ast_mood >= 20:
            ast "What do you want, [ast_genie_name]?" ("angry", "base", "angry", "mid", xpos="base", ypos="base", trans=d3)
        elif 40 > ast_mood >= 30:
            ast "*Hmph*..." ("annoyed", "narrow", "worried", "L", xpos="base", ypos="base", trans=d3)
        elif 50 > ast_mood >= 40:
            ast "*Tsk*" ("angry", "narrow", "angry", "mid", xpos="base", ypos="base", trans=d3)
        elif ast_mood >= 50:
            ast "What?!" ("scream", "narrow", "angry", "mid", xpos="base", ypos="base", trans=d3)
            ast "" ("angry", "narrow", "angry", "mid")

        call describe_mood(_("Astoria"), ast_mood)
        call tutorial("moodngifts")
    else:
        if game.daytime:
            ast "Mornin', [ast_genie_name]." ("base", "base", "base", "mid", xpos="base", ypos="base", trans=d3)
        else:
            ast "Evenin', [ast_genie_name]." ("base", "base", "base", "mid", xpos="base", ypos="base", trans=d3)
    return