label a_christmas_tale2_rewards:
    # Unlock outfit message. Should only appear once.

    if not her_outfit_ribbon.unlocked:
        call unlock_clothing(text=">New clothing items for Hermione have been unlocked!", item=her_outfit_ribbon)
        call unlock_clothing(text=">Several new clothing items for Hermione have been unlocked!", item=her_outfit_xmas)
        call unlock_clothing(text=">New clothing items for Tonks have been unlocked!", item=ton_outfit_ribbon)
        call unlock_clothing(text=">New clothing items for Tonks have been unlocked!", item=ton_outfit_elf)
        call unlock_clothing(text=">New clothing items for Tonks have been unlocked!", item=ton_outfit_xmas)

        call give_reward("Some lesser clothing items have been unlocked as well. *Ho-ho-ho!*")

    if not xmas_phoenix_ITEM.owned:
        $ xmas_phoenix_ITEM.owned = 1
        $ xmas_owl_ITEM.owned = 1
        $ xmas_fireplace_ITEM.owned = 1
        $ xmas_lights_ITEM.owned = 1
        $ xmas_wreaths_ITEM.owned = 1
        $ xmas_giftchair_ITEM.owned = 1

        call give_reward("Christmas decorations have been unlocked!", gift="interface/icons/xmas_wreaths.webp")

    return

