WTS/game/scripts/characters/hermione/events/jobs_NOT_IN_USE.txt

# Barmaid Job
label job_2:
    if states.her.level <= 6:
        her "*Humph*!..."
    elif states.her.level >=7 and states.her.level <= 15:
        her "Yes [name_genie_hermione]..."
    else:
        her "As you wish [name_genie_hermione]."

    show screen blkfade
    with d5
    # Setup
    play sound "sounds/cloth_sound.ogg"
    $ her_outfit_last.save()
    $ hermione.equip(her_outfit_maid)
    her "" ("base", "base", "base", "mid",xpos="right",ypos="base")
    hide screen blkfade
    with d5

    pause 2.5
    hide hermione_main
    with d3

    gen "Off you go then..." ("base", xpos="far_left", ypos="head")

    call her_walk(action="leave")

    $ states.her.busy = True
    $ current_job = "barmaid"

    jump main_room_menu

label barmaid_responses:

    $ hermione.equip(her_outfit_maid)
    $ payment = renpy.random.randint(20, 50)

    call her_walk(action="enter", xpos="mid", ypos="base")

    her "" ("base", "base", "base", "mid",xpos="right",ypos="base")
    pause.5

    menu:
        "\"How was your day?\"":
            her "Fine..."
            gen "Anything unusual happen?" ("base", xpos="far_left", ypos="head")
            her "Not really, I just served people drinks."
            gen "Well, in that case, ten points to Gryffindor." ("base", xpos="far_left", ypos="head")
            her "Thank you, [name_genie_hermione], here's your payment."
        "-Dismiss her-":
            her "Here's your payment."
            nar "You receive {number=payment} gold coins."
            gen "Well done [name_hermione_genie], ten points to Gryffindor." ("base", xpos="far_left", ypos="head")

    her "Thank you, [name_genie_hermione]."

    $ states.env.gryffindor+= 20
    $ states.env.gold += payment

    call her_walk(action="leave")

    $ hermione.equip(her_outfit_last)

    $ states.her.busy = True
    $ current_job = None
    jump main_room_menu

# Gryffindor Cheerleader Job (Needs outfit)
label job_3:
    if states.her.level <= 6:
        her "*Humph*!..."
    elif states.her.level <= 15:
        her "Yes, [name_genie_hermione]..." ("normal", "base", "base", "R")
    else:
        her "As you wish, [name_genie_hermione]." ("open", "base", "base", "mid")

    show screen blkfade
    with d5
    play sound "sounds/cloth_sound.ogg"
    $ her_outfit_last.save() # Store current outfit.
    if her_outfit_cheerleader_2.unlocked and states.her.level >= 11: #Sexy
        $ hermione.equip(her_outfit_cheerleader_2)
    else: #Normal
        $ hermione.equip(her_outfit_cheerleader_1)
    her "" ("base", "base", "base", "mid",xpos="right",ypos="base")
    hide screen blkfade
    with d5

    pause 2.5
    hide hermione_main
    with d3

    gen "You look great!" ("grin", xpos="far_left", ypos="head")
    her "Thank you..." ("base", "happyCl", "base", "mid")
    gen "Off you go then..." ("base", xpos="far_left", ypos="head")

    call her_walk(action="leave")

    $ states.her.busy = True
    $ current_job = "gryffindor_cheerleader"

    jump main_room_menu

