label cho_summon_setup:

    $ cho_wardrobe_unlocked = True

    # Reset doll state
    $ cho.wear("all")
    $ cho.set_cum(None)
    $ cho.animation = None

    # Unlock favours at tier 3
    # this will probably move to a cho_quid_E# event once we've implemented Gryffindor lead-up events
    if cho_tier == 3:
        $ cho_favors_unlocked = True

    if cho_outfits_schedule:
        $ cho.equip_random_outfit()

    call play_sound("door")
    call cho_chibi("stand", "mid", "base")
    with d3

    #Cho greeting.
    call play_music("cho")

    if cho_mood > 0:
        if 5 > cho_mood >= 1:
            cho "Yes, [cho_genie_name]?" ("annoyed", "base", "base", "mid", xpos="base", ypos="base", trans=d3)
        elif 10 > cho_mood >= 5:
            cho "*sigh*... Yes, [cho_genie_name]?" ("open", "base", "base", "R", xpos="base", ypos="base", trans=d3)
        elif 20 > cho_mood >= 10:
            cho "What is it, [cho_genie_name]?" ("annoyed", "base", "angry", "mid", xpos="base", ypos="base",trans=d3)
        elif 30 > cho_mood >= 20:
            cho "What do you want, \"[cho_genie_name]\"?" ("angry", "narrow", "angry", "mid", xpos="base", ypos="base",trans=d3)
        elif 40 > cho_mood >= 30:
            cho "*Hmph*..." ("upset", "base", "angry", "R", xpos="base", ypos="base",trans=d3)
        elif 50 > cho_mood >= 40:
            cho "*Tsk*" ("soft", "narrow", "angry", "R", xpos="base", ypos="base",trans=d3)
        elif cho_mood >= 50:
            cho "I can't believe you've done this!" ("scream", "wide", "angry", "mid", xpos="base", ypos="base",trans=d3)
            cho "" ("upset", "wide", "angry", "mid")

        call describe_mood("Cho", cho_mood)
        call tutorial("moodngifts")
    else:
        if game.daytime:
            cho "Good morning, [cho_genie_name]." ("base", "base", "base", "mid", xpos="base", ypos="base", trans=d3)
        else:
            cho "Good evening, [cho_genie_name]." ("base", "base", "base", "mid", xpos="base", ypos="base", trans=d3)

    if cho_tier == 1:
        # Intro hints
        if not ss_he.cho_E1 or not cho_intro.E3_complete:

            label .hint_menu:

            menu:
                "-Talk-" (icon="interface/icons/small/talk.webp"):
                    cho "Have you gotten Hermione to stop spreading rumours about me?" ("annoyed", "narrow", "base", "mid")
                    gen "Oh, was I supposed to do that?" ("base", xpos="far_left", ypos="head")
                    cho "Yes!" ("angry", "base", "base", "mid")
                    gen "Right..." ("base", xpos="far_left", ypos="head")
                    gen "(Hmm... I think I could use this tension between those two...)" ("base", xpos="far_left", ypos="head")
                    if not ss_he.cho_E1:
                        gen "(Better tell Snape about my plan before confronting Miss Granger...)" ("base", xpos="far_left", ypos="head")
                    elif not cho_intro.E3_complete:
                        gen " (I should probably talk to Hermione...)" ("base", xpos="far_left", ypos="head")

                    jump cho_summon_setup.hint_menu

                "-Dismiss Her-":
                    stop music fadeout 3.0

                    if cho_mood == 0:
                        cho "Goodbye, [cho_genie_name]." (face="happy")
                    else:
                        cho "Goodbye, [cho_genie_name]." (face="annoyed")

                    call play_sound("door")

                    jump end_cho_event

    return