label phoenix:

    if game.day == 1:
        if not states.gen.ev.intro.bird_examined:
            $ states.gen.ev.intro.bird_examined = True
            $ phoenix_OBJ.idle = "phoenix_idle"
            call gen_chibi("stand","mid","base",flip=False)
            with d5
            gen "*Hmm*..." ("base", xpos="far_left", ypos="head")
            gen "Even this weird-looking bird radiates magic..." ("base", xpos="far_left", ypos="head")
            call gen_chibi("sit_behind_desk")
            with d5
        else:
            gen "It's just a bird. Nothing more to say." ("base", xpos="far_left", ypos="head")

        if states.gen.ev.intro.bird_examined and states.gen.ev.intro.desk_examined and states.gen.ev.intro.cupboard_examined and states.gen.ev.intro.door_examined and states.gen.ev.intro.fireplace_examined:
            jump genie_intro_E2

    jump main_room_menu

label phoenix_feed:
    if not states.bird_fed:
        $ states.bird_fed = True
        $ states.bird_fed_times += 1

        call gen_chibi("grab_high", phoenix_OBJ.xpos, phoenix_OBJ.ypos+365, flip=False) # Note: Flip is inconsistent
        with d3
        pause .5

        $ phoenix_OBJ.foreground = "phoenix_food"
        with d3

        random:
            gen "There you go..." ("base", xpos="far_left", ypos="head")
            gen "Eat up, buddy." ("base", xpos="far_left", ypos="head")
            gen "Savour every bite, bird." ("base", xpos="far_left", ypos="head")
            gen "Don't be shy—dig in, it's not like this stuff grows on trees." ("base", xpos="far_left", ypos="head")
            gen "Eat up! You're the star ingredient in an upcoming hearty phoenix soup." ("grin", xpos="far_left", ypos="head")

        pause .8
        call gen_chibi("sit_behind_desk")
    else:
        random:
            gen "I already fed it today." ("base", xpos="far_left", ypos="head")
            gen "The poor thing doesn't even need more food today, it's all set." ("base", xpos="far_left", ypos="head")
            gen "Let's leave the Phoenix to its nap. It had enough for the day." ("base", xpos="far_left", ypos="head")
            gen "This phoenix prefers to take things slow and steady." ("base", xpos="far_left", ypos="head")
            gen "It's full up and won't need to eat till tomorrow." ("base", xpos="far_left", ypos="head")
            gen "I wonder if I pet you enough, would you magically transform into a sexy woman?" ("base", xpos="far_left", ypos="head")

        pause .8
    jump main_room_menu

