### Tier 2 ###

label hg_pf_grope_breasts_T2:
    stop music fadeout 1.0
    call her_chibi_scene("grope_tits", trans=d7)
    pause.8

    her "!!!" ("normal", "wide", "worried", "shocked")
    call nar(">Hermione takes a hesitant step back...")

    her "!!!?" ("mad", "wide", "base", "stare", cheeks="blush", ypos="head", trans=hpunch)
    hide screen bld1
    call ctc

    call nar(">Hermione tries to pull away from you, but you hold her firmly by her breasts...")

    her "??!" ("base", "narrow", "base", "up", cheeks="blush")
    call play_music("playful_tension") #SEX THEME.
    her "[genie_name], what are you--?" ("angry", "happyCl", "worried", "mid", cheeks="blush",emote="sweat")
    call nar(">She tries to pull away again.")
    call nar(">You squeeze her tits like a vice.")

    her "[genie_name], you're hurting me!" ("angry", "squint", "base", "mid", cheeks="blush")
    gen "Then stand still, [hermione_name]!" ("angry", xpos="far_left", ypos="head")
    her "B-but..." ("soft", "wide", "base", "stare")
    gen "All I want to do is squeeze your tits a little, then you will get your points!" ("base", xpos="far_left", ypos="head")
    her "B-but... this is..." ("disgust", "narrow", "base", "down", cheeks="blush")
    gen "Just stand still..." ("base", xpos="far_left", ypos="head")
    gen "go to your happy place or something..." ("base", xpos="far_left", ypos="head")
    her "M-my happy place...?" ("angry", "wink", "base", "mid")
    call nar(">You feel the girl's shapely breasts in your palms...")

    her "............................" ("shock", "happyCl", "worried", "mid", ypos="head")

    menu:
        "-Squeeze her tits with all of your strength-":
            $ her_mood += 6
            call nar(">You put strength into your hold...")
            her "my........." ("disgust", "narrow", "base", "down", cheeks="blush")
            call nar(">You squeeze her tits even harder...")
            her "[genie_name], you're hurting them..." ("shock", "happyCl", "worried", "mid")
            gen "Be quiet [hermione_name]..." ("base", xpos="far_left", ypos="head")
            her "Ouch........." ("disgust", "narrow", "base", "down", cheeks="blush")
            call nar(">You squeeze her ample tits with all your strength.")
            her "Ah! It hurts!" ("angry", "squint", "base", "mid", cheeks="blush")
            her "They're gonna burst! Please stop it!" ("angry", "squint", "base", "mid", cheeks="blush")
            gen "They are not going to burst, you silly girl..." ("base", xpos="far_left", ypos="head")
            call nar(">You loosen your grip a little...")
            her "It hurts..." ("shock", "happyCl", "worried", "mid")
            gen "You will be fine..." ("base", xpos="far_left", ypos="head")
            her "........." ("annoyed", "narrow", "angry", "R", cheeks="blush")

            jump end_hg_pf_grope

        "-Give her tits a tender massage-":
            $ her_mood += 3
            call nar(">You start massaging Hermione's beasts through her clothes...")
            her "[genie_name]...?" ("shock", "happyCl", "worried", "mid")
            gen "The points, [hermione_name]... You need the points. Concentrate on that." ("base", xpos="far_left", ypos="head")
            her "Yes..." ("annoyed", "narrow", "angry", "R", cheeks="blush")
            her "Yes, for the honour of the Gryffindor house..." ("angry", "happyCl", "worried", "mid", cheeks="blush")
            "*Squeeze-squeeze*"
            call nar(">You keep massaging her tits...","start")
            call nar(">You give one of her breasts a few pinches trying to locate the nipple...","end")
            her "[genie_name]... you're pinching me...?" ("shock", "happyCl", "worried", "mid")
            call nar(">Your attempts prove to be fruitless though. The fabric of her clothes is quite thick...")
            her "Gryffindor........." ("angry", "happyCl", "worried", "mid", cheeks="blush")

            jump end_hg_pf_grope

        "-Let her go and give her the points-":
            gen "Well if you're going to make a drama out of this, you might as well leave..." ("base", xpos="far_left", ypos="head")
            call nar(">You unhand the girl's breasts...")
            her "Thank you..." ("soft", "closed", "base", "mid", cheeks="blush")
            gen "But you didn't earn them today..." ("base", xpos="far_left", ypos="head")
            her "..............." ("annoyed", "base", "angry", "mid", cheeks="blush")

            jump end_hg_pf_grope