label gryffindor_cheer_responses:

    if her_outfit_cheerleader_2.unlocked and states.her.level >= 11: #Sexy
        $ hermione.equip(her_outfit_cheerleader_2)
    else: #Normal
        $ hermione.equip(her_outfit_cheerleader_1)
    $ payment = renpy.random.randint(40, 80)

    call her_walk(action="enter", xpos="mid", ypos="base")

    her "" ("base", "base", "base", "mid",xpos="right",ypos="base")
    pause.5

    menu:
        "\"How was your day?\"":
            random:
                block:
                    her "It was good [name_genie_hermione], I think that the team morale has really started to go up." ("base", "base", "base", "mid")
                    gen "How so?" ("base", xpos="far_left", ypos="head")
                    her "Well, since I've started, they seem to have improved their tactics." ("open", "base", "base", "mid")
                    her "They also seem much happier. Harry is always looking at me with a smile on his face." ("base", "base", "base", "mid")
                    gen "And does he look at you a lot?" ("base", xpos="far_left", ypos="head")
                    her "Of course he does, we're good friends." ("open", "base", "base", "mid")
                    gen "\"I'm sure that must be the reason\"..." ("base", xpos="far_left", ypos="head")
                    her "Well, here's the money, [name_genie_hermione]." ("base", "base", "base", "mid")
                    nar "You receive [payment] gold coins."
                    gen "Well done, [name_hermione_genie], ten points to Gryffindor." ("base", xpos="far_left", ypos="head")
                block:
                    her "Tiring. This cheering thing really is quite exhausting." ("open", "base", "worried", "mid")
                    gen "Anything interesting happen?" ("base", xpos="far_left", ypos="head")
                    her "Not unless you count me almost dropping my pom-pom." ("normal", "base", "base", "mid")
                    gen "I don't... Well, did they pay you?" ("base", xpos="far_left", ypos="head")
                    her "Of course, here you are [name_genie_hermione]." ("open", "base", "base", "mid")
                    nar "You receive [payment] gold coins."
                    gen "Well done [name_hermione_genie], ten points to Gryffindor." ("base", xpos="far_left", ypos="head")
                block:
                    her "Very well, thank you... All the boys said that I helped keep their spirits up." ("open", "base", "base", "mid")
                    gen "{size=-5}I'm sure that wasn't the only thing you've helped stay up...{/size}" ("base", xpos="far_left", ypos="head")
                    her "What was that [name_genie_hermione]?" ("open", "squint", "base", "mid")
                    gen "I was just saying that I'm sure you did a stand up job." ("base", xpos="far_left", ypos="head")
                    her "I think so..." ("base", "happyCl", "base", "mid")
                    gen "Well, did they pay you for raising their \"spirits\"?" ("base", xpos="far_left", ypos="head")
                    her "Of course they did." ("open", "base", "base", "mid")
                    nar "You receive [payment] gold coins."
                    gen "Well done [name_hermione_genie], ten points to Gryffindor." ("base", xpos="far_left", ypos="head")
                block:
                    gen "You seem very chipper today." ("base", xpos="far_left", ypos="head")
                    her "Of course I am, we won!" ("base", "base", "base", "mid")
                    gen "Won?" ("base", xpos="far_left", ypos="head")
                    her "We won! We beat Slytherin in a practice match." ("smile", "happyCl", "base", "mid")
                    gen "You seem a little bit overexcited for just a practice match." ("base", xpos="far_left", ypos="head")
                    her "Well it was such a great game. Not to mention that we got to rub it in those Slytherin students' faces afterwards." ("smile", "base", "base", "R")
                    gen "Well I'm glad that you are enjoying your work." ("grin", xpos="far_left", ypos="head")
                    her "I am [name_genie_hermione]. Given that most of the \"work\" I've done to help my house is kept private, it feels good to be able to do something public once." ("open", "base", "base", "mid")
                    gen "Not to mention you get paid for it..." ("base", xpos="far_left", ypos="head")
                    her "Oh, right, Here you are..." ("soft", "base", "base", "R")
                    nar "You receive [payment] gold coins."
                    gen "Well done [name_hermione_genie], ten points to Gryffindor." ("base", xpos="far_left", ypos="head")
                block:
                    her "We won! We managed to beat Slytherin." ("base", "base", "base", "mid")
                    gen "That must have been very exhilarating. I'm sure your cheering gave the extra motivation needed to win." ("base", xpos="far_left", ypos="head")
                    her "I think it did [name_genie_hermione]. They were all very excited to receive their reward for winning the game." ("base", "happyCl", "base", "mid")

                    menu:
                        "-Reward?-":
                            gen "What reward did you promise them?" ("base", xpos="far_left", ypos="head")
                            her "Well, I was quite keen to ensure our victory against Slytherin that I may have promised that I would give each of them a blowjob if they won." ("grin", "base", "base", "R")
                            gen "You gave every team member a blowjob after the game?" ("base", xpos="far_left", ypos="head")
                            her "And the water boy..." ("smile", "narrow", "base", "mid_soft")
                            gen "How did you even manage that? Did you have to crawl around the locker room on your knees?" ("base", xpos="far_left", ypos="head")
                            her "Of course not, they all patiently waited for their turn..." ("scream", "closed", "angry", "mid")
                            gen "Who doesn't love a queue..." ("base", xpos="far_left", ypos="head")
                            gen "So they queued up... And then?" ("base", xpos="far_left", ypos="head")
                            her "Well I did what I said I would, I'm not the kind of person to lie am I?" ("annoyed", "base", "worried", "R")
                            her "So, I gave them the reward I promised... And surely, you of all people would know how a blowjob works." ("annoyed", "happy", "base", "R")
                            gen "That's not quite what I meant." ("base", xpos="far_left", ypos="head")
                            gen "You just look rather..." ("base", xpos="far_left", ypos="head")
                            gen "Clean, that's all." ("base", xpos="far_left", ypos="head")
                            her @ cheeks blush "Oh, well..." ("base", "narrow", "worried", "down")
                            her @ cheeks blush "I didn't want to make a mess." ("soft", "narrow", "base", "down")
                            her "Anyhow, I'm glad I did it. I can't wait to rub it in Astoria's face tomorrow..." ("smile", "base", "base", "mid")
                            gen "I'm glad you think it was worth it. Did they pay you?" ("base", xpos="far_left", ypos="head")
                        "-Okay-":
                            gen "I'm sure it was worth it. Did they pay you?" ("base", xpos="far_left", ypos="head")

                    her "Of course they did [name_genie_hermione], here you are."
                    gen "Well done [name_hermione_genie], ten points to Gryffindor." ("base", xpos="far_left", ypos="head")

        "-Dismiss her-":
            her "Here's your payment [name_genie_hermione]." ("soft", "base", "base", "R")
            gen "Well done [name_hermione_genie], ten points to Gryffindor." ("base", xpos="far_left", ypos="head")

    her "Thank you, [name_genie_hermione]." ("base", "happyCl", "base", "mid")
    nar "You receive [payment] gold coins."
    $ states.env.gryffindor+= 20
    $ states.env.gold += payment

    call her_walk(action="leave")

    $ hermione.equip(her_outfit_last)

    $ states.her.busy = True
    $ current_job = None
    jump main_room_menu