label a_christmas_tale2():

    # Setup
    $ fireplace_OBJ.foreground = "fireplace_fire"
    $ phoenix_OBJ.decoration = xmas_phoenix_ITEM
    $ owl_OBJ.decoration = xmas_owl_ITEM
    $ fireplace_OBJ.decoration = xmas_fireplace_ITEM
    $ tonks.equip(ton_outfit_elf)
    $ hermione.equip(her_outfit_ribbon)
    $ hermione_chibi.zorder = 4
    stop weather
    $ game.daytime = False
    $ game.weather = "snow"
    call room("main_room")
    call play_music("stop")
    call gen_chibi("hide")
    show screen blkfade
    with d5

    centered "{size=+7}{color=#cbcbcb}Santa's Little Helper{/color}{/size}"

    hide screen blkfade
    with d5

    play weather "sounds/wind_long_loop.ogg" fadein 2 fadeout 2
    call play_music("anguish")

    show screen bld1
    with d3

    nar "T'was the night before Christmas on a cold winter night."
    nar "We see the headmasters room but there's no one in sight."
    nar "No sound but the wind as the storm outside roars."
    nar "But then a man enters, as he never knocks on any doors."

    call sna_walk(action="enter")
    pause 0.5
    sna "Genie I wanted--" ("snape_06", trans=d3)
    hide snape_main
    with d3
    nar "Said the man as he entered."
    call sna_walk("desk", "base")
    sna "Never here when you need him..." ("snape_01", trans=d3)
    sna "Are genies always this self-centred?" ("snape_29")
    sna "Another walk to the pub if I want to get pissed..." ("snape_06")
    sna "Another--" ("snape_04")

    hide snape_main
    hide screen bld1
    with d3

    nar "Interrupted dialogue as the room filled with mist."
    nar "With three booming ho's, Santa Claus appeared."

    $ renpy.sound.play("sounds/fire_woosh.ogg")
    $ fireplace_OBJ.foreground = None
    stop bg_sounds
    show screen genie_santa_chibi(620, 170, flip=True)
    call teleport((620+75, 440))
    call sna_chibi(flip=True)
    with d3
    sna "Genie of course... You think I'd fall for that fake beard?" ("snape_05", trans=d3)

    san1 "I think you must be mistaken."
    hide snape_main
    hide screen bld1
    with d3
    nar "Said Santa to the man."
    show screen bld1
    with d3
    san1 "I'm not Genie, I'm Santa!"
    san1 "I deliver presents!"
    san2 "That's the plan!"

    san1 "I bring cheers and presents, to all across the land."
    sna "Are you sure about that? I don't see a sack in your hand..." ("snape_01", trans=d3)
    hide snape_main
    with d3
    san1 "Be patient dear boy... Don't you give me that face."
    san1 "Your gift will get here soon through this office fireplace."
    hide screen bld1
    with d3

    nar "With a big puff of smoke and a whiz and a whirl, an elf stood before them."

    show ch_ton elf zorder tonks_chibi.zorder at Transform(pos=(750, 430))
    show screen xmas_bag((750, 290))
    call teleport((680+75, 460))

    show screen bld1
    with d3
    san2 "Now check out this girl!"

    ton "" ("horny", "narrow", "base", "mid", hair="happy", xpos="mid", trans=d3)
    call ctc
    hide tonks_main
    sna "Now that is a present!" ("snape_13", trans=d3)
    sna "You've outdone yourself." ("snape_20")
    hide snape_main
    san1 "That's not your present, that's my sexy helper elf..."

    ton "Eye's up here boy..." ("base", "base", "base", "mid", hair="happy", trans=dissolve)
    ton "Your present is in this sack..." ("soft", "narrow", "base", "down", hair="happy")
    ton "These milkers belong to Santa!" ("horny", "narrow", "base", "L", hair="horny")
    san2 "They're my after-work Christmas snack!"

    hide tonks_main
    hide screen bld1

    show ch_ton elf zorder tonks_chibi.zorder at Transform(pos=(750, 430), xzoom=-1)
    with d3

    nar "And with a swish of her wand his present was revealed."

    hide screen xmas_bag
    show screen xmas_bagfloor((750, 290))
    show ch_hem ribbon zorder hermione_chibi.zorder at Transform(pos=(785, 450), xzoom=1)
    #call her_chibi(xpos=750, ypos=460)
    call play_sound("magic")
    with flash

    show ch_ton elf zorder tonks_chibi.zorder at Transform(pos=(750, 430), xzoom=1)
    with d3

    her "" ("soft", "base", "base", "mid", cheeks="blush", trans=dissolve)
    nar "In front of him a girl, no longer concealed."
    nar "With a bow around her pussy and ribbons around her tits."

    hide hermione_main
    with d3

    sna "Now that's a proper present!" ("snape_13", trans=d3)
    hide snape_main
    with d3
    san2 "Now unwrap those naughty bits!"

    ton "Wait, I just remembered, don't unwrap the present yet!" ("mad", "shocked", "base", "L", hair="happy", trans=dissolve)
    ton "If he's not been good this year then a gift he cannot get." ("open", "closed", "shocked", "mid", hair="happy")
    hide tonks_main
    with d3

    san2 "I'm certain he's been good... Now unwrap her I insist!"

    ton "I'm not so sure myself... His offences fill this list." ("upset", "narrow", "base", "down", hair="happy", trans=dissolve)
    hide tonks_main
    with d3

    san1 "Then read it for me elf... I'm sure it will be quick..."
    hide screen bld1
    with d3
    nar "The elf then unrolled it... A scroll six inches thick."

    ton "Inflating the points gained to put the Slytherins in the lead..." ("open", "base", "raised", "down", hair="happy", trans=dissolve)
    hide tonks_main
    with d3

    her "What?" ("clench", "happy", "angry", "mid", trans=dissolve)
    hide hermione_main
    with d3

    san1 "That can't be true!"
    sna "Mere fabrications that, indeed..." ("snape_35", trans=d3)
    hide snape_main
    with d3

    ton "Teaching plenty of classes despite that he's blind drunk." ("upset", "base", "shocked", "down", hair="happy", trans=dissolve)
    sna "I can't believe they bought that it was {i}\"Essence du Skunk\"{/i}..." ("snape_45", trans=d3)
    hide snape_main
    with d3

    ton "Punishing students for talking in class..." ("open", "closed", "base", "mid", hair="happy")
    sna "They were breaking the rules!" ("snape_07", trans=d3)
    hide snape_main
    with d3

    ton "So is slapping their ass..." ("disgust", "narrow", "base", "mid", hair="happy")
    san1 "Well I'm sure they're all right... It was only a slap..."
    ton "I'm not done yet santa, there's more..." ("annoyed", "narrow", "base", "L", hair="happy")
    san1 "What the crap..."

    ton "Stealing mounds of sweets and sniffing girls hair..." ("normal", "base", "raised", "down", hair="happy")
    sna "Now let's be reasonable for a minute, this list isn't fair!" ("snape_18", trans=d3)
    hide snape_main
    with d3

    san1 "I think he's got a point, at least he didn't curse..."
    ton "You say that but now, is when the list is getting worse..." ("disgust", "base", "base", "mid", hair="happy")

    ton "He's bought blowjobs with house points... Now that doesn't sound great..." ("open", "narrow", "base", "down", hair="happy")
    san2 "A misprint I'm sure!"
    ton "The list says thirty-eight..." ("mad", "wide", "base", "down", hair="happy")

    ton "Wrapped around his finger... This is making me sick..." ("upset", "base", "base", "down", hair="upset")
    ton "This list is massive!" ("clench", "wide", "annoyed", "down", hair="angry")
    san1 "Then just skim it real quick..."

    ton "Taking girls books and replacing it with smut..." ("disgust", "narrow", "base", "down", hair="happy")
    ton "Then punishing them for it by spanking their butt..." ("annoyed", "narrow", "annoyed", "mid", hair="happy")

    sna "She had it coming I tell you... That girl was a whore..." ("snape_12", trans=d3)
    hide snape_main
    with d3

    ton "See what I mean Santa?" ("disgust", "base", "base", "L", hair="disgusted")
    ton "And this list has even more..." ("upset", "base", "base", "down", hair="happy")

    ton "Confiscating panties... Cumming on floors..." ("soft", "base", "annoyed", "down", hair="happy")
    ton "Spying in the toilets..." ("disgust", "narrow", "base", "down", hair="disgusted")
    ton "Never knocks on any doors..." ("open", "closed", "base", "mid", hair="happy")

    san1 "Never knocks on any doors?!"
    nar "Said Santa at last."
    san1 "Now that's a big offence!"
    ton "You really think so Santa?" ("annoyed", "wide", "raised", "mid", hair="happy")
    sna "Blast..." ("snape_11", trans=d3)
    hide snape_main
    with d3

    san1 "Sexual acts is one thing... But not knocking on doors!"
    san1 "A man without manners is what Santa Claus abhors."
    san1 "I can't give you a gift but I offer this advice."
    san1 "Most things I will ignore but good manners deem you nice."

    san1 "Now ladies it's time to leave, it is a busy time of year..."
    san1 "Let us empty this sack and spread my Christmas cheer."
    ton "This meeting took way too long so we better spread it quick..." ("mad", "base", "base", "L", hair="happy")
    ton "I hope I get overtime for this..." ("annoyed", "base", "base", "R", hair="happy")
    hide tonks_main
    with d3
    san2 "I'll let you ride my magic di--"

    call gen_chibi("hide")
    #call ton_chibi("hide")
    #call her_chibi("hide")
    hide ch_hem ribbon
    hide ch_ton elf
    call play_sound("magic")
    show screen xmas_smoke
    with flash

    #Effect and then they're gone

    nar "Smoke then filled the room and then slowly dispersed, his present now gone..."
    sna "Santa, You're the worst..." ("snape_03", trans=d3)
    nar "With the man's final words left echoing across the halls."
    nar "He had to spend another Christmas with the bluest of blue balls..."

    call hide_characters
    with d5

    $ renpy.end_replay()

screen xmas_bag(pos):
    zorder 5
    add "images/misc/bag.webp" zoom 0.5 pos pos

screen xmas_bagfloor(pos):
    zorder 2
    add "images/misc/bag_floor.webp" zoom 0.5 pos pos

screen xmas_smoke():
    zorder 10
    add "xmas_smoke"

image xmas_smoke:
    "images/misc/smoke.webp"
    align (0.5, 0.5)
    zoom 0.55
    subpixel True

    parallel:
        linear 2.5 yoffset -10
        linear 2.5 yoffset 10
        repeat

    parallel:
        linear 5.0 xoffset 20
        linear 5.0 xoffset -20
        repeat