### Tier 3 ###

label hg_pf_grope_breasts_T3: # Favour fails if you Slap them.
    stop music fadeout 1.0
    call her_chibi_scene("behind_desk_front", trans=d7)
    $ hermione.strip("robe", "accessory")

    if hg_strip.trigger:
        menu:
            "\"First, lift up your top\"" if hermione.is_worn("top"):
                her "[genie_name]?!" ("clench", "base", "base", "mid")
                gen "What? It's not like I haven't seen them before..." ("base", xpos="far_left", ypos="head")
                her "But!" ("clench", "narrow", "base", "down")
                call play_music("playful_tension") # SEX THEME.
                gen "I just want to massage them a little..." ("base", xpos="far_left", ypos="head")
                her "..............................." ("annoyed", "narrow", "base", "down")
                her "Promise me you will be gentle with them." ("soft", "narrow", "base", "mid_soft")
                gen "Sure..." ("base", xpos="far_left", ypos="head")

                call her_chibi_scene("behind_desk_front_show_tits", trans=d5)
                with d5

                gen "Nice...{w} Now take it off will you?" ("base", xpos="far_left", ypos="head")

                $ hermione.strip("top")
                call her_chibi_scene("behind_desk_front", trans=d5)
                with d3

                gen "Very good..." ("base", xpos="far_left", ypos="head")
                her "..." ("soft", "narrow", "base", "R", trans=d5)

                if hermione.is_worn("bra"):
                    gen "Now your bra..." ("base", xpos="far_left", ypos="head")

                    $ hermione.strip("bra")
                    her "..." ("annoyed", "narrow", "base", "mid")

            "\"Yes, let me feel them!\"":
                pass

    pause.5

    call bld
    menu:
        gen "Let's see now..." ("base", xpos="far_left", ypos="head")
        "-Grab them-":
            jump hg_pf_grope_breasts_T3_continue

        "-Slap them-":
            pass


    # Event fails
    call nar(">You give Hermione's tits a loud slap!")
    call slap_her

    $ her_mood += 10
    her "!!!" ("scream", "wide", "base", "stare", cheeks="blush")
    her "Ouch! It hurts! *SOB*!" ("angry", "base", "worried", "mid", cheeks="blush")
    gen "Did you like it though?" ("base", xpos="far_left", ypos="head")
    her "Did I... \"like it\", [genie_name]...?" ("annoyed", "narrow", "annoyed", "mid")
    her "What girl in her right mind would like to be treated this way?"
    stop music fadeout 1.0

    $ hermione.wear("all")
    call her_chibi_scene("reset","desk","base", trans=fade)
    pause.5

    her "You are a mean and demented old man!" ("angry", "base", "angry", "mid", cheeks="blush", tears="soft", xpos="mid", ypos="base")
    gen "............" ("base", xpos="far_left", ypos="head")

    call her_walk(action="leave")

    call bld
    gen "Well, no points for Gryffindor then..." ("base", xpos="far_left", ypos="head")

    jump end_hermione_event

label hg_pf_grope_breasts_T3_continue:
    call her_chibi_scene("grope_tits", trans=d7)
    call ctc

    her ".............................." ("angry", "narrow", "base", "down")
    gen "You have great tits, [hermione_name]..." ("base", xpos="far_left", ypos="head")
    her "...................................." ("angry", "narrow", "base", "down")
    gen "You like it when I squeeze them like this?" ("base", xpos="far_left", ypos="head")
    her "Excuse me, [genie_name], but you are confusing me with one of those lowly harlots again..." ("upset", "closed", "base", "mid")
    her "I am only letting you fondle me because I am getting paid for it..." ("upset", "closed", "base", "mid")
    her "Not because I enjoy it..." ("upset", "closed", "base", "mid")
    gen "I see..." ("base", xpos="far_left", ypos="head")
    gen "So, you're more like a prostitute then..." ("base", xpos="far_left", ypos="head")
    her "[genie_name]!" ("angry", "wide", "base", "stare")
    her "Prostitutes are paid to have sex with men..." ("angry", "wide", "base", "stare")
    her "I'd never do something like that!" ("upset", "closed", "base", "mid")

    call nar(">You squeeze one of the girl's tits tightly and give the other a couple of firm tugs.")

    her "*Ah*..." ("open", "happyCl", "worried", "mid")
    gen "Enjoying yourself, [hermione_name]?" ("base", xpos="far_left", ypos="head")

    her "[genie_name], I am only doing this--" ("upset", "closed", "base", "mid")

    call nar(">You squeeze both of her tits with force...")

    her "*Ah*..." ("shock", "happyCl", "worried", "mid")
    gen "Tell me you like this, [hermione_name]!" ("base", xpos="far_left", ypos="head")
    her "[genie_name], I am only letting you do this to me because--" ("open", "happyCl", "worried", "mid")
    gen "I know, I know..." ("base", xpos="far_left", ypos="head")
    gen "You are starting to sound like a broken record." ("base", xpos="far_left", ypos="head")
    her "...." ("annoyed", "narrow", "annoyed", "mid")


    jump end_hg_pf_grope