# Slytherin Cheerleader Job
label job_4:

    if states.her.level <= 6:
        her "*Humph*!..."
    elif states.her.level >=7 and states.her.level <= 15:
        her "Yes, [name_genie_hermione]..."
    else:
        her "As you wish, [name_genie_hermione]."

    show screen blkfade
    with d5
    play sound "sounds/cloth_sound.ogg"
    $ her_outfit_last.save() # Store current outfit.
    if her_outfit_cheerleader_2.unlocked and states.her.level >= 11: #Sexy
        $ hermione.equip(her_outfit_cheerleader_2)
    else: #Normal
        $ hermione.equip(her_outfit_cheerleader_1)
    her "" ("base", "base", "base", "mid",xpos="right",ypos="base")
    hide screen blkfade
    with d5

    pause 2.5
    hide hermione_main
    with d3

    gen "You look incredible!" ("angry", xpos="far_left", ypos="head")
    her "Thank you..." ("base", "happyCl", "base", "mid")
    gen "Off you go then..." ("base", xpos="far_left", ypos="head")

    call her_walk(action="leave")

    $ states.her.busy = True
    $ current_job = "slytherin_cheerleader"

    call music_block
    jump main_room_menu

label slytherin_cheer_responses:

    if her_outfit_cheerleader_2.unlocked and states.her.level >= 11: #Sexy
        $ hermione.equip(her_outfit_cheerleader_2)
    else: #Normal
        $ hermione.equip(her_outfit_cheerleader_1)

    $ payment = renpy.random.randint(50, 100)

    call her_walk(action="enter", xpos="mid", ypos="base")

    if states.her.public_level > 15:
        her "" ("base", "narrow", "base", "up",xpos="right",ypos="base")
    else:
        her "" ("base", "base", "base", "mid",xpos="right",ypos="base")
    pause.5

    menu:
        "-Ask her about her day-":
            random:
                block:
                    gen "How was your day today [name_hermione_genie]?" ("base", xpos="far_left", ypos="head")
                    her "Exhausting... Those Slytherin pigs insisted that I cheer for their entire practice session." ("open", "closed", "angry", "mid")
                    her "They were hardly playing the game by the end. They were just standing there watching me."
                    gen "Well what was your routine?" ("base", xpos="far_left", ypos="head")
                    her "Mostly star jumps while I cheered \"Go Slytherin!\"." ("annoyed", "squint", "angry", "mid")
                    gen "So you were just jumping up and down? That doesn't seem like a very intricate cheer." ("base", xpos="far_left", ypos="head")
                    her "It isn't, but it's what they insisted I do." ("annoyed", "narrow", "angry", "R")
                    gen "Well it definitely sounds like you earned your points." ("base", xpos="far_left", ypos="head")
                    gen "Thirty points to Gryffindor." ("base", xpos="far_left", ypos="head")
                block:
                    gen "How was your day today [name_hermione_genie]?" ("base", xpos="far_left", ypos="head")
                    her "Uneventful. I completed my routine and then went back to my room..." ("open", "squint", "base", "mid")
                    gen "You didn't talk to anyone?" ("base", xpos="far_left", ypos="head")
                    her "I make a point of trying to avoid Slytherin students as best I can." ("annoyed", "narrow", "angry", "R")
                    gen "Are they really that unbearable?" ("base", xpos="far_left", ypos="head")
                    her "Yes..." ("open", "closed", "angry", "mid")
                    gen "Well, you earned your points." ("base", xpos="far_left", ypos="head")
                    gen "Thirty points to Gryffindor." ("base", xpos="far_left", ypos="head")
                block:
                    gen "Hello [name_hermione_genie]." ("base", xpos="far_left", ypos="head")
                    her "Hello [name_genie_hermione]." ("normal", "base", "base", "mid")
                    gen "How did everything go today?" ("base", xpos="far_left", ypos="head")
                    her "Very well... In fact, I think I might be doing too well." ("annoyed", "base", "worried", "R")
                    gen "How so?" ("base", xpos="far_left", ypos="head")
                    her "I think that my cheering is having too much of a positive effect." ("open", "base", "worried", "mid")
                    her "I'm not sure that I want the Slytherin team to improve, let alone because of me..." ("open", "base", "worried", "R")
                    gen "Just think about how you're helping your house in other ways." ("base", xpos="far_left", ypos="head")
                    her "I suppose you're right [name_genie_hermione]." ("open", "base", "base", "mid")
                    gen "Of course I am... Now, did they pay you?" ("base", xpos="far_left", ypos="head")
                    her "Yes [name_genie_hermione]." ("base", "base", "base", "mid")
                    gen "Well done [name_hermione_genie], twenty points to Gryffindor." ("base", xpos="far_left", ypos="head")
                block:
                    her "[name_genie_hermione], something must be done about those Slytherin boys..." ("open", "closed", "angry", "mid")
                    her "It's bad enough that I have to cheer for them, but they are being a little bit touchy." ("annoyed", "narrow", "angry", "R")
                    gen "Touchy?" ("base", xpos="far_left", ypos="head")
                    her "Yes, they keep groping me. It's highly inappropriate, and it interrupts my routine." ("scream", "closed", "angry", "mid")
                    gen "You kept dancing while they groped you?" ("base", xpos="far_left", ypos="head")
                    her "Of course, I'm there to complete a job. I'm not getting distracted just because of a few boys." ("open", "closed", "angry", "mid")
                    gen "Well, what would you have me do?" ("base", xpos="far_left", ypos="head")
                    her "Speak to Professor Snape, tell him to chastise them. They'll listen to him..." ("angry", "base", "angry", "mid")
                    gen "Very well, I'll speak to him. Although I'm not sure it will have the effect you're hoping for." ("base", xpos="far_left", ypos="head")
                    her "It better, otherwise I won't put my full effort into this..." ("normal", "squint", "angry", "mid")
                    gen "{size=-5}I'm sure that'll show them.{/size}" ("base", xpos="far_left", ypos="head")
                    her "What was that [name_genie_hermione]?" ("open", "squint", "base", "mid")
                    gen "Nothing [name_hermione_genie], I'll speak to Professor Snape tonight..." ("base", xpos="far_left", ypos="head")
                block:#Comes back with cum on her
                    gen "What the hell happened to you?" ("base", xpos="far_left", ypos="head")
                    her "I did my job [name_genie_hermione]." ("angry", "narrow", "base", "down")
                    gen "What are you talking about? You were supposed to be a cheerleader." ("base", xpos="far_left", ypos="head")
                    gen "You know, cheering..." ("base", xpos="far_left", ypos="head")
                    gen "And all that." ("base", xpos="far_left", ypos="head")
                    her "I am [name_genie_hermione]. I just performed a different type of cheer today." ("soft", "narrow", "annoyed", "up")
                    gen "And by that, you mean jerking off the entire Slytherin team?" ("base", xpos="far_left", ypos="head")
                    her "Well that's not how it started. I was initially just giving them a bit of a dance in the locker room..." ("angry", "narrow", "base", "down")
                    her "And one thing led to another."
                    gen "Fine, I don't want to hear it. How much did they pay you for this \"cheering\"?" ("base", xpos="far_left", ypos="head")
                    her "Pay me?" ("silly", "narrow", "base", "dead")
                    gen "You are supposed to be paid for this [name_hermione_genie]." ("base", xpos="far_left", ypos="head")
                    her @ cheeks blush "Oh, I must have forgotten... Sorry [name_genie_hermione]." ("base", "base", "base", "R")
                    gen "Fine, but you aren't getting any points." ("base", xpos="far_left", ypos="head")
                    her "Of course [name_genie_hermione]. Will that be all?" ("base", "base", "base", "mid")
                    gen "Yes, you're free to go now." ("base", xpos="far_left", ypos="head")
                    her "Thank you, [name_genie_hermione]." ("base", "narrow", "base", "mid_soft")

                    jump end_her_working_no_payment
        "-Dismiss her-":
            her "Here's your payment." ("open", "base", "base", "mid")
            nar "You receive [payment] gold coins."
            gen "Well done [name_hermione_genie], thirty points to Gryffindor." ("base", xpos="far_left", ypos="head")

    her "Thank you, [name_genie_hermione]." ("base", "narrow", "base", "mid_soft")
    nar "You receive [payment] gold coins."
    $ states.env.gryffindor+= 30
    $ states.env.gold += payment

    label end_her_working_no_payment:

    call her_walk(action="leave")

    $ hermione.equip(her_outfit_last)

    $ states.her.busy = True
    $ current_job = None

    call music_block
    jump main_room_menu