label phoenix_pet:
    if not states.bird_petted:
        $ states.bird_petted = True
        $ states.bird_petted_times += 1
        call gen_chibi("petting", phoenix_OBJ.xpos, phoenix_OBJ.ypos+270, flip=False) # Note: Flip is inconsistent
        with d3
        pause .5

        random:
            gen "Who's a good bird?" ("base", xpos="far_left", ypos="head")
            "*Pat* *Pat* *Pat*..."
            gen "Glad you aren't as noisy as Iago..." ("base", xpos="far_left", ypos="head")
            gen "Can't resist a little head scratch, eh?" ("base", xpos="far_left", ypos="head")
            gen "Nice feathers, wouldn't want to pluck those out..." ("base", xpos="far_left", ypos="head")
            gen "See? I scratch your back, you scratch mine." ("base", xpos="far_left", ypos="head")

            block if 20 > states.bird_petted_times > 10:
                gen "I've petted you {number=states.bird_petted_times} times. Just a couple more, and I'm sure something will happen... Right?" ("base", xpos="far_left", ypos="head")
            block if 30 > states.bird_petted_times > 20:
                gen "How many more times do I have to pet you for you to do something? It's been {number=states.bird_petted_times} already!" ("angry", xpos="far_left", ypos="head")
            block if 40 > states.bird_petted_times > 30:
                gen "Dear diary, it's been {number=states.bird_petted_times} pets since I landed here, yet that stubborn bird still refuses to talk to me." ("base", xpos="far_left", ypos="head")
            block if 50 > states.bird_petted_times > 40:
                gen "I pet you patiently, but all I get is silence. Wait, how many times was it again? {number=states.bird_petted_times}?" ("base", xpos="far_left", ypos="head")
            block if 60 > states.bird_petted_times > 50:
                gen "I've read about talking birds, but you must have missed that chapter." ("base", xpos="far_left", ypos="head")
            block if 70 > states.bird_petted_times > 60:
                gen "Why won't you even acknowledge my presence, bird?" ("base", xpos="far_left", ypos="head")
            block if 80 > states.bird_petted_times > 70:
                gen "Another day, another attempt to coax some words out of you." ("base", xpos="far_left", ypos="head")
            block if 90 > states.bird_petted_times > 80:
                gen "Do you understand how hard it is to communicate with a bird that won't talk back?" ("base", xpos="far_left", ypos="head")
            block if 100 > states.bird_petted_times > 90:
                gen "I'm starting to wonder if you're just ignoring me on purpose." ("base", xpos="far_left", ypos="head")
            block if 110 > states.bird_petted_times > 100:
                gen "This is getting old. Can't you just say something already?" ("base", xpos="far_left", ypos="head")
            block if 120 > states.bird_petted_times > 110:
                gen "I've tried everything. What's it going to take to get through to you?" ("base", xpos="far_left", ypos="head")
            block if 130 > states.bird_petted_times > 120:
                gen "You're testing my patience, feathered friend." ("base", xpos="far_left", ypos="head")
            block if 140 > states.bird_petted_times > 130:
                gen "It's like talking to a brick wall, but at least a brick wall doesn't pretend to understand." ("base", xpos="far_left", ypos="head")
            block if 150 > states.bird_petted_times > 140:
                gen "Congratulations, you've mastered the art of infuriating silence." ("base", xpos="far_left", ypos="head")
                faw "..."
            block if 300 > states.bird_petted_times > 200:
                gen "Hello darkness my old friend..." ("base", xpos="far_left", ypos="head")
                faw "*cawk*"
                gen "There's no way that fucking worked!" ("angry", xpos="far_left", ypos="head")
                gen "Seriously, though, can you talk now?" ("base", xpos="far_left", ypos="head")
                faw "..."
                gen "... Just great." ("base", xpos="far_left", ypos="head")
            block if states.bird_petted_times > 300:
                gen "I can't believe I'm still doing this." ("base", xpos="far_left", ypos="head")
                faw "AHHHH AFTER TEN THOUSAND YEARS I'M FREE!"
                gen "BY THE GREAT DESERT SANDS, IT FINALLY WORKED!" ("grin", xpos="far_left", ypos="head")
                gen "But wait, I've only been doing this for {number=game.day}..." ("base", xpos="far_left", ypos="head")
                faw "Oh, really? Well, I still have time for a nap then."
                gen "WAIT A FUCKING—" ("angry", xpos="far_left", ypos="head")

                call gen_chibi("sit_behind_desk")
                with blackfade

                gen "Ugh... I guess I must have fell asleep at some point..." ("base", xpos="far_left", ypos="head")
                gen "Was it all but a dream?" ("base", xpos="far_left", ypos="head")

                jump main_room_menu

        pause .8
        call gen_chibi("sit_behind_desk")
    else:
        random:
            gen "This phoenix has reached its daily petting limit, sadly, I'm afraid." ("base", xpos="far_left", ypos="head")
            gen "I have already petted it today." ("base", xpos="far_left", ypos="head")
            gen "It's in a post-pet state, I should leave it alone." ("base", xpos="far_left", ypos="head")
            gen "I don't want to cause carpel-talon tunnel." ("base", xpos="far_left", ypos="head")
            gen "Gave that bird a good ruffling, now off to groom a griffin." ("base", xpos="far_left", ypos="head")

    jump main_room_menu