### Tier 4 ###

label hg_pf_grope_breasts_T4:
    stop music fadeout 1.0
    call her_chibi_scene("behind_desk_front", trans=d7)
    pause.8

    her "............" ("base", "narrow", "worried", "down", cheeks="blush")

    call play_music("playful_tension") # SEX THEME.
    $ hermione.strip("robe", "accessory")

    if hermione.is_worn("top"):
        call nar(">Hermione shifts to start undoing her clothes...")

        menu:
            "\"That's right, take it off!\"":
                $ hermione.strip("top")
                with d3

                if hermione.is_worn("bra"):
                    gen "Show them to me at once!" ("grin", xpos="far_left", ypos="head")
                    her "......."
                    $ hermione.strip("bra")
                pass

            "\"No, leave it on.\"":

                gen "I want to massage them with your top on..." ("base", xpos="far_left", ypos="head")
                her "Oh, I see..." ("open", "base", "base", "R", cheeks="blush")
                jump hg_pf_grope_breasts_T4_clothed

    elif hermione.is_worn("bra"):
        call nar(">Hermione shifts to start undoing her bra...")
        $ hermione.strip("bra")
        her "" ("base", "narrow", "worried", "down", cheeks="blush")
        call ctc
        gen "Very good..." ("base", xpos="far_left", ypos="head")


    jump hg_pf_grope_breasts_T4_naked

label hg_pf_grope_breasts_T4_naked:
    stop music fadeout 1.0
    call her_chibi_scene("behind_desk_front", trans=d7)
    call ctc

    call play_music("playful_tension") # SEX THEME.

    hide hermione_main
    her "" ("base", "narrow", "worried", "mid", cheeks="blush", xpos="mid", ypos="base")
    call ctc

    menu:
        gen "..." ("base", xpos="far_left", ypos="head")
        "-Grab them-":
            jump hg_pf_grope_breasts_T4_continue

        "-Slap them-":
            pass

    call nar(">You give Hermione's tits a loud slap!")
    call slap_her

    her "!!!" ("scream", "wide", "base", "stare", cheeks="blush")
    her "Ouch!" ("angry", "base", "worried", "mid", cheeks="blush")
    her "[genie_name], what did you do that for?"
    gen "Dunno... Seemed like a good idea..." ("base", xpos="far_left", ypos="head")
    gen "Did you like it?" ("base", xpos="far_left", ypos="head")
    her "... Of course not, [genie_name]." ("annoyed", "closed", "base", "mid")
    gen "Let's try this again, then." ("base", xpos="far_left", ypos="head")
    her "What?" ("annoyed", "base", "base", "mid")
    call slap_her

    her "!!!" ("scream", "wide", "base", "stare", cheeks="blush")
    her "Ouch! Stop hurting me!"
    gen "Admit that you enjoy it and I will." ("base", xpos="far_left", ypos="head")
    her "But I don't..." ("disgust", "narrow", "base", "down")
    her "And if you plan to keep on doing this to me, [genie_name]..."
    her "... then I think I should leave." ("annoyed", "narrow", "annoyed", "mid")
    gen "Fine, fine..." ("base", xpos="far_left", ypos="head")

    jump hg_pf_grope_breasts_T4_continue

label hg_pf_grope_breasts_T4_clothed:
    call her_chibi_scene("grope_tits", trans=d7)
    call ctc

    #">Hermione stands in front of you expectantly..."
    #">You reach out for her ample breasts..."
    #">And start massaging them firmly..."

    "*squeeze-squeeze-squeeze*"

    her "................" ("base", "narrow", "base", "up", cheeks="blush")

    menu:
        "\"Do you enjoy this, [hermione_name]?\"":
            her "What...?" ("base", "base", "base", "R", cheeks="blush")
            her "Oh, I don't mind it..." ("base", "base", "base", "R", cheeks="blush")
            "*squeeze-squeeze-squeeze*"
            call nar(">You keep massaging her soft tits...")

            if her_tier <= 5:
                her "I mean, this isn't a big deal, as long as I am getting paid..." ("base", "narrow", "base", "up", cheeks="blush")
                if hermione.is_worn("top"):
                    call nar(">You keep on massaging her tits through her clothes...")
                her "A small price to pay for the honour of my house, really......{heart}" ("soft", "base", "base", "R", cheeks="blush")
            else:
                gen "Really? It seems to me as if you love it." ("base", xpos="far_left", ypos="head")
                her "I wouldn't say that I love it..." ("base", "narrow", "base", "up", cheeks="blush")
                call nar(">You keep on massaging her tits through her uniform...")
                gen "What would you say then, [hermione_name]?" ("base", xpos="far_left", ypos="head")
                her "I just like it, {size=-4}a lot{heart}{/size}" ("base", "narrow", "base", "up", cheeks="blush")

            jump hg_pf_grope_breasts_T4_continue

        "-Pull on them abruptly with force-":
            call nar(">You give Hermione's tits a sudden but firm pull...","start")
            with vpunch
            her "Ouch..." ("angry", "happyCl", "worried", "mid", cheeks="blush",emote="sweat")
            call nar(">You pull on her tits again. This time much stronger.","start")
            with vpunch
            her "Ouch! [genie_name], what are you trying to do...?" ("angry", "happyCl", "worried", "mid", cheeks="blush",emote="sweat")
            call nar(">You jerk the girl down by her tits with all your strength...","start")
            with vpunch
            with vpunch
            call nar(">Hermione almost loses balance...","end")
            her "*Panting* What are you doing, [genie_name]...?" ("open", "base", "base", "R", cheeks="blush")
            her "You don't need to be so rough with me....{heart}" ("base", "base", "base", "R", cheeks="blush")

            jump hg_pf_grope_breasts_T4_continue

label hg_pf_grope_breasts_T4_continue:
    call her_chibi_scene("grope_tits", trans=d7)
    call ctc

    her "*Ah*..." ("open", "narrow", "worried", "down")

    call nar(">You squeeze her tits a few more times, then give them a firm tug...")

    her "*Ah*... [genie_name]..." ("open", "base", "base", "mid")
    gen "What? You enjoy this, don't you?" ("base", xpos="far_left", ypos="head")
    her "No... I..." ("open", "base", "base", "mid")
    gen "Don't you lie to your headmaster, [hermione_name]!" ("base", xpos="far_left", ypos="head")

    call nar(">You squeeze her tits again...")

    her "*Ah*..." ("open", "narrow", "worried", "down")
    her "I am not lying, [genie_name]..." ("open", "narrow", "worried", "down")
    her "Why would I enjoy this?" ("open", "base", "base", "mid")
    gen "I don't know [hermione_name]. You tell me." ("base", xpos="far_left", ypos="head")

    call nar(">You keep massaging her breasts...")

    her "*Ah*... I..." ("open", "base", "base", "mid")
    gen "Yes, what is it?" ("base", xpos="far_left", ypos="head")
    her "It's... It's nothing, [genie_name]..." ("angry", "base", "base", "mid")
    gen "Oh, I think it's something." ("base", xpos="far_left", ypos="head")
    gen "I think you like me squeezing your tits like this." ("base", xpos="far_left", ypos="head")
    her "[genie_name], please..." ("angry", "narrow", "base", "down")

    if game.daytime:
        her "Classes are about to start..." ("angry", "narrow", "base", "down")
    else:
        her "It's getting late..." ("angry", "narrow", "base", "down")

    her "Can I go now, [genie_name]? Please?" ("angry", "base", "base", "mid")

    gen "Sure, go ahead..." ("base", xpos="far_left", ypos="head")
    pause 2
    her "..............." ("angry", "narrow", "base", "down")
    pause.2

    her "[genie_name], you're... Still... Holding me." ("angry", "base", "base", "mid")
    gen "Oh, right... my bad." ("base", xpos="far_left", ypos="head")


    jump end_hg_pf